aboutsummaryrefslogtreecommitdiff
path: root/gnu/services/spice.scm
blob: b8d2f8486e9c7fb3775f4741708f98e2da75d319 (about) (plain) 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016 David Craven <david@craven.ch>
;;; Copyright © 2017 Clément Lassieur <clement@lassieur.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services spice)
  #:use-module (gnu packages spice)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (guix deprecation)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:export (spice-vdagent-configuration
            spice-vdagent-configuration?
            spice-vdagent-service-type
            spice-vdagent-service))  ; deprecated

(define-record-type* <spice-vdagent-configuration>
  spice-vdagent-configuration make-spice-vdagent-configuration
  spice-vdagent-configuration?
  (spice-vdagent spice-vdagent-configuration-spice-vdagent
                 (default spice-vdagent)))

(define (spice-vdagent-shepherd-service config)
  "Return a <shepherd-service> for spice-vdagentd with CONFIG."
  (define spice-vdagent (spice-vdagent-configuration-spice-vdagent config))

  (define spice-vdagentd-command
    (list
     (file-append spice-vdagent "/sbin/spice-vdagentd")
     "-x"))

  (list
   (shepherd-service
    (documentation "Spice vdagentd service")
    (requirement '(dbus-system))
    (provision '(spice-vdagentd))
    (start #~(lambda args
               ;; spice-vdagentd supports being activated upon the client
               ;; connecting to its socket; when not using such feature, the
               ;; socket should not exist before vdagentd creates it itself.
               (mkdir-p "/run/spice-vdagentd")
               (false-if-exception
                (delete-file "/run/spice-vdagentd/spice-vdagent-sock"))
               (fork+exec-command '#$spice-vdagentd-command)))
    (stop #~(make-kill-destructor)))))

(define spice-vdagent-profile
  (compose list spice-vdagent-configuration-spice-vdagent))

(define spice-vdagent-service-type
  (service-type
   (name 'spice-vdagent)
   (default-value (spice-vdagent-configuration))
   (extensions
    (list (service-extension shepherd-root-service-type
                             spice-vdagent-shepherd-service)
          (service-extension profile-service-type
                             spice-vdagent-profile)))
   (description "Start the @command{vdagentd} and @command{vdagent} daemons
from the @code{spice-vdagent} package to enable window resizing and clipboard
sharing for @acronym{VM, virtual machine} guests.")))

(define-deprecated (spice-vdagent-service
                    #:optional (config (spice-vdagent-configuration)))
  "Start the @command{vdagentd} and @command{vdagent} daemons
from @var{spice-vdagent} to enable guest window resizing and
clipboard sharing."
  (service spice-vdagent-service-type config))
generated by cgit
at-uuid->string uuid) "Convert FAT32/FAT16 UUID, a 4-byte bytevector, to its string representation." (let ((high (bytevector-uint-ref uuid 0 %fat-endianness 2)) (low (bytevector-uint-ref uuid 2 %fat-endianness 2))) (format #f "~:@(~4,'0x-~4,'0x~)" low high))) (define %fat-uuid-rx (make-regexp "^([[:xdigit:]]{4})-([[:xdigit:]]{4})$")) (define (string->fat-uuid str) "Parse STR, which is in FAT32/FAT16 format, and return a bytevector or #f." (match (regexp-exec %fat-uuid-rx str) (#f #f) (rx-match (uint-list->bytevector (list (string->number (match:substring rx-match 2) 16) (string->number (match:substring rx-match 1) 16)) %fat-endianness 2)))) ;;; ;;; NTFS. ;;; (define-syntax %ntfs-endianness ;; Endianness of NTFS file system. (identifier-syntax (endianness little))) (define (ntfs-uuid->string uuid) "Convert NTFS UUID, a 8-byte bytevector, to its string representation." (format #f "~{~:@(~2,'0x~)~}" (reverse (bytevector->u8-list uuid)))) (define %ntfs-uuid-rx (make-regexp "^([[:xdigit:]]{16})$")) (define (string->ntfs-uuid str) "Parse STR, which is in NTFS format, and return a bytevector or #f." (match (regexp-exec %ntfs-uuid-rx str) (#f #f) (rx-match (u8-list->bytevector (let loop ((str str) (res '())) (if (string=? str "") res (loop (string-drop str 2) (cons (string->number (string-take str 2) 16) res)))))))) ;;; ;;; Generic interface. ;;; (define string->ext2-uuid string->dce-uuid) (define string->ext3-uuid string->dce-uuid) (define string->ext4-uuid string->dce-uuid) (define string->bcachefs-uuid string->dce-uuid) (define string->btrfs-uuid string->dce-uuid) (define string->f2fs-uuid string->dce-uuid) (define string->jfs-uuid string->dce-uuid) (define string->xfs-uuid string->dce-uuid) (define-syntax vhashq (syntax-rules (=>) ((_) vlist-null) ((_ (key others ... => value) rest ...) (vhash-consq key value (vhashq (others ... => value) rest ...))) ((_ (=> value) rest ...) (vhashq rest ...)))) (define %uuid-parsers (vhashq ('dce 'ext2 'ext3 'ext4 'bcachefs 'btrfs 'f2fs 'jfs 'xfs 'luks => string->dce-uuid) ('exfat 'fat32 'fat16 'fat => string->fat-uuid) ('ntfs => string->ntfs-uuid) ('iso9660 => string->iso9660-uuid))) (define %uuid-printers (vhashq ('dce 'ext2 'ext3 'ext4 'bcachefs 'btrfs 'f2fs 'jfs 'xfs 'luks => dce-uuid->string) ('iso9660 => iso9660-uuid->string) ('exfat 'fat32 'fat16 'fat => fat-uuid->string) ('ntfs => ntfs-uuid->string))) (define* (string->uuid str #:optional (type 'dce)) "Parse STR as a UUID of the given TYPE. On success, return the corresponding bytevector; otherwise return #f." (match (vhash-assq type %uuid-parsers) (#f #f) ((_ . (? procedure? parse)) (parse str)))) ;; High-level UUID representation that carries its type with it. ;; ;; This is necessary to serialize bytevectors with the right printer in some ;; circumstances. For instance, GRUB "search --fs-uuid" command compares the ;; string representation of UUIDs, not the raw bytes; thus, when emitting a ;; GRUB 'search' command, we need to produce the right string representation ;; (see <https://debbugs.gnu.org/cgi/bugreport.cgi?msg=52;att=0;bug=27735>). (define-record-type <uuid> (make-uuid type bv) uuid? (type uuid-type) ;'dce | 'iso9660 | ... (bv uuid-bytevector)) (define* (bytevector->uuid bv #:optional (type 'dce)) "Return a UUID object make of BV and TYPE." (make-uuid type bv)) (define-syntax uuid (lambda (s) "Return the UUID object corresponding to the given UUID representation or #f if the string could not be parsed." (syntax-case s (quote) ((_ str (quote type)) (and (string? (syntax->datum #'str)) (identifier? #'type)) ;; A literal string: do the conversion at expansion time. (let ((bv (string->uuid (syntax->datum #'str) (syntax->datum #'type)))) (unless bv (syntax-violation 'uuid "invalid UUID" s)) #`(make-uuid 'type #,(datum->syntax s bv)))) ((_ str) (string? (syntax->datum #'str)) #'(uuid str 'dce)) ((_ str) #'(let ((bv (string->uuid str 'dce))) (and bv (make-uuid 'dce bv)))) ((_ str type) #'(let ((bv (string->uuid str type))) (and bv (make-uuid type bv))))))) (define uuid->string ;; Convert the given bytevector or UUID object, to the corresponding UUID ;; string representation. (match-lambda* (((? bytevector? bv)) (uuid->string bv 'dce)) (((? bytevector? bv) type) (match (vhash-assq type %uuid-printers) (#f #f) ((_ . (? procedure? unparse)) (unparse bv)))) (((? uuid? uuid)) (uuid->string (uuid-bytevector uuid) (uuid-type uuid))))) (define uuid=? ;; Return true if A is equal to B, comparing only the actual bits. (match-lambda* (((? bytevector? a) (? bytevector? b)) (bytevector=? a b)) (((? uuid? a) (? bytevector? b)) (bytevector=? (uuid-bytevector a) b)) (((? uuid? a) (? uuid? b)) (bytevector=? (uuid-bytevector a) (uuid-bytevector b))) (((or (? uuid? a) (? bytevector? a)) (or (? uuid? b) (? bytevector? b))) (uuid=? b a))))
generated by cgit