blob: 5bd5201478d29a2b197254f8884aadcb345c6311 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
#!/usr/bin/env gnuplot
## SPDX-License-Identifier: CC0-1.0
##
## Copyright (C) 2025 Woj. Kosior <koszko@koszko.org>
if (!exists("counts_filename")) counts_filename = \
"unflattened-multiver-counts.csv";
if (!exists("out_filename")) out_filename = "unflattened-multiver-counts.svg";
set terminal svg size 800,400 font "DejaVu,sans,14.5";
set output out_filename;
#set title "Numbers of rebuilt packages present in Debian, categorized by their unflattenable build dependency counts.";
set ylabel "Built project count";
set xlabel "Remaining dependency conflicts count";
set datafile separator ",";
set boxwidth 0.5;
set style fill solid border -1;
set key noautotitle;
set xtics scale 0;
set lmargin 11;
set rmargin 3.5;
set linetype 1 linecolor rgb "0x777777";
set linetype 2 linecolor rgb "0x333333";
stats "unflattened-multiver-counts.csv" using "ALL-PACKAGES" nooutput;
lbl_shift = STATS_max / 40;
set yrange [0:(STATS_max * 1.1)];
plot counts_filename \
using 0:"ALL-PACKAGES":xtic(stringcolumn("MULTIVER-COUNT")) \
with boxes \
title "All rebuilt", \
"" \
using 0:"IN-DEBIAN-PACKAGES" \
with boxes fill pattern 5 \
title "Packaged in Debian", \
"" \
using 0:\
(column("ALL-PACKAGES") + lbl_shift):\
(column("ALL-PACKAGES")) \
with labels, \
"" \
using 0:\
(column("IN-DEBIAN-PACKAGES") + lbl_shift):\
((column("IN-DEBIAN-PACKAGES") + STATS_max / 20 < \
column("ALL-PACKAGES")) ? \
stringcolumn("IN-DEBIAN-PACKAGES") : "") \
with labels;
|
