;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017, 2020 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2022 Simon Tournier <zimon.toutoune@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (test-cache)
  #:use-module (guix cache)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-19)
  #:use-module (srfi srfi-64)
  #:use-module ((guix utils) #:select (call-with-temporary-directory))
  #:use-module (ice-9 match))

(test-begin "cache")

(test-equal "remove-expired-cache-entries"
  '("o" "l" "d")
  (let* ((removed '())
         (now     (time-second (current-time time-monotonic)))
         (ttl     100)
         (stamp   (match-lambda
                    ((or "n" "e" "w") (+ now 100))
                    ((or "o" "l" "d") (- now 100))))
         (delete  (lambda (entry)
                    (set! removed (cons entry removed)))))
    (remove-expired-cache-entries (reverse '("n" "e" "w"
                                             "o" "l" "d"))
                                  #:entry-expiration stamp
                                  #:delete-entry delete)
    removed))

(define-syntax-rule (test-cache-cleanup cache exp ...)
  (call-with-temporary-directory
   (lambda (cache)
     (let* ((deleted '())
            (delete! (lambda (entry)
                       (set! deleted (cons entry deleted)))))
       exp ...
       (maybe-remove-expired-cache-entries cache
                                           (const '("a" "b" "c"))
                                           #:entry-expiration (const 0)
                                           #:delete-entry delete!)
       (reverse deleted)))))

(test-equal "maybe-remove-expired-cache-entries, first cleanup"
  '("a" "b" "c")
  (test-cache-cleanup cache))

(test-equal "maybe-remove-expired-cache-entries, no cleanup needed"
  '()
  (test-cache-cleanup cache
    (call-with-output-file (string-append cache "/last-expiry-cleanup")
      (lambda (port)
        (display (+ (time-second (current-time time-monotonic)) 100)
                 port)))))

(test-equal "maybe-remove-expired-cache-entries, cleanup needed"
  '("a" "b" "c")
  (test-cache-cleanup cache
    (call-with-output-file (string-append cache "/last-expiry-cleanup")
      (lambda (port)
        (display 0 port)))))

(test-equal "maybe-remove-expired-cache-entries, empty cache"
  '("a" "b" "c")
  (test-cache-cleanup cache
    (call-with-output-file (string-append cache "/last-expiry-cleanup")
      (lambda (port)
        (display "" port)))))

(test-equal "maybe-remove-expired-cache-entries, corrupted cache"
  '("a" "b" "c")
  (test-cache-cleanup cache
    (call-with-output-file (string-append cache "/last-expiry-cleanup")
      (lambda (port)
        (display "1\"34657890" port)))))

(test-end "cache")

;;; Local Variables:
;;; eval: (put 'test-cache-cleanup 'scheme-indent-function 1)
;;; End:
fo' class='commit-info'>
<tr><th>author</th><td>Efraim Flashner &lt;efraim@flashner.co.il&gt;</td><td class='right'>2024-03-18 11:31:41 +0200</td></tr>
<tr><th>committer</th><td>Efraim Flashner &lt;efraim@flashner.co.il&gt;</td><td class='right'>2024-07-19 00:42:53 +0300</td></tr>
<tr><th>commit</th><td colspan='2' class='oid'><a href='/guix/commit/gnu?id=2d90c36b8b467717b93b5c10d0ae53b11b93f06a'>2d90c36b8b467717b93b5c10d0ae53b11b93f06a</a> (<a href='/guix/patch/gnu?id=2d90c36b8b467717b93b5c10d0ae53b11b93f06a'>patch</a>)</td></tr>
<tr><th>tree</th><td colspan='2' class='oid'><a href='/guix/tree/?id=2d90c36b8b467717b93b5c10d0ae53b11b93f06a'>be6bbbb48001087754e540f233a6c833994c53e9</a> /<a href='/guix/tree/gnu?id=2d90c36b8b467717b93b5c10d0ae53b11b93f06a'>gnu</a></td></tr>
<tr><th>parent</th><td colspan='2' class='oid'><a href='/guix/commit/gnu?id=8328acc018c10baf47c7381d1d07ed6b6552e490'>8328acc018c10baf47c7381d1d07ed6b6552e490</a> (<a href='/guix/diff/gnu?id=2d90c36b8b467717b93b5c10d0ae53b11b93f06a&amp;id2=8328acc018c10baf47c7381d1d07ed6b6552e490'>diff</a>)</td></tr><tr><th>download</th><td colspan='2' class='oid'><a href='/guix/snapshot/guix-2d90c36b8b467717b93b5c10d0ae53b11b93f06a.tar.gz'>guix-2d90c36b8b467717b93b5c10d0ae53b11b93f06a.tar.gz</a><br/><a href='/guix/snapshot/guix-2d90c36b8b467717b93b5c10d0ae53b11b93f06a.zip'>guix-2d90c36b8b467717b93b5c10d0ae53b11b93f06a.zip</a><br/></td></tr></table>
<div class='commit-subject'>gnu: Add rust-multer-3.</div><div class='commit-msg'>* gnu/packages/crates-io.scm (rust-multer-3): New variable.
(rust-multer-2): Inherit from rust-multer-3.

Change-Id: I6ec55f2f5ea431bb68e7fdecb88a1ee5d0ac6053
</div><div class='diffstat-header'><a href='/guix/diff/?id=2d90c36b8b467717b93b5c10d0ae53b11b93f06a'>Diffstat</a> (limited to 'gnu')</div><table summary='diffstat' class='diffstat'>