#!@GUILE@ --no-auto-compile
-*- scheme -*-
!#
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013 Mark H Weaver <mhw@netris.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

;; IMPORTANT: We must avoid loading any modules from Guix here,
;; because we need to adjust the guile load paths first.
;; It's okay to import modules from core Guile though.
(use-modules (ice-9 regex)
             (srfi srfi-26))

(let ()
  (define-syntax-rule (push! elt v) (set! v (cons elt v)))

  (define config-lookup
    (let ((config '(("prefix"         . "@prefix@")
                    ("datarootdir"    . "@datarootdir@")
                    ("guilemoduledir" . "@guilemoduledir@")
                    ("localedir"      . "@localedir@")))
          (var-ref-regexp (make-regexp "\\$\\{([a-z]+)\\}")))
      (define (expand-var-ref match)
        (lookup (match:substring match 1)))
      (define (expand str)
        (regexp-substitute/global #f var-ref-regexp str
                                  'pre expand-var-ref 'post))
      (define (lookup name)
        (expand (assoc-ref config name)))
      lookup))

  (define (maybe-augment-load-paths!)
    (unless (getenv "GUIX_UNINSTALLED")
      (let ((module-dir (config-lookup "guilemoduledir")))
        (push! module-dir %load-path)
        (push! module-dir %load-compiled-path))
      (let ((updates-dir (and=> (or (getenv "XDG_CONFIG_HOME")
                                    (and=> (getenv "HOME")
                                           (cut string-append <> "/.config")))
                                (cut string-append <> "/guix/latest"))))
        (when (and updates-dir (file-exists? updates-dir))
          (push! updates-dir %load-path)
          (push! updates-dir %load-compiled-path)))))

  (define (run-guix-main)
    (let ((guix-main (module-ref (resolve-interface '(guix ui))
                                 'guix-main)))
      (bindtextdomain "guix" (config-lookup "localedir"))
      (bindtextdomain "guix-packages" (config-lookup "localedir"))
      (apply guix-main (command-line))))

  (maybe-augment-load-paths!)
  (run-guix-main))
d><span title='2018-09-02 15:43:51 +0200'>2018-09-02</span></td><td><a href='/guix/commit/build-aux/compile-as-derivation.scm?id=20cbd4f5f4d08bc26c22eb40b6c1e55b02e93f23'>compile-as-derivation: Adjust %load-compiled-path.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-06-09 12:02:27 +0200'>2018-06-09</span></td><td><a href='/guix/commit/build-aux/compile-as-derivation.scm?id=75e24d7b0e19ab2164aecb340e82d07d2b9714e7'>pull: Install the new Guix in a profile.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-06-09 12:02:27 +0200'>2018-06-09</span></td><td><a href='/guix/commit/build-aux/compile-as-derivation.scm?id=8a0d9bc8a3f153159d9e239a151c0fa98f1e12d8'>self: Produce a complete package with the 'guix' command.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-04-08 17:48:25 +0200'>2018-04-08</span></td><td><a href='/guix/commit/build-aux/compile-as-derivation.scm?id=2cfc8d69644af6c53fed9128425e8ff70ad4509f'>build: Add 'as-derivation' target.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>