;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2023 Bruno Victal <mirai@makinata.eu>
;;; Copyright © 2023 Felix Lechner <felix.lechner@lease-up.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu tests pam)
  #:use-module (gnu tests)
  #:use-module (gnu services)
  #:use-module (gnu services base)
  #:use-module (gnu system)
  #:use-module (gnu system pam)
  #:use-module (gnu system vm)
  #:use-module (guix gexp)
  #:use-module (ice-9 format)
  #:export (%test-pam-limits))


;;;
;;; pam-limits-service-type
;;;

(define pam-limit-entries
  (list
   ;; make sure the limits apply to root (uid 0)
   (pam-limits-entry ":0" 'both 'rtprio 99)               ;default is 0
   (pam-limits-entry ":0" 'both 'memlock 'unlimited)))    ;default is 8192 kbytes

(define (run-test-pam-limits config)
  "Run tests in a os with pam-limits-service-type configured."
  (define os
    (marionette-operating-system
     (simple-operating-system
      (service pam-limits-service-type config))
     #:imported-modules '((gnu services herd))))

  (define vm
    (virtual-machine os))

  (define name "pam-limits-service")

  (define test
    (with-imported-modules '((gnu build marionette)
                             (guix build syscalls))
      #~(begin
          (use-modules (gnu build marionette)
                       (guix build syscalls)
                       (srfi srfi-64))

          (let ((marionette (make-marionette (list #$vm))))

            (test-runner-current (system-test-runner #$output))

            (test-begin #$name)

            (test-equal "log in on tty1 and read limits"
              '(("99")                  ;real-time priority
                ("unlimited"))          ;max locked memory

              (begin
                ;; Wait for tty1.
                (marionette-eval '(begin
                                    (use-modules (gnu services herd))
                                    (start-service 'term-tty1))
                                 marionette)

                (marionette-control "sendkey ctrl-alt-f1" marionette)

                ;; Now we can type.
                (marionette-type "root\n" marionette)
                (marionette-type "ulimit -r > real-time-priority\n" marionette)
                (marionette-type "ulimit -l > max-locked-memory\n" marionette)

                ;; Read the two files.
                (marionette-eval '(use-modules (rnrs io ports)) marionette)
                (let ((guest-file (lambda (file)
                                    (string-tokenize
                                     (wait-for-file file marionette
                                                    #:read 'get-string-all)))))
                  (list (guest-file "/root/real-time-priority")
                        (guest-file "/root/max-locked-memory")))))

            (test-end)))))

  (gexp->derivation (string-append name "-test") test))

(define %test-pam-limits
  (system-test
   (name "pam-limits-service")
   (description "Test that pam-limits-service actually sets the limits as
configured.")
   (value (run-test-pam-limits pam-limit-entries))))
penne</td></tr>
<tr><td><span title='2021-04-20 14:32:53 +0200'>2021-04-20</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=3313f61e18cbb4a89ec6c980b39f8e5fcad2b890'>services: wireguard: Add keep-alive support.</a><span class='msg-avail'>...</span></td><td>Guillaume Le Vaillant</td></tr>
<tr><td><span title='2021-02-17 10:32:15 +0100'>2021-02-17</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=43b2e440c38a39eb64088bd6c08771c060aa10fc'>services: wireguard: New service.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2020-11-18 15:05:41 +0100'>2020-11-18</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=5221df34149465c5bbc1a76f83cb09f8911279f5'>gnu: vpn: Make ca, key and cert optional.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2020-02-19 04:08:55 +0100'>2020-02-19</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=c6c447701c9cfdeedf77224399faa9c07b12d045'>gnu: services: Add openvpn options.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2020-02-19 04:08:40 +0100'>2020-02-19</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=0372dd1a1e51e39382ee5d1aa968589b40506b8f'>gnu: services: Fix openvpn boolean fields.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2017-10-10 22:06:08 +0200'>2017-10-10</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=4b8b4418e609b5e0bfb6efbc11ac28deaa437e80'>services: vpn: Fix default tls-auth configuration.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2017-03-31 20:55:05 -0500'>2017-03-31</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=9fc221b58cecd73e22cac01cb0918a774a4a7b2f'>doc: Fix typos.</a><span class='msg-avail'>...</span></td><td>Eric Bavier</td></tr>
<tr><td><span title='2017-03-24 16:09:18 +0100'>2017-03-24</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=85ac401acf2e33e4cb6d1510ac24867dc516e656'>services: openvpn: Fix a typo which was corrected in generated doc.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2017-01-25 14:05:37 +0100'>2017-01-25</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=e57bd0bed86caac304e5f37c5653e6b13858c7c5'>services: Fix 'mkdir-p' in activation scripts.</a><span class='msg-avail'>...</span></td><td>Clément Lassieur</td></tr>
<tr><td><span title='2017-01-20 21:39:17 +0100'>2017-01-20</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=be051880c435d19e7788d5df56c062f7797e0a49'>services: Reindent vpn.scm.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2017-01-15 12:24:52 +0100'>2017-01-15</span></td><td><a href='/guix/commit/gnu/services/vpn.scm?id=2be1b4712d362fa9face12a731e75038ae9d59ba'>gnu: Add openvpn service.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>