;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2023 Bruno Victal <mirai@makinata.eu>
;;; Copyright © 2023 Felix Lechner <felix.lechner@lease-up.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu tests pam)
  #:use-module (gnu tests)
  #:use-module (gnu services)
  #:use-module (gnu services base)
  #:use-module (gnu system)
  #:use-module (gnu system pam)
  #:use-module (gnu system vm)
  #:use-module (guix gexp)
  #:use-module (ice-9 format)
  #:export (%test-pam-limits))


;;;
;;; pam-limits-service-type
;;;

(define pam-limit-entries
  (list
   ;; make sure the limits apply to root (uid 0)
   (pam-limits-entry ":0" 'both 'rtprio 99)               ;default is 0
   (pam-limits-entry ":0" 'both 'memlock 'unlimited)))    ;default is 8192 kbytes

(define (run-test-pam-limits config)
  "Run tests in a os with pam-limits-service-type configured."
  (define os
    (marionette-operating-system
     (simple-operating-system
      (service pam-limits-service-type config))
     #:imported-modules '((gnu services herd))))

  (define vm
    (virtual-machine os))

  (define name "pam-limits-service")

  (define test
    (with-imported-modules '((gnu build marionette)
                             (guix build syscalls))
      #~(begin
          (use-modules (gnu build marionette)
                       (guix build syscalls)
                       (srfi srfi-64))

          (let ((marionette (make-marionette (list #$vm))))

            (test-runner-current (system-test-runner #$output))

            (test-begin #$name)

            (test-equal "log in on tty1 and read limits"
              '(("99")                  ;real-time priority
                ("unlimited"))          ;max locked memory

              (begin
                ;; Wait for tty1.
                (marionette-eval '(begin
                                    (use-modules (gnu services herd))
                                    (start-service 'term-tty1))
                                 marionette)

                (marionette-control "sendkey ctrl-alt-f1" marionette)

                ;; Now we can type.
                (marionette-type "root\n" marionette)
                (marionette-type "ulimit -r > real-time-priority\n" marionette)
                (marionette-type "ulimit -l > max-locked-memory\n" marionette)

                ;; Read the two files.
                (marionette-eval '(use-modules (rnrs io ports)) marionette)
                (let ((guest-file (lambda (file)
                                    (string-tokenize
                                     (wait-for-file file marionette
                                                    #:read 'get-string-all)))))
                  (list (guest-file "/root/real-time-priority")
                        (guest-file "/root/max-locked-memory")))))

            (test-end)))))

  (gexp->derivation (string-append name "-test") test))

(define %test-pam-limits
  (system-test
   (name "pam-limits-service")
   (description "Test that pam-limits-service actually sets the limits as
configured.")
   (value (run-test-pam-limits pam-limit-entries))))
..</span></td><td>Janneke Nieuwenhuizen</td></tr>
<tr><td><span title='2024-01-05 00:31:36 -0500'>2024-01-05</span></td><td><a href='/guix/commit/build-aux?id=6702118c94d05f8410e89781f661e1fd3858b365'>build: test-driver.scm: Set mode.</a><span class='msg-avail'>...</span></td><td>Tomas Volf</td></tr>
<tr><td><span title='2023-08-21 10:45:45 +0200'>2023-08-21</span></td><td><a href='/guix/commit/build-aux?id=3c6b6941a2c76c26ebf0c1bfd7f901a22c19dce1'>maint: Add 'etc/hurd-manifest.scm'.</a><span class='msg-avail'>...</span></td><td>Janneke Nieuwenhuizen</td></tr>
<tr><td><span title='2023-07-25 15:48:42 +0200'>2023-07-25</span></td><td><a href='/guix/commit/build-aux?id=9dfda9e1a0d2798d4caf23fa00bf272ca1afcc7e'>cuirass: Update hurd-manifest with newly supported packages.</a><span class='msg-avail'>...</span></td><td>Janneke Nieuwenhuizen</td></tr>
<tr><td><span title='2022-05-26 11:41:05 +0200'>2022-05-26</span></td><td><a href='/guix/commit/build-aux?id=d90bd5642a3663cc7d5124068fadbf8fa28b3207'>cuirass: Create just as many threads as needed.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2022-05-26 11:41:05 +0200'>2022-05-26</span></td><td><a href='/guix/commit/build-aux?id=98a6642298be6663b9d318b7dea46d1dba275839'>cuirass: Fork inferior processes before creating threads.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2022-05-20 18:46:07 +0200'>2022-05-20</span></td><td><a href='/guix/commit/build-aux?id=598f7289db9955584457ffc11c8504f3938a1618'>cuirass: Close each inferior upon completion.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>