;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017, 2018 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2018 Clément Lassieur <clement@lassieur.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu tests dict)
  #:use-module (gnu tests)
  #:use-module (gnu system)
  #:use-module (gnu system nss)
  #:use-module (gnu system vm)
  #:use-module (gnu services)
  #:use-module (gnu services dict)
  #:use-module (gnu services networking)
  #:use-module (gnu packages wordnet)
  #:use-module (guix gexp)
  #:use-module (guix store)
  #:use-module (guix packages)
  #:use-module (guix modules)
  #:export (%test-dicod))

(define %dicod-os
  (simple-operating-system
   (service dhcp-client-service-type)
   (service dicod-service-type
            (dicod-configuration
             (interfaces '("0.0.0.0"))
             (handlers (list (dicod-handler
                              (name "wordnet")
                              (module "dictorg")
                              (options
                               ;; XXX: Not useful since WordNet does not
                               ;; provide DICT-formatted data?
                               (list #~(string-append "dbdir=" #$wordnet))))))
             (databases (list (dicod-database
                               (name "wordnet")
                               (complex? #t)
                               (handler "wordnet")
                               (options '("database=wn")))
                              %dicod-database:gcide))))))

(define* (run-dicod-test)
  "Run tests of 'dicod-service-type'."
  (define os
    (marionette-operating-system
     %dicod-os
     #:imported-modules
     (source-module-closure '((gnu services herd)))))

  (define vm
    (virtual-machine
     (operating-system os)
     (port-forwardings '((8000 . 2628)))))

  (define test
    (with-imported-modules '((gnu build marionette))
      #~(begin
          (use-modules (ice-9 rdelim)
                       (ice-9 regex)
                       (srfi srfi-64)
                       (gnu build marionette))
          (define marionette
            ;; Forward the guest's DICT port to local port 8000.
            (make-marionette (list #$vm)))

          (define %dico-socket
            (socket PF_INET SOCK_STREAM 0))

          (mkdir #$output)
          (chdir #$output)

          (test-begin "dicod")

          ;; Wait for the service to be started.
          (test-assert "service is running"
            (marionette-eval
             '(begin
                (use-modules (gnu services herd))
                (start-service 'dicod))
             marionette))

          ;; Wait until dicod is actually listening.
          ;; TODO: Use a PID file instead.
          (test-assert "connect inside"
            (wait-for-tcp-port 2628 marionette))

          (test-assert "connect"
            (let ((addr (make-socket-address AF_INET INADDR_LOOPBACK 8000)))
              (connect %dico-socket addr)
              (read-line %dico-socket 'concat)))

          (test-equal "CLIENT"
            "250 ok\r\n"
            (begin
              (display "CLIENT \"GNU Guile\"\r\n" %dico-socket)
              (read-line %dico-socket 'concat)))

          (test-assert "DEFINE"
            (begin
              (display "DEFINE ! hello\r\n" %dico-socket)
              (display "QUIT\r\n" %dico-socket)
              (let ((result (read-string %dico-socket)))
                (and (string-contains result "gcide")
                     (string-contains result "hello")
                     result))))

          (test-end)
          (exit (= (test-runner-fail-count (test-runner-current)) 0)))))

  (gexp->derivation "dicod" test))

(define %test-dicod
  (system-test
   (name "dicod")
   (description "Connect to the dicod DICT server.")
   (value (run-dicod-test))))
ix-manual.es.po?id=b212fef4b076faccdd36335c728fd71321778716'>nls: Update 'es' translation of the manual.</a></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2019-05-13 10:57:11 +0200'>2019-05-13</span></td><td><a href='/guix/commit/po/doc/guix-manual.es.po?id=8548cf6e95917f7b56042d2d275a08e91eedf31a'>nls: Update es translation.</a></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-05-01 11:33:32 +0200'>2019-05-01</span></td><td><a href='/guix/commit/po/doc/guix-manual.es.po?id=a3b32d57d6677fded92dbd3f4ecafbf9aceeb855'>nls: Fix cross-reference syntax error in 'guix-manual.es.po'.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-05-01 10:16:58 +0200'>2019-05-01</span></td><td><a href='/guix/commit/po/doc/guix-manual.es.po?id=d3619b296fd1db6441e09bb51b55a4264b9fd0ed'>nls: Update manual translations for de, es, fr, and zh_CN.</a></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-04-25 18:55:12 +0200'>2019-04-25</span></td><td><a href='/guix/commit/po/doc/guix-manual.es.po?id=57e2b24dc03e44e4e379436e63d29231f1f9d28c'>nls: Update 'es' translation.</a></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2019-04-23 23:56:16 +0200'>2019-04-23</span></td><td><a href='/guix/commit/po/doc/guix-manual.es.po?id=6227e1b7477b71f31ea3bf8a74c32fe7238dcece'>doc: Add Spanish translation.</a><span class='msg-avail'>...</span></td><td>Miguel Ángel Arruga Vivas</td></tr>