;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2019, 2020 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu system keyboard)
  #:use-module (guix gexp)
  #:use-module ((gnu packages xorg)
                #:select (xkeyboard-config console-setup))
  #:use-module (srfi srfi-9 gnu)
  #:use-module (ice-9 match)
  #:export (keyboard-layout?
            keyboard-layout
            keyboard-layout-name
            keyboard-layout-variant
            keyboard-layout-model
            keyboard-layout-options

            keyboard-layout->console-keymap))

;;; Commentary:
;;;
;;; This module provides a data structure to represent keyboard layouts
;;; according to the XKB naming and classification (see the 'xkeyboard-config'
;;; package).
;;;
;;; Code:

(define-immutable-record-type <keyboard-layout>
  (%keyboard-layout name variant model options)
  keyboard-layout?
  (name      keyboard-layout-name)                ;string
  (variant   keyboard-layout-variant)             ;#f | string
  (model     keyboard-layout-model)               ;#f | string
  (options   keyboard-layout-options))            ;list of strings

(define* (keyboard-layout name #:optional variant
                          #:key model (options '()))
  "Return a new keyboard layout with the given NAME and VARIANT.

NAME must be a string such as \"fr\"; VARIANT must be a string such as
\"bepo\" or \"nodeadkeys\".  See the 'xkeyboard-config' package for valid
options."
  (%keyboard-layout name variant model options))

(define* (keyboard-layout->console-keymap layout
                                          #:key
                                          (xkeyboard-config xkeyboard-config))
  "Return a Linux console keymap file for LAYOUT, a <keyboard-layout> record.
Layout information is taken from the XKEYBOARD-CONFIG package."
  (define build
    (with-imported-modules '((guix build utils))
      #~(begin
          (use-modules (guix build utils)
                       (ice-9 popen)
                       (ice-9 match))

          (define pipe
            (open-pipe* OPEN_READ
                        #+(file-append console-setup "/bin/ckbcomp")
                        (string-append "-I"
                                       #+(file-append xkeyboard-config
                                                      "/share/X11/xkb"))
                        "-rules" "base"
                        #$@(match (keyboard-layout-model layout)
                             (#f      '())
                             (model   `("-model" ,model)))
                        #$(keyboard-layout-name layout)
                        #$(or (keyboard-layout-variant layout)
                              "")
                        #$(string-join (keyboard-layout-options layout) ",")))

          (call-with-output-file #$output
            (lambda (output)
              (dump-port pipe output)))

          ;; Note: ckbcomp errors out when the layout name is unknown, but
          ;; merely emits a warning when the variant is unknown.
          (unless (zero? (close-pipe pipe))
            (error "failed to create console keymap for keyboard layout"
                   #$(keyboard-layout-name layout))))))

  (computed-file (string-append "console-keymap."
                                (string-map (match-lambda
                                              (#\, #\-)
                                              (chr chr))
                                            (keyboard-layout-name layout)))
                 build))
d><td><a href='/guix/commit/NEWS?id=011dab59d80690d20875d43e73c3cfd8af95af99'>Update NEWS.</a><span class='msg-avail'>...</span></td><td>Maxim Cournoyer</td></tr>
<tr><td><span title='2022-09-14 23:57:56 -0400'>2022-09-14</span></td><td><a href='/guix/commit/NEWS?id=839950c4a9925bf3d7108cb8533be37b185fb8bd'>Update NEWS.</a><span class='msg-avail'>...</span></td><td>Maxim Cournoyer</td></tr>
<tr><td><span title='2021-11-23 10:24:28 +0100'>2021-11-23</span></td><td><a href='/guix/commit/NEWS?id=daf7b5ecef8de0e536ffd8d2957f022d010767a8'>Update NEWS.</a></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-09-23 20:02:23 +0200'>2021-09-23</span></td><td><a href='/guix/commit/NEWS?id=ff775440218c4f576d51aa01ce419b1fb786170a'>Update NEWS.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2021-09-18 23:08:32 +0200'>2021-09-18</span></td><td><a href='/guix/commit/NEWS?id=eb6593cec4b0cedef44bf156e2e6727ead82006c'>Update NEWS.</a></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-07-07 23:54:20 -0400'>2021-07-07</span></td><td><a href='/guix/commit/NEWS?id=4cbe0127a668cbcc64087c5d311308b59d39b104'>guix-install.sh: Prompt for configuring substitutes discovery.</a><span class='msg-avail'>...</span></td><td>Maxim Cournoyer</td></tr>
<tr><td><span title='2021-06-29 14:53:21 -0400'>2021-06-29</span></td><td><a href='/guix/commit/NEWS?id=82daab42811a2e3c7684ebdf12af75ff0fa67b99'>pack: Add support for the deb format.</a><span class='msg-avail'>...</span></td><td>Maxim Cournoyer</td></tr>
<tr><td><span title='2021-05-10 13:48:30 -0400'>2021-05-10</span></td><td><a href='/guix/commit/NEWS?id=80dc6ad4a89b68b5e837fc22c9b1322b86527bef'>Update NEWS.</a></td><td>Maxim Cournoyer</td></tr>
<tr><td><span title='2021-05-10 11:21:02 -0400'>2021-05-10</span></td><td><a href='/guix/commit/NEWS?id=7418a200742768d21b567916b25e4d3351472230'>Update NEWS.</a></td><td>Leo Famulari</td></tr>
<tr><td><span title='2021-05-10 11:42:03 +0200'>2021-05-10</span></td><td><a href='/guix/commit/NEWS?id=3a0fcaa0fe721792d1543e863c3fba805376bdac'>Update NEWS.</a></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-05-04 16:57:05 +0200'>2021-05-04</span></td><td><a href='/guix/commit/NEWS?id=b37ab28401c55adbb8e36ea2931849636752524d'>Update NEWS.</a></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-11-22 20:27:28 +0100'>2020-11-22</span></td><td><a href='/guix/commit/NEWS?id=a099685659b4bfa6b3218f84953cbb7ff9e88063'>Update NEWS.</a></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-11-13 09:13:56 +0100'>2020-11-13</span></td><td><a href='/guix/commit/NEWS?id=1e272d42f6217b70c9801b93e46b144e9ab27664'>Update NEWS.</a></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-11-09 23:27:09 +0100'>2020-11-09</span></td><td><a href='/guix/commit/NEWS?id=b51da3ccef74e5842b87e39eea839e36831e844e'>Update NEWS.</a></td><td>Ludovic Courtès</td></tr>