;; -*-scheme-*-

;; This is an operating system configuration template for a "bare bones
;; development" setup, with no X11 display server.

;; To build a disk image for a virtual machine, do something like:
;;
;;   ./pre-inst-env guix system image --image-type=hurd-qcow2 --image-size=6G \
;;      --no-offload gnu/system/examples/devel-hurd.tmpl
;;
;; You may run it like so
;;
;;     cp /gnu/store/.../disk-image devel-hurd.img
;;     guix shell qemu -- qemu-system-i386 -m 4096                \
;;       --enable-kvm                                             \
;;       --device e1000,netdev=net0                               \
;;       --netdev user,id=net0,hostfwd=tcp:127.0.0.1:10022-:2222  \
;;       --hda devel-hurd.img
;;
;;     ssh -p 10022 root@localhost
;;     guix build -e '(@@ (gnu packages commencement) gnu-make-boot0)'
;;
;; or even:
;;
;;     guix build hello
;;
;; For Guix hacking, do something like:
;;
;;     guix shell --boostrap -D guix
;;     mkdir -p ~/src/guix
;;     cd src/guix
;;     git clone https://git.savannah.gnu.org/git/guix.git master
;;     cd master
;;     ./bootstrap
;;     ./configure
;;     make

(include "bare-hurd.tmpl")

(use-modules (srfi srfi-1)
             (ice-9 match)
             (gnu system hurd)
             (guix packages)
             (guix store))

(use-package-modules base compression file gawk gdb hurd less m4
                     package-management ssh version-control)

(define (input->package input)
  "Return the INPUT as package, or #f."
  (match input
    ((label (and (? package?) package))
     package)
    ((label (and (? package?) package . output))
     (cons package output))
    (_ #f)))

(define guix-packages
  (filter-map input->package
              (fold alist-delete (package-direct-inputs guix)
                    ;; These are not essential and do not build yet.
                    '("graphviz" "guile-avahi" "po4a"))))

(define hurd-packages
  (filter-map input->package
              (fold alist-delete (package-direct-inputs hurd)
                    ;; These are not essential, rumpkernel is very big.
                    '("dde-sources" "parted" "rumpkernel" "util-linux"
                      "texinfo"))))

(define %hurd-devel-os
  (operating-system
    (inherit %hurd-os)
    (bootloader (bootloader-configuration
                 (bootloader grub-minimal-bootloader)
                 (targets '("/dev/sdX"))
                 (timeout 0)))
    (timezone "Europe/Berlin")
    (swap-devices (list (swap-space
                          (target "/swapfile"))))
    (packages (cons*
               gdb-minimal
               git-minimal
               gnu-make
               m4
               openssh-sans-x
               (append
                guix-packages
                hurd-packages
                %base-packages/hurd)))))

%hurd-devel-os
</span></td><td><a href='/guix/commit/m4?id=8e3dfb3d6dfc0f19bd9a9f9b163f0f3d7dccc865'>build: Correct guix_system on musl libc distros.</a><span class='msg-avail'>...<span class='msg-tooltip'>* m4/guix.m4 (GUIX_SYSTEM_TYPE): Add linux-musl* case. This prevents
the macro from mis-parsing the host OS, which causes breakage when
building from source.

Signed-off-by: Ludovic Courtès &lt;ludo@gnu.org&gt;
</span></span></td><td>Antero Mejr</td></tr>

<tr><td><span title='2022-04-29 18:07:17 +0200'>2022-04-29</span></td><td><a href='/guix/commit/tests/publish.scm?id=c1719a0adf3fa7611b56ca4d75b3ac8cf5c9c8ac'>publish: Send uncached narinfo replies from the main thread.</a><span class='msg-avail'>...<span class='msg-tooltip'>Fixes &lt;https://issues.guix.gnu.org/54723&gt;.
Reported by Guillaume Le Vaillant &lt;glv@posteo.net&gt;.

Regression introduced in f743f2046be2c5a338ab871ae8666d8f6de7440b.

With commit f743f2046be2c5a338ab871ae8666d8f6de7440b, responses to
pipelined GETs would end up being written concurrently by many threads.
Thus the body of those responses could be interleaved and garbled.

* guix/scripts/publish.scm: Revert
f743f2046be2c5a338ab871ae8666d8f6de7440b.
* tests/publish.scm ("/*.narinfo pipeline"): New test.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2022-02-14 11:23:56 +0100'>2022-02-14</span></td><td><a href='/guix/commit/tests/publish.scm?id=6adce1538d2df6fa2d68abc13ae94e2fa826d124'>publish: Do not sign the URL/Compression/FileSize narinfo fields.</a><span class='msg-avail'>...<span class='msg-tooltip'>This will allow mirror operators to alter these non-normative bits of a
narinfo without having to resign narinfos.

* guix/scripts/publish.scm (narinfo-string): Remove
URL/Compression/FileSize from BASE-INFO.  Move them after "Signature".
* tests/publish.scm ("/*.narinfo")
("/*.narinfo with properly encoded '+' sign")
("/*.narinfo with lzip + gzip")
("with cache, lzip + gzip"): Adjust accordingly.
* tests/substitute.scm ("query narinfo with signature over relevant subset"):
New test.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2022-01-19 22:07:54 +0100'>2022-01-19</span></td><td><a href='/guix/commit/tests/publish.scm?id=435ffae2f29ecaa94f3aca835d79e222bc1263d5'>tests: Adjust to gzip as the default log compression.</a><span class='msg-avail'>...<span class='msg-tooltip'>This is a followup to 575e52ac2b090fd194086e9c1c53bbf8055acbc2.

* tests/publish.scm ("/log/NAME"): Expect a gzip-encoded log.
</span></span></td><td>Ludovic Courtès</td></tr>