;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017 Sou Bunnbu <iyzsong@member.fsf.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services sysctl)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (gnu packages linux)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:use-module (srfi srfi-1)
  #:use-module (ice-9 match)
  #:export (sysctl-configuration
            sysctl-service-type))


;;;
;;; System Control Service.
;;;

(define-record-type* <sysctl-configuration>
  sysctl-configuration make-sysctl-configuration
  sysctl-configuration?
  (sysctl   sysctl-configuration-sysctl    ; path of the 'sysctl' command
            (default (file-append procps "/sbin/sysctl")))
  (settings sysctl-configuration-settings  ; alist of string pairs
            (default '())))

(define (sysctl-configuration-settings->sysctl.conf settings)
  "Return a file for @command{sysctl} to set kernel parameters as specified by
@var{settings}."
  (apply mixed-text-file "sysctl.conf"
         (append-map (match-lambda
                       ((key . value)
                        (list key "=" value "\n")))
                     settings)))

(define sysctl-shepherd-service
  (match-lambda
    (($ <sysctl-configuration> sysctl settings)
     (let ((sysctl.conf
            (sysctl-configuration-settings->sysctl.conf settings)))
       (shepherd-service
        (documentation "Configure kernel parameters at boot.")
        (provision '(sysctl))
        (start #~(lambda _
                   (zero? (system* #$sysctl "--load" #$sysctl.conf))))
        (one-shot? #t))))))

(define sysctl-service-type
  (service-type
   (name 'sysctl)
   (extensions
    (list (service-extension shepherd-root-service-type
                             (compose list sysctl-shepherd-service))))
   (compose concatenate)
   (extend (lambda (config settings)
             (sysctl-configuration
              (inherit config)
              (settings (append (sysctl-configuration-settings config)
                                settings)))))
   (default-value (sysctl-configuration))))
-07-06</span></td><td><a href='/guix/commit/gnu/installer/services.scm?id=961ffca1c75141cbb351d143b22b673638e9659d'>installer: Restore LatGrkCyr-8x16 console font depending on language.</a><span class='msg-avail'>...<span class='msg-tooltip'>Partially-Fixes: &lt;https://issues.guix.gnu.org/64006&gt;

* gnu/installer/services.scm (system-services-&gt;configuration): When the
LANGUAGE environment variable matches a known native console font, wrap the
base services with modify-services, configuring console-font-service-type to
set the native console font on every tty instead of the default console font.

Signed-off-by: Florian Pelz &lt;pelzflorian@pelzflorian.de&gt;
</span></span></td><td>Denys Nykula</td></tr>
<tr><td><span title='2022-11-20 23:20:31 +0100'>2022-11-20</span></td><td><a href='/guix/commit/gnu/installer/services.scm?id=8c7ea71344b91c2c36dfbf6f2bc6daf559b1c696'>installer: Add comment above the 'packages' field.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/installer/services.scm (system-services-&gt;configuration): Add
heading above the 'packages' field.  Rename 'heading' to
'service-heading'.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2022-08-08 11:54:25 +0200'>2022-08-08</span></td><td><a href='/guix/commit/gnu/installer/services.scm?id=ff9522fb69b9f4a31a5b766029e26dc53a2d1cf8'>installer: Add comments and vertical space to the generated config.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/installer/parted.scm (user-partitions-&gt;configuration): Introduce
vertical space and a comment.
* gnu/installer/services.scm (G_): New macro.
(%system-services): Add comment for OpenSSH.
(system-services-&gt;configuration): Add vertical space and comments.
* gnu/installer/user.scm (users-&gt;configuration): Add comment.
* gnu/installer/steps.scm (format-configuration): Add comment.
(configuration-&gt;file): Expound leading comment.  Pass #:format-comment
to 'pretty-print-with-comments/splice'.
</span></span></td><td>Ludovic Courtès</td></tr>