;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2021 Oleg Pykhalov <go.wigust@gmail.com>
;;; Copyright © 2023 Justin Veilleux <terramorpha@cock.li>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services syncthing)
  #:use-module (gnu packages syncthing)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:use-module (ice-9 match)
  #:use-module (srfi srfi-1)
  #:export (syncthing-configuration
            syncthing-configuration?
            syncthing-service-type))

;;; Commentary:
;;;
;;; This module provides a service definition for the syncthing service.
;;;
;;; Code:

(define-record-type* <syncthing-configuration>
  syncthing-configuration make-syncthing-configuration
  syncthing-configuration?
  (syncthing syncthing-configuration-syncthing ;file-like
             (default syncthing))
  (arguments syncthing-configuration-arguments ;list of strings
             (default '()))
  (logflags  syncthing-configuration-logflags  ;number
             (default 0))
  (user      syncthing-configuration-user      ;string
             (default #f))
  (group     syncthing-configuration-group     ;string
             (default "users"))
  (home      syncthing-configuration-home      ;string
             (default #f))
  (home-service? syncthing-configuration-home-service?
                 (default for-home?) (innate)))

(define syncthing-shepherd-service
  (match-record-lambda <syncthing-configuration>
      (syncthing arguments logflags user group home home-service?)
    (list
     (shepherd-service
      (provision (if home-service?
                     '(syncthing)
                     (list (string->symbol
                            (string-append "syncthing-" user)))))
      (documentation "Run syncthing.")
      (requirement (if home-service? '() '(loopback user-processes)))
      (start #~(make-forkexec-constructor
                (append (list (string-append #$syncthing "/bin/syncthing")
                              "--no-browser"
                              "--no-restart"
                              (string-append "--logflags=" (number->string #$logflags)))
                        '#$arguments)
                #:user #$(and (not home-service?) user)
                #:group #$(and (not home-service?) group)
                #:environment-variables
                (append (list (string-append "HOME=" (or #$home (passwd:dir (getpw #$user))))
                              "SSL_CERT_DIR=/etc/ssl/certs"
                              "SSL_CERT_FILE=/etc/ssl/certs/ca-certificates.crt")
                        (filter (negate       ;XXX: 'remove' is not in (guile)
                                 (lambda (str)
                                   (or (string-prefix? "HOME=" str)
                                       (string-prefix? "SSL_CERT_DIR=" str)
                                       (string-prefix? "SSL_CERT_FILE=" str))))
                                (environ)))))
      (respawn? #f)
      (stop #~(make-kill-destructor))))))

(define syncthing-service-type
  (service-type (name 'syncthing)
                (extensions (list (service-extension shepherd-root-service-type
                                                     syncthing-shepherd-service)))
                (description
                 "Run @uref{https://github.com/syncthing/syncthing, Syncthing}
decentralized continuous file system synchronization.")))

;;; syncthing.scm ends here
er-xwayland: Update to 23.2.5 [security fixes].</a><span class='msg-avail'>...</span></td><td>John Kehayias</td></tr>
<tr><td><span title='2024-03-30 10:02:52 +0100'>2024-03-30</span></td><td><a href='/guix/commit/gnu/packages/xorg.scm?id=72ca1a336ab296187a4d025c399fade63004c780'>Merge branch 'emacs-team'</a></td><td>Liliana Marie Prikler</td></tr>
<tr><td><span title='2024-03-27 05:22:31 +0100'>2024-03-27</span></td><td><a href='/guix/commit/gnu/packages/xorg.scm?id=4c70f5242befb5786cb437559a4d8701e630bd29'>Merge branch 'master' into emacs-team</a></td><td>Liliana Marie Prikler</td></tr>
<tr><td><span title='2024-03-26 08:23:07 +0200'>2024-03-26</span></td><td><a href='/guix/commit/gnu/packages/xorg.scm?id=7dfb3155fc4dd37bea93a8704c37e4aff87e5013'>gnu: xterm: Update to 390.</a><span class='msg-avail'>...</span></td><td>Efraim Flashner</td></tr>
<tr><td><span title='2024-03-10 09:39:39 +0800'>2024-03-10</span></td><td><a href='/guix/commit/gnu/packages/xorg.scm?id=7f1cd8847fb3c7a1c75df0a06e1fa4d298a66cbb'>gnu: xpra: Update to 5.0.7.</a><span class='msg-avail'>...</span></td><td>Andy Tai</td></tr>
<tr><td><span title='2024-03-02 08:07:11 +0100'>2024-03-02</span></td><td><a href='/guix/commit/gnu/packages/xorg.scm?id=3d4fc910f73220f47e5f2459853333a7c83c5d1d'>Merge branch 'master' into emacs-team</a></td><td>Liliana Marie Prikler</td></tr>