;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2021 Oleg Pykhalov <go.wigust@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services syncthing)
  #:use-module (gnu packages syncthing)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:use-module (ice-9 match)
  #:use-module (srfi srfi-1)
  #:export (syncthing-configuration
            syncthing-configuration?
            syncthing-service-type))

;;; Commentary:
;;;
;;; This module provides a service definition for the syncthing service.
;;;
;;; Code:

(define-record-type* <syncthing-configuration>
  syncthing-configuration make-syncthing-configuration
  syncthing-configuration?
  (syncthing syncthing-configuration-syncthing ;<package>
             (default syncthing))
  (arguments syncthing-configuration-arguments ;list of strings
             (default '()))
  (logflags  syncthing-configuration-logflags  ;number
             (default 0))
  (user      syncthing-configuration-user      ;string
             (default #f))
  (group     syncthing-configuration-group     ;string
             (default "users"))
  (home      syncthing-configuration-home      ;string
             (default #f)))

(define syncthing-shepherd-service
  (match-lambda
    (($ <syncthing-configuration> syncthing arguments logflags user group home)
     (list
      (shepherd-service
       (provision (list (string->symbol (string-append "syncthing-" user))))
       (documentation "Run syncthing.")
       (requirement '(loopback))
       (start #~(make-forkexec-constructor
                 (append (list (string-append #$syncthing "/bin/syncthing")
                               "-no-browser"
                               "-no-restart"
                               (string-append "-logflags=" (number->string #$logflags)))
                         '#$arguments)
                 #:user #$user
                 #:group #$group
                 #:environment-variables
                 (append (list (string-append "HOME=" (or #$home (passwd:dir (getpw #$user))))
                               "SSL_CERT_DIR=/etc/ssl/certs"
                               "SSL_CERT_FILE=/etc/ssl/certs/ca-certificates.crt")
                         (remove (lambda (str)
                                   (or (string-prefix? "HOME=" str)
                                       (string-prefix? "SSL_CERT_DIR=" str)
                                       (string-prefix? "SSL_CERT_FILE=" str)))
                                 (environ)))))
       (respawn? #f)
       (stop #~(make-kill-destructor)))))))

(define syncthing-service-type
  (service-type (name 'syncthing)
                (extensions (list (service-extension shepherd-root-service-type
                                                     syncthing-shepherd-service)))
                (description
                 "Run @uref{https://github.com/syncthing/syncthing, Syncthing}
decentralized continuous file system synchronization.")))

;;; syncthing.scm ends here
5</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=21332f3b8cb8f407a89cdfe7d0460a9947675872'>gnu: hpcguix-web: Update to 0.2.0.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-09-26 23:20:56 +0200'>2021-09-26</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=89b05442933d92f4b21c3294455a498e8333727d'>tests: Reduce boilerplate for users of 'system-test-runner'.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-09-25 18:52:05 +0200'>2021-09-25</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=1fb75128a5202b406622da6272bc809c46d1f439'>tests: Adjust to SRFI-64 as found in Guile 3.0.7.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-06-01 14:33:27 +0200'>2021-06-01</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=0b76b25a0eff7a422f8ebcc8c095d7ede82c8863'>tests: hpcguix-web: Fix it.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2021-04-18 09:52:18 +0200'>2021-04-18</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=89af95313d031e1a8a57c6a10f20a636884872b5'>tests: Increase VM memory size.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2021-04-18 09:52:18 +0200'>2021-04-18</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=3b5c4e6fb285e29a6d348732852e0407c28e30f4'>tests: patchwork: Fix it.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2021-04-12 19:12:46 -0400'>2021-04-12</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=c311147bd16aa0e5746d9cbf31502f5fd61e470c'>services: postgresql: Change service default socket directory.</a><span class='msg-avail'>...</span></td><td>Christopher Baines</td></tr>
<tr><td><span title='2021-01-28 12:57:26 +0100'>2021-01-28</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=6c0679215f4ffa534c1eb2e8c8a6e043a0c993fe'>services: postgresql: Add socket directory support.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2020-10-20 22:39:43 +0100'>2020-10-20</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=bdcf4d88d58798eca7811c8b1fbd4638168d05c3'>services: databases: Don't specify a default postgresql version.</a><span class='msg-avail'>...</span></td><td>Christopher Baines</td></tr>
<tr><td><span title='2020-07-13 04:23:43 +0200'>2020-07-13</span></td><td><a href='/guix/commit/gnu/tests/web.scm?id=5cd9cd644ca493b230cb229e7c46641e94a4e2fa'>gnu: tests: Fix unbound variable.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>