;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2018 Arun Isaac <arunisaac@systemreboot.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services security-token)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (gnu packages admin)
  #:use-module (gnu packages base)
  #:use-module (gnu packages security-token)
  #:use-module (gnu system shadow)
  #:use-module (guix gexp)
  #:use-module (guix modules)
  #:use-module (guix records)
  #:use-module (ice-9 match)
  #:use-module (srfi srfi-26)
  #:export (pcscd-configuration
            pcscd-configuration?
            pcscd-configuration-pcsc-lite
            pcscd-configuration-usb-drivers
            pcscd-service-type))

;;;
;;; PC/SC Smart Card Daemon
;;;

(define-record-type* <pcscd-configuration>
  pcscd-configuration make-pcscd-configuration pcscd-configuration?
  (pcsc-lite pcscd-configuration-pcsc-lite
             (default pcsc-lite))
  (usb-drivers pcscd-configuration-usb-drivers
               (default (list ccid))))

(define pcscd-shepherd-service
  (match-lambda
    (($ <pcscd-configuration> pcsc-lite)
     (with-imported-modules (source-module-closure
                             '((gnu build shepherd)))
       (shepherd-service
        (documentation "PC/SC Smart Card Daemon")
        (provision '(pcscd))
        (requirement '(syslogd))
        (modules '((gnu build shepherd)))
        (start #~(lambda _
                   (invoke #$(file-append pcsc-lite "/sbin/pcscd"))
                   (call-with-input-file "/var/run/pcscd/pcscd.pid" read)))
        (stop #~(make-kill-destructor)))))))

(define pcscd-activation
  (match-lambda
    (($ <pcscd-configuration> pcsc-lite usb-drivers)
     (with-imported-modules (source-module-closure
                             '((guix build utils)))
       #~(begin
           (use-modules (guix build utils))
           ;; XXX: We can't use (guix utils) because it requires a
           ;; dynamically-linked Guile, hence the duplicate switch-symlinks.
           (define (switch-symlinks link target)
             (let ((pivot (string-append link ".new")))
               (symlink target pivot)
               (rename-file pivot link)))
           (mkdir-p "/var/lib")
           (switch-symlinks "/var/lib/pcsc"
                            #$(directory-union
                               "pcsc"
                               (map (cut file-append <> "/pcsc")
                                    usb-drivers))))))))

(define pcscd-service-type
  (service-type
   (name 'pcscd)
   (description
    "Run @command{pcscd}, the PC/SC smart card daemon.")
   (extensions
    (list (service-extension shepherd-root-service-type
                             (compose list pcscd-shepherd-service))
          (service-extension activation-service-type
                             pcscd-activation)))
   (default-value (pcscd-configuration))))
512530d8f87e076263227216c467727bb'>installer: Turn help menu into parameters menu.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2020-04-06 15:06:03 +0200'>2020-04-06</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=786c9c39bc0826737e99f0c750ea30033cdbc202'>installer: Add a help page.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2019-04-17 15:16:08 +0200'>2019-04-17</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=9015e63996156dfaafecef182d20128f268c2719'>installer: Sort keyboard layouts according to language and translations.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-04-17 15:11:21 +0200'>2019-04-17</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=feaa83a377966b6cec982f0bbaba1ea15c28d52e'>installer: Translate keyboard layout names.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-03-25 23:37:05 +0100'>2019-03-25</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=3191b5f6ba5ebbb59a7448facd999ad7f7aeae79'>installer: Set the system's 'keyboard-layout' field.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-02-18 01:52:47 +0100'>2019-02-18</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=b83e4a93a2118513cdd2186d796729f0813264c0'>gnu: Fix some typos in the installer.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2019-01-17 14:04:27 +0100'>2019-01-17</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=cb614af01146d9d4be40e705f71db4efcbe684e7'>installer: keymap: Put English layout and international variant ahead.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2019-01-17 14:04:25 +0100'>2019-01-17</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=9e58d4e90e77db150fbc57a559eaa01d85ce03f6'>installer: keymap: Fix keymap selection of layouts with not variant.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2019-01-17 14:04:25 +0100'>2019-01-17</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=7d812901daf0259d5d381199168d6d2994ce00ac'>installer: Turn "Cancel" buttons into "Exit" buttons.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2019-01-17 14:04:24 +0100'>2019-01-17</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=54754efc91e4862f5a904d53a82fcc59e19646a2'>installer: Fix compute calls.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2019-01-17 14:04:23 +0100'>2019-01-17</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=c088b2e47f6675199f1ef545df7d04d4532e64e3'>installer: Do not ask for keyboard model.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2019-01-17 14:04:22 +0100'>2019-01-17</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=5cdb6bd2db0b465fa616a9fd36760b14844d5c48'>installer: Remove "selection" from all titles.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2019-01-17 14:04:20 +0100'>2019-01-17</span></td><td><a href='/guix/commit/gnu/installer/newt/keymap.scm?id=d0f3a672dcbdfefd3556b6a21985ff0e35eed3be'>gnu: Add graphical installer support.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>