;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2018 Arun Isaac <arunisaac@systemreboot.net>
;;; Copyright © 2020 Tobias Geerinckx-Rice <me@tobias.gr>
;;; Copyright © 2021 Brice Waegeneire <brice@waegenei.re>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services security-token)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (gnu packages admin)
  #:use-module (gnu packages base)
  #:use-module (gnu packages security-token)
  #:use-module (gnu system shadow)
  #:use-module (guix gexp)
  #:use-module (guix modules)
  #:use-module (guix records)
  #:use-module (ice-9 match)
  #:use-module (srfi srfi-26)
  #:export (pcscd-configuration
            pcscd-configuration?
            pcscd-configuration-pcsc-lite
            pcscd-configuration-usb-drivers
            pcscd-service-type))

;;;
;;; PC/SC Smart Card Daemon
;;;

(define-record-type* <pcscd-configuration>
  pcscd-configuration make-pcscd-configuration pcscd-configuration?
  (pcsc-lite pcscd-configuration-pcsc-lite
             (default pcsc-lite))
  (usb-drivers pcscd-configuration-usb-drivers
               (default (list ccid))))

(define pcscd-shepherd-service
  (match-lambda
    (($ <pcscd-configuration> pcsc-lite)
     (with-imported-modules (source-module-closure
                             '((gnu build shepherd)))
       (shepherd-service
        (documentation "PC/SC Smart Card Daemon")
        (provision '(pcscd))
        (requirement '(syslogd))
        (modules '((gnu build shepherd)))
        (start #~(lambda _
                   (let ((socket "/run/pcscd/pcscd.comm"))
                     (when (file-exists? socket)
                       (delete-file socket)))
                   (fork+exec-command
                    (list #$(file-append pcsc-lite "/sbin/pcscd")
                          "--foreground")
                    #:log-file "/var/log/pcscd.log")))
        (stop #~(make-kill-destructor)))))))

(define pcscd-activation
  (match-lambda
    (($ <pcscd-configuration> pcsc-lite usb-drivers)
     (with-imported-modules (source-module-closure
                             '((guix build utils)))
       #~(begin
           (use-modules (guix build utils))
           ;; XXX: We can't use (guix utils) because it requires a
           ;; dynamically-linked Guile, hence the duplicate switch-symlinks.
           (define (switch-symlinks link target)
             (let ((pivot (string-append link ".new")))
               (symlink target pivot)
               (rename-file pivot link)))
           (mkdir-p "/var/lib")
           (switch-symlinks "/var/lib/pcsc"
                            #$(directory-union
                               "pcsc"
                               (map (cut file-append <> "/pcsc")
                                    usb-drivers))))))))

(define pcscd-service-type
  (service-type
   (name 'pcscd)
   (description
    "Run @command{pcscd}, the PC/SC smart card daemon.")
   (extensions
    (list (service-extension shepherd-root-service-type
                             (compose list pcscd-shepherd-service))
          (service-extension activation-service-type
                             pcscd-activation)))
   (default-value (pcscd-configuration))))

</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-11-11 00:14:31 +0100'>2021-11-11</span></td><td><a href='/guix/commit/tests/print.scm?id=b2ed40c29f578d46d42cb1c5e99bd797cea3aba0'>import: print: Handle patches that are origins.</a><span class='msg-avail'>...<span class='msg-tooltip'>* guix/import/print.scm (package-&gt;code)[source-&gt;code]: Handle patches
that are origins.
* tests/print.scm (pkg-with-origin-input): Add 'patches' field.
(pkg-with-origin-patch, pkg-with-origin-patch-source): New variables.
("package with origin patch"): New test.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-11-11 00:14:31 +0100'>2021-11-11</span></td><td><a href='/guix/commit/tests/print.scm?id=b3240ae846cb1ace2322a68eca3497f11d0be6f1'>import: print: Correctly handle URI lists.</a><span class='msg-avail'>...<span class='msg-tooltip'>* guix/import/print.scm (package-&gt;code)[factorized-uri-code]: New
procedure.
[source-&gt;code]: Use it, and factorize URI when it's a list.
* tests/print.scm (pkg-with-origin-input): Check origin URI to a list.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-11-11 00:14:31 +0100'>2021-11-11</span></td><td><a href='/guix/commit/tests/print.scm?id=04d929570ad816793d7e0024a11314124ce87f98'>import: print: Properly render packages with origins as inputs.</a><span class='msg-avail'>...<span class='msg-tooltip'>* guix/import/print.scm (package-&gt;code)[source-&gt;code]: Check whether
VERSION is true before calling 'factorize-uri'.
[package-lists-&gt;code]: Add clause for inputs that are origins.
* tests/print.scm (pkg-with-origin-input, pkg-with-origin-input-source):
New variables.
("package with origin input"): New test.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-07-11 00:49:16 +0200'>2021-07-11</span></td><td><a href='/guix/commit/tests/print.scm?id=ff992fcfaf8455910b4bb5e02861fe9ae3dfd974'>import: print: Emit new-style package inputs when possible.</a><span class='msg-avail'>...<span class='msg-tooltip'>* guix/import/print.scm (redundant-input-labels?): New procedure.
(package-&gt;code)[package-lists-&gt;code]: Rename to...
[inputs-&gt;code]: ... this.  When 'redundant-input-labels?' returns true,
emit label-less inputs.  Adjust callers to new name.
* tests/print.scm (pkg-with-inputs): Adjust accordingly.
</span></span></td><td>Ludovic Courtès</td></tr>