;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2019 Oleg Pykhalov <go.wigust@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services nix)
  #:use-module (gnu packages admin)
  #:use-module (gnu packages package-management)
  #:use-module (gnu services base)
  #:use-module (gnu services configuration)
  #:use-module (gnu services shepherd)
  #:use-module (gnu services web)
  #:use-module (gnu services)
  #:use-module (gnu system shadow)
  #:use-module (guix gexp)
  #:use-module (guix packages)
  #:use-module (guix records)
  #:use-module (guix store)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-26)
  #:export (nix-service-type))

;;; Commentary:
;;;
;;; This module provides a service definition for the Nix daemon.
;;;
;;; Code:


;;;
;;; Accounts
;;;

;; Copied from gnu/services/base.scm
(define* (nix-build-accounts count #:key
                             (group "nixbld")
                             (shadow shadow))
  "Return a list of COUNT user accounts for Nix build users with the given
GID."
  (unfold (cut > <> count)
          (lambda (n)
            (user-account
             (name (format #f "nixbld~2,'0d" n))
             (system? #t)
             (group group)
             (supplementary-groups (list group "kvm"))
             (comment (format #f "Nix Build User ~2d" n))
             (home-directory "/var/empty")
             (shell (file-append shadow "/sbin/nologin"))))
          1+
          1))
(define (nix-accounts _)
  "Return the user accounts and user groups."
  (cons (user-group
         (name "nixbld")
         (system? #t)

         ;; Use a fixed GID so that we can create the store with the right
         ;; owner.
         (id 40000))
        (nix-build-accounts 10 #:group "nixbld")))

(define (nix-activation _)
  "Return the activation gexp."
  (with-imported-modules '((guix build utils))
    #~(begin
        (use-modules (guix build utils)
                     (srfi srfi-26))
        (for-each (cut mkdir-p <>) '("/nix/store" "/nix/var/log"
                                     "/nix/var/nix/gcroots/per-user"
                                     "/nix/var/nix/profiles/per-user"))
        (chown "/nix/store"
               (passwd:uid (getpw "root")) (group:gid (getpw "nixbld01")))
        (chmod "/nix/store" #o775)
        (for-each (cut chmod <> #o777) '("/nix/var/nix/profiles"
                                         "/nix/var/nix/profiles/per-user")))))

(define (nix-shepherd-service _)
  "Return a <shepherd-service> for Nix."
  (list
   (shepherd-service
    (provision '(nix-daemon))
    (documentation "Run nix-daemon.")
    (requirement '())
    (start #~(make-forkexec-constructor
              (list (string-append #$nix "/bin/nix-daemon"))))
    (respawn? #f)
    (stop #~(make-kill-destructor)))))

(define nix-service-type
  (service-type
   (name 'nix)
   (extensions
    (list (service-extension shepherd-root-service-type nix-shepherd-service)
          (service-extension account-service-type nix-accounts)
          (service-extension activation-service-type nix-activation)))
   (default-value '())
   (description "Run the Nix daemon.")))

;;; nix.scm ends here
ix/commit/gnu/packages/gps.scm?id=9f3028676cb353d98ae07ad72ceca00af9b9f309'>gnu: gpxsee: Update to 7.16.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2019-10-01 12:06:00 +0200'>2019-10-01</span></td><td><a href='/guix/commit/gnu/packages/gps.scm?id=0cf2b6f2dbcd299f7a4b7a563cf34ae5de154b15'>Merge branch 'master' into core-updates</a></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-09-28 17:23:25 +0200'>2019-09-28</span></td><td><a href='/guix/commit/gnu/packages/gps.scm?id=7b6eabc709cd26a4c29e856797cf2e5378ea5791'>gnu: gpxsee: Update to 7.12.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2019-09-06 20:46:00 -0400'>2019-09-06</span></td><td><a href='/guix/commit/gnu/packages/gps.scm?id=65542a8852759f35e19959149ac92297c8b54be5'>Merge branch 'master' into core-updates</a></td><td>Mark H Weaver</td></tr>
<tr><td><span title='2019-09-05 14:46:42 +0300'>2019-09-05</span></td><td><a href='/guix/commit/gnu/packages/gps.scm?id=6b4ed9ad970ff097c66dff34fe80d75232c86d46'>gnu: gama: Update to 2.07.</a><span class='msg-avail'>...</span></td><td>Efraim Flashner</td></tr>
<tr><td><span title='2019-07-31 14:41:35 +0200'>2019-07-31</span></td><td><a href='/guix/commit/gnu/packages/gps.scm?id=cfad3defb727ff3f0df0382531963911e9d38f1e'>gnu: gpsbabel: Remove GCC 5 workaround.</a><span class='msg-avail'>...</span></td><td>Marius Bakke</td></tr>
<tr><td><span title='2019-07-08 10:38:23 +0300'>2019-07-08</span></td><td><a href='/guix/commit/gnu/packages/gps.scm?id=c7b757c46c91c4c3ddb4b784ae132af119f17ea8'>gnu: gama: Update to 2.06.</a><span class='msg-avail'>...</span></td><td>Efraim Flashner</td></tr>
<tr><td><span title='2019-06-13 13:00:37 +0200'>2019-06-13</span></td><td><a href='/guix/commit/gnu/packages/gps.scm?id=ed8a551653e3d833d3c9cbbd412782acfb26f666'>gnu: gpxsee: Fetch from Git instead of a generated tarball.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-06-13 13:00:37 +0200'>2019-06-13</span></td><td><a href='/guix/commit/gnu/packages/gps.scm?id=286ef5d97c2054c4361f728d2c92587084262e46'>gnu: gpxsee: Upgrade to 7.8</a><span class='msg-avail'>...</span></td><td>Nikolay Korotkiy</td></tr>
<tr><td><span title='2019-05-13 14:16:48 +0200'>2019-05-13</span></td><td><a href='/guix/commit/gnu/packages/gps.scm?id=2508b075174bf0b3f81609e89490f9116eb69aeb'>gnu: gpscorrelate: Update home page.</a><span class='msg-avail'>...</span></td><td>Marius Bakke</td></tr>