;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 Alex Kost <alezost@gmail.com>
;;; Copyright © 2015 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services lirc)
  #:use-module (gnu services)
  #:use-module (gnu services dmd)
  #:use-module (gnu packages lirc)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:use-module (ice-9 match)
  #:export (lirc-service))

;;; Commentary:
;;;
;;; LIRC service.
;;;
;;; Code:

(define-record-type* <lirc-configuration>
  lirc-configuration make-lirc-configuration
  lirc-configuation?
  (lirc          lirc-configuration-lirc          ;<package>
                 (default lirc))
  (device        lirc-configuration-device)       ;string
  (driver        lirc-configuration-driver)       ;string
  (config-file   lirc-configuration-file)         ;string | file-like object
  (extra-options lirc-configuration-options       ;list of strings
                 (default '())))

(define %lirc-activation
  #~(begin
      (use-modules (guix build utils))
      (mkdir-p "/var/run/lirc")))

(define lirc-dmd-service
  (match-lambda
    (($ <lirc-configuration> lirc device driver config-file options)
     (list (dmd-service
            (provision '(lircd))
            (documentation "Run the LIRC daemon.")
            (requirement '(user-processes))
            (start #~(make-forkexec-constructor
                      (list (string-append #$lirc "/sbin/lircd")
                            "--nodaemon"
                            #$@(if device
                                   #~("--device" #$device)
                                   #~())
                            #$@(if driver
                                   #~("--driver" #$driver)
                                   #~())
                            #$@(if config-file
                                   #~(#$config-file)
                                   #~())
                            #$@options)))
            (stop #~(make-kill-destructor)))))))

(define lirc-service-type
  (service-type (name 'lirc)
                (extensions
                 (list (service-extension dmd-root-service-type
                                          lirc-dmd-service)
                       (service-extension activation-service-type
                                          (const %lirc-activation))))))

(define* (lirc-service #:key (lirc lirc)
                       device driver config-file
                       (extra-options '()))
  "Return a service that runs @url{http://www.lirc.org,LIRC}, a daemon that
decodes infrared signals from remote controls.

The daemon will use specified @var{device}, @var{driver} and
@var{config-file} (configuration file name).

Finally, @var{extra-options} is a list of additional command-line options
passed to @command{lircd}."
  (service lirc-service-type
           (lirc-configuration
            (lirc lirc)
            (device device) (driver driver)
            (config-file config-file)
            (extra-options extra-options))))

;;; lirc.scm ends here
</span></td><td><a href='/guix/commit/gnu/packages/xfig.scm?id=dd36ca07f0f6ee5adf1629f4dd56702755683e72'>gnu: Add fig2dev.</a><span class='msg-avail'>...<span class='msg-tooltip'>The source used by the transfig package is outdated and its development
was moved into the repository used by fig2dev though the utility
`transfig' is considered obsolete and not built by default in the
fig2dev package.  In practice, this is not a problem since the user is
generally after the `fig2dev' utility which was also provided in the
(now obsolete) transfig package.

Descriptions and comments pointing to the now obsolete packages are
adjusted accordingly.  For texlive-latex-make, this follow upstream at
&lt;https://gitlab.inria.fr/latex-utils/latex-make/-/commit/1dcc04aaa860b123924ae83fc30a47d6f7179f7a&gt;.

* gnu/packages/xfig.scm: Import all of (guix licenses).
(xfig)[license]: Adjust accordingly.
(fig2dev): New variable.
(transfig): Deprecate in favor of fig2dev.
* gnu/packages/patches/transfig-gcc10-fno-common.patch: Removed file.
* gnu/local.mk (dist_patch_DATA): Unregister it.
* gnu/packages/docbook.scm (dblatex): Update comment.
* gnu/packages/tex.scm (texlive-latex-make)[description]: Update description.

Signed-off-by: Liliana Marie Prikler &lt;liliana.prikler@gmail.com&gt;
</span></span></td><td>Bruno Victal</td></tr>
<tr><td><span title='2023-10-01 08:14:55 +0200'>2023-10-01</span></td><td><a href='/guix/commit/gnu/packages/xfig.scm?id=8c0146514298621b9307e7627839b2be80e46a26'>gnu: xfig: Use G-Expressions.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/packages/xfig.scm (xfig)[arguments]&lt;#:phases&gt;: Relocate
'strip-bogus-exec-prefix into …
[sources]: … here, as a snippet instead.
[inputs]: Restyle.

Signed-off-by: Liliana Marie Prikler &lt;liliana.prikler@gmail.com&gt;
</span></span></td><td>Bruno Victal</td></tr>