;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 Alex Kost <alezost@gmail.com>
;;; Copyright © 2015, 2016, 2022 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services lirc)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (gnu packages lirc)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:use-module (ice-9 match)
  #:export (lirc-configuration
            lirc-configuation?
            lirc-service
            lirc-service-type))

;;; Commentary:
;;;
;;; LIRC service.
;;;
;;; Code:

(define-record-type* <lirc-configuration>
  lirc-configuration make-lirc-configuration
  lirc-configuation?
  (lirc          lirc-configuration-lirc          ;file-like
                 (default lirc))
  (device        lirc-configuration-device)       ;string
  (driver        lirc-configuration-driver)       ;string
  (config-file   lirc-configuration-file)         ;string | file-like object
  (extra-options lirc-configuration-options       ;list of strings
                 (default '())))

(define %lirc-activation
  #~(begin
      (use-modules (guix build utils))
      (mkdir-p "/var/run/lirc")))

(define lirc-shepherd-service
  (match-lambda
    (($ <lirc-configuration> lirc device driver config-file options)
     (list (shepherd-service
            (provision '(lircd))
            (documentation "Run the LIRC daemon.")
            (requirement '(user-processes))
            (start #~(make-forkexec-constructor
                      (list (string-append #$lirc "/sbin/lircd")
                            "--nodaemon"
                            #$@(if device
                                   #~("--device" #$device)
                                   #~())
                            #$@(if driver
                                   #~("--driver" #$driver)
                                   #~())
                            #$@(if config-file
                                   #~(#$config-file)
                                   #~())
                            #$@options)))
            (stop #~(make-kill-destructor)))))))

(define lirc-service-type
  (service-type (name 'lirc)
                (extensions
                 (list (service-extension shepherd-root-service-type
                                          lirc-shepherd-service)
                       (service-extension activation-service-type
                                          (const %lirc-activation))))
                (description "Run LIRC, a daemon that decodes infrared signals
from remote controls.")))

(define* (lirc-service #:key (lirc lirc)
                       device driver config-file
                       (extra-options '()))
  "Return a service that runs @url{http://www.lirc.org,LIRC}, a daemon that
decodes infrared signals from remote controls.

The daemon will use specified @var{device}, @var{driver} and
@var{config-file} (configuration file name).

Finally, @var{extra-options} is a list of additional command-line options
passed to @command{lircd}."
  (service lirc-service-type
           (lirc-configuration
            (lirc lirc)
            (device device) (driver driver)
            (config-file config-file)
            (extra-options extra-options))))

;;; lirc.scm ends here
ix/commit/gnu/build/hurd-boot.scm?id=44e65a75886282a01001179e01bff2b9e957eb0a'>hurd-boot: Create /servers/crash.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-06-27 13:01:40 +0200'>2020-06-27</span></td><td><a href='/guix/commit/gnu/build/hurd-boot.scm?id=65d95e5d852e47343b9acc1717918c9db7364c01'>hurd-boot: Mount /proc, add /etc/mtab.</a><span class='msg-avail'>...</span></td><td>Jan (janneke) Nieuwenhuizen</td></tr>
<tr><td><span title='2020-06-27 12:59:40 +0200'>2020-06-27</span></td><td><a href='/guix/commit/gnu/build/hurd-boot.scm?id=db08a0d2031469f63c8520ce604d2cbf2b4b980b'>hurd-boot: Remove duplicate calls to 'scope'.</a><span class='msg-avail'>...</span></td><td>Jan (janneke) Nieuwenhuizen</td></tr>
<tr><td><span title='2020-06-19 10:40:53 +0200'>2020-06-19</span></td><td><a href='/guix/commit/gnu/build/hurd-boot.scm?id=f25e8f76fec03e5a31c221e7427d6962ece1aa67'>hurd-boot: Use 'setxattr' instead of invoking settrans.</a><span class='msg-avail'>...</span></td><td>Jan (janneke) Nieuwenhuizen</td></tr>
<tr><td><span title='2020-06-19 10:38:26 +0200'>2020-06-19</span></td><td><a href='/guix/commit/gnu/build/hurd-boot.scm?id=951847ee3792f8fa57d2bd38d84d9fa9c276c0fa'>hurd-boot: Create individual translators instead of running MAKEDEV.</a><span class='msg-avail'>...</span></td><td>Jan (janneke) Nieuwenhuizen</td></tr>
<tr><td><span title='2020-06-08 14:26:14 +0200'>2020-06-08</span></td><td><a href='/guix/commit/gnu/build/hurd-boot.scm?id=68d8c094659565fe19abc1c433a17337ce5cacb7'>gnu: services: Add %hurd-startup-service.</a><span class='msg-avail'>...</span></td><td>Jan (janneke) Nieuwenhuizen</td></tr>
<tr><td><span title='2020-06-08 14:26:14 +0200'>2020-06-08</span></td><td><a href='/guix/commit/gnu/build/hurd-boot.scm?id=b37c544196898cc3dfa3da07ed344fbe11abc120'>hurd-boot: Further cleanup of "rc".</a><span class='msg-avail'>...</span></td><td>Jan (janneke) Nieuwenhuizen</td></tr>