;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 Alex Kost <alezost@gmail.com>
;;; Copyright © 2015, 2016 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services lirc)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (gnu packages lirc)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:use-module (ice-9 match)
  #:export (lirc-configuration
            lirc-configuation?
            lirc-service
            lirc-service-type))

;;; Commentary:
;;;
;;; LIRC service.
;;;
;;; Code:

(define-record-type* <lirc-configuration>
  lirc-configuration make-lirc-configuration
  lirc-configuation?
  (lirc          lirc-configuration-lirc          ;<package>
                 (default lirc))
  (device        lirc-configuration-device)       ;string
  (driver        lirc-configuration-driver)       ;string
  (config-file   lirc-configuration-file)         ;string | file-like object
  (extra-options lirc-configuration-options       ;list of strings
                 (default '())))

(define %lirc-activation
  #~(begin
      (use-modules (guix build utils))
      (mkdir-p "/var/run/lirc")))

(define lirc-shepherd-service
  (match-lambda
    (($ <lirc-configuration> lirc device driver config-file options)
     (list (shepherd-service
            (provision '(lircd))
            (documentation "Run the LIRC daemon.")
            (requirement '(user-processes))
            (start #~(make-forkexec-constructor
                      (list (string-append #$lirc "/sbin/lircd")
                            "--nodaemon"
                            #$@(if device
                                   #~("--device" #$device)
                                   #~())
                            #$@(if driver
                                   #~("--driver" #$driver)
                                   #~())
                            #$@(if config-file
                                   #~(#$config-file)
                                   #~())
                            #$@options)))
            (stop #~(make-kill-destructor)))))))

(define lirc-service-type
  (service-type (name 'lirc)
                (extensions
                 (list (service-extension shepherd-root-service-type
                                          lirc-shepherd-service)
                       (service-extension activation-service-type
                                          (const %lirc-activation))))))

(define* (lirc-service #:key (lirc lirc)
                       device driver config-file
                       (extra-options '()))
  "Return a service that runs @url{http://www.lirc.org,LIRC}, a daemon that
decodes infrared signals from remote controls.

The daemon will use specified @var{device}, @var{driver} and
@var{config-file} (configuration file name).

Finally, @var{extra-options} is a list of additional command-line options
passed to @command{lircd}."
  (service lirc-service-type
           (lirc-configuration
            (lirc lirc)
            (device device) (driver driver)
            (config-file config-file)
            (extra-options extra-options))))

;;; lirc.scm ends here
Remove key-mon.scm.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2023-01-05 08:14:55 +0100'>2023-01-05</span></td><td><a href='/guix/commit/po/packages?id=dc7eb6f07ae982b4c9d083cfb10f72cb031c0424'>nls: Update translations.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-12-04 22:25:23 +0100'>2022-12-04</span></td><td><a href='/guix/commit/po/packages?id=2e75b328b6bbdadbffe5b643a4891b5026a0defd'>nls: Update translations.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-11-20 16:01:08 +0100'>2022-11-20</span></td><td><a href='/guix/commit/po/packages?id=da6c6763fa72585a1df3021781f8d33c3b64dcc8'>scripts: Use translations for guix.pot for service descriptions.</a><span class='msg-avail'>...</span></td><td>pelzflorian (Florian Pelz)</td></tr>
<tr><td><span title='2022-11-04 10:56:38 +0100'>2022-11-04</span></td><td><a href='/guix/commit/po/packages?id=a65ce9dd500460af4f97e7398fb35dd817f4c677'>nls: Update translations.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-10-06 08:20:20 +0200'>2022-10-06</span></td><td><a href='/guix/commit/po/packages?id=70fc8f6d619ce9f16a8cc0bbb10a011bd3a9997a'>nls: Update translations.</a></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-09-04 16:52:02 +0200'>2022-09-04</span></td><td><a href='/guix/commit/po/packages?id=77e3042aef6d8e519d016555464e466399318b4f'>nls: Update translations.</a></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-08-16 21:25:25 +0200'>2022-08-16</span></td><td><a href='/guix/commit/po/packages?id=37cd5536797450e18ffd5a54595a3453a8a8154f'>ui: Describe package outputs.</a><span class='msg-avail'>...</span></td><td>Liliana Marie Prikler</td></tr>
<tr><td><span title='2022-08-10 23:32:24 +0200'>2022-08-10</span></td><td><a href='/guix/commit/po/packages?id=aacbe59fbceb8a93ecb68fed8581dfdd70dafc11'>nls: Update translations.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-07-09 21:49:34 +0200'>2022-07-09</span></td><td><a href='/guix/commit/po/packages?id=e0d47d8facafb6d6c04741bbf30eefbc68aaefb9'>nls: Update translations.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-06-04 17:42:54 +0200'>2022-06-04</span></td><td><a href='/guix/commit/po/packages?id=809c57c872a6dd48007d1abf6d7f3dd1482ec53a'>nls: Update translations.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-05-01 18:07:34 +0200'>2022-05-01</span></td><td><a href='/guix/commit/po/packages?id=6b4124cdcc203d47dc40158062afa1497d73d592'>nls: Update translations.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-04-02 18:42:36 +0200'>2022-04-02</span></td><td><a href='/guix/commit/po/packages?id=8a208df17fe81fbf34f5a86cc52bb0b8e33c7b96'>nls: Update translations.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>