;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 Alex Kost <alezost@gmail.com>
;;; Copyright © 2015, 2016 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services lirc)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (gnu packages lirc)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:use-module (ice-9 match)
  #:export (lirc-configuration
            lirc-configuation?
            lirc-service
            lirc-service-type))

;;; Commentary:
;;;
;;; LIRC service.
;;;
;;; Code:

(define-record-type* <lirc-configuration>
  lirc-configuration make-lirc-configuration
  lirc-configuation?
  (lirc          lirc-configuration-lirc          ;<package>
                 (default lirc))
  (device        lirc-configuration-device)       ;string
  (driver        lirc-configuration-driver)       ;string
  (config-file   lirc-configuration-file)         ;string | file-like object
  (extra-options lirc-configuration-options       ;list of strings
                 (default '())))

(define %lirc-activation
  #~(begin
      (use-modules (guix build utils))
      (mkdir-p "/var/run/lirc")))

(define lirc-shepherd-service
  (match-lambda
    (($ <lirc-configuration> lirc device driver config-file options)
     (list (shepherd-service
            (provision '(lircd))
            (documentation "Run the LIRC daemon.")
            (requirement '(user-processes))
            (start #~(make-forkexec-constructor
                      (list (string-append #$lirc "/sbin/lircd")
                            "--nodaemon"
                            #$@(if device
                                   #~("--device" #$device)
                                   #~())
                            #$@(if driver
                                   #~("--driver" #$driver)
                                   #~())
                            #$@(if config-file
                                   #~(#$config-file)
                                   #~())
                            #$@options)))
            (stop #~(make-kill-destructor)))))))

(define lirc-service-type
  (service-type (name 'lirc)
                (extensions
                 (list (service-extension shepherd-root-service-type
                                          lirc-shepherd-service)
                       (service-extension activation-service-type
                                          (const %lirc-activation))))))

(define* (lirc-service #:key (lirc lirc)
                       device driver config-file
                       (extra-options '()))
  "Return a service that runs @url{http://www.lirc.org,LIRC}, a daemon that
decodes infrared signals from remote controls.

The daemon will use specified @var{device}, @var{driver} and
@var{config-file} (configuration file name).

Finally, @var{extra-options} is a list of additional command-line options
passed to @command{lircd}."
  (service lirc-service-type
           (lirc-configuration
            (lirc lirc)
            (device device) (driver driver)
            (config-file config-file)
            (extra-options extra-options))))

;;; lirc.scm ends here
es.guix.gnu.org/52940&gt;.

* tests/gremlin.scm (file-needed/recursive): Consider two entries to be
equivalent not when they are the same string, but rather when they refer to
the same file.
[ground-truth]: In addition to strings that begin with "linux-vdso.so", remove
strings that begin with "linux-vdso64.so".
</span></span></td><td>Chris Marusich</td></tr>
<tr><td><span title='2021-06-23 20:30:22 -0700'>2021-06-23</span></td><td><a href='/guix/commit/tests/gremlin.scm?id=e4b5a23841bc6a92e2e21dd8b1038addee55eb02'>tests: gremlin: Skip file-needed/recursive if DT_NEEDED is empty.</a><span class='msg-avail'>...<span class='msg-tooltip'>* tests/gremlin.scm (file-needed/recursive): Skip the test when (file-runpath
%guile-executable) evaluates to the empty list.  This causes the test to be
correctly skipped in the case where Guix has been built using a foreign
distro's toolchain and libraries.
</span></span></td><td>Chris Marusich</td></tr>
<tr><td><span title='2021-04-22 14:04:27 +0200'>2021-04-22</span></td><td><a href='/guix/commit/tests/gremlin.scm?id=1010171280cb34c8dc361644b66fdd1a041d297a'>gremlin: 'elf-dynamic-info' returns a file name rathern than a dynamic entry.</a><span class='msg-avail'>...<span class='msg-tooltip'>* guix/build/gremlin.scm (elf-dynamic-info): Return the dynamic entry
value, not the dynamic entry.
* tests/gremlin.scm ("elf-dynamic-info-soname"): New test.

Signed-off-by: Ludovic Courtès &lt;ludo@gnu.org&gt;
</span></span></td><td>Dion Mendel</td></tr>
<tr><td><span title='2020-12-01 21:30:28 +0100'>2020-12-01</span></td><td><a href='/guix/commit/tests/gremlin.scm?id=53fd256e5ba43e516fb9d6eaf085b88fe8bd12b6'>gremlin: Add 'file-needed/recursive'.</a><span class='msg-avail'>...<span class='msg-tooltip'>* guix/build/gremlin.scm (file-needed/recursive): New procedure.
* tests/gremlin.scm ("file-needed/recursive"): New test.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-09-19 17:28:46 +0200'>2020-09-19</span></td><td><a href='/guix/commit/tests/gremlin.scm?id=49a1203d67a90a6a7ce4e4537697a6da96ceb213'>gremlin: Add 'set-file-runpath', 'file-runpath', and 'file-needed'.</a><span class='msg-avail'>...<span class='msg-tooltip'>* guix/build/gremlin.scm (file-dynamic-info, file-runpath, file-needed):
New procedures.
(&amp;missing-runpath-error, &amp;runpath-too-long-error): New condition types.
(set-file-runpath): New procedure.
* tests/gremlin.scm ("set-file-runpath + file-runpath"): New test.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-05-18 12:10:15 +0200'>2019-05-18</span></td><td><a href='/guix/commit/tests/gremlin.scm?id=6b97415996583b15a97dad8254f610275353e913'>gremlin: Adjust tests for foreign distros.</a><span class='msg-avail'>...<span class='msg-tooltip'>Fixes &lt;https://bugs.gnu.org/35775&gt;.

* tests/gremlin.scm ("elf-dynamic-info-needed, executable"): Expect only
libguile and libc among NEEDED.
("strip-runpath"): Pass '--enable-new-dtags' to get RUNPATH, not RPATH.
</span></span></td><td>Ting-Wei Lan</td></tr>