;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2020 Jan (janneke) Nieuwenhuizen <janneke@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services hurd)
  #:use-module (gnu packages admin)
  #:use-module (gnu packages hurd)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (gnu system)
  #:use-module (guix gexp)
  #:use-module (guix records)
  #:export (hurd-console-configuration
            hurd-console-service-type
            hurd-getty-configuration
            hurd-getty-service-type))

;;; Commentary:
;;;
;;; This module implements services for the Hurd.
;;;
;;; Code:

;;;
;;; The Hurd VGA console service.
;;;

(define-record-type* <hurd-console-configuration>
  hurd-console-configuration make-hurd-console-configuration
  hurd-console-configuration?
  (hurd   hurd-console-configuration-hurd ;package
          (default hurd)))

(define (hurd-console-shepherd-service config)
  "Return a <shepherd-service> for a Hurd VGA console with CONFIG."

  (define console-command
    #~(list
       (string-append #$(hurd-console-configuration-hurd config) "/bin/console")
       "-c" "/dev/vcs"
       "-d" "vga"
       "-d" "pc_kbd"
       "-d" "generic_speaker"))

  (list (shepherd-service
         (documentation "Run the Hurd’s VGA console client.")
         (provision '(console))
         (requirement '(user-processes))
         (start #~(make-forkexec-constructor #$console-command))
         (stop #~(make-kill-destructor)))))

(define hurd-console-service-type
  (service-type
   (name 'console)
   (description "Run the Hurd console client.")
   (extensions
    (list (service-extension shepherd-root-service-type
                             hurd-console-shepherd-service)))
   (default-value (hurd-console-configuration))))


;;;
;;; The Hurd getty service.
;;;

(define-record-type* <hurd-getty-configuration>
  hurd-getty-configuration make-hurd-getty-configuration
  hurd-getty-configuration?
  (hurd       hurd-getty-configuration-hurd  ;<package>
              (default hurd))
  (tty        hurd-getty-configuration-tty)  ;string
  (baud-rate  hurd-getty-configuration-baud-rate
              (default 38400)))              ;integer

(define (hurd-getty-shepherd-service config)
  "Return a <shepherd-service> for a Hurd getty with CONFIG."

  (let ((hurd      (hurd-getty-configuration-hurd config))
        (tty       (hurd-getty-configuration-tty config))
        (baud-rate (hurd-getty-configuration-baud-rate config)))

    (define getty-command
      #~(list
         (string-append #$hurd "/libexec/getty")
         #$(number->string baud-rate)
         #$tty))

    (list
     (shepherd-service
      (documentation "Run getty on a tty.")
      (provision (list (string->symbol (string-append "term-" tty))))
      (requirement '(user-processes console))
      (start #~(make-forkexec-constructor #$getty-command))
      (stop  #~(make-kill-destructor))))))

(define hurd-getty-service-type
  (service-type
   (name 'getty)
   (extensions (list (service-extension shepherd-root-service-type
                                        hurd-getty-shepherd-service)))
   (description
    "Provide console login using the Hurd @command{getty} program.")))

;;; hurd.scm ends here
rg&gt;</td><td class='right'>2023-05-25 07:25:26 +0200</td></tr>
<tr><th>committer</th><td>Josselin Poiret &lt;dev@jpoiret.xyz&gt;</td><td class='right'>2023-07-13 18:59:22 +0200</td></tr>
<tr><th>commit</th><td colspan='2' class='oid'><a href='/guix/commit/gnu/home/services?id=37256c02a2b2b54378b19a31765e1e42aa3ff514'>37256c02a2b2b54378b19a31765e1e42aa3ff514</a> (<a href='/guix/patch/gnu/home/services?id=37256c02a2b2b54378b19a31765e1e42aa3ff514'>patch</a>)</td></tr>
<tr><th>tree</th><td colspan='2' class='oid'><a href='/guix/tree/?id=37256c02a2b2b54378b19a31765e1e42aa3ff514'>8b6837ccf7c3d244ce3e6c3dfb197c02fbcfc5f0</a> /<a href='/guix/tree/gnu/home/services?id=37256c02a2b2b54378b19a31765e1e42aa3ff514'>gnu/home/services</a></td></tr>
<tr><th>parent</th><td colspan='2' class='oid'><a href='/guix/commit/gnu/home/services?id=bbfb41ed9dff845e12ebd597026729f637903ac4'>bbfb41ed9dff845e12ebd597026729f637903ac4</a> (<a href='/guix/diff/gnu/home/services?id=37256c02a2b2b54378b19a31765e1e42aa3ff514&amp;id2=bbfb41ed9dff845e12ebd597026729f637903ac4'>diff</a>)</td></tr><tr><th>download</th><td colspan='2' class='oid'><a href='/guix/snapshot/guix-37256c02a2b2b54378b19a31765e1e42aa3ff514.tar.gz'>guix-37256c02a2b2b54378b19a31765e1e42aa3ff514.tar.gz</a><br/><a href='/guix/snapshot/guix-37256c02a2b2b54378b19a31765e1e42aa3ff514.zip'>guix-37256c02a2b2b54378b19a31765e1e42aa3ff514.zip</a><br/></td></tr></table>
<div class='commit-subject'>gnu: netdde: Resurrect and update to 2.6.32.65-2-e67c284ac1.</div><div class='commit-msg'>* gnu/packages/patches/netdde-build-fix.patch: New file.
* gnu/local.mk (dist_patch_DATA): Add it.
* gnu/packages/hurd.scm (netdde)[source]: Update to
e67c284ac113d939b10b4578334f27dab29d5b08 and use it.
[inputs]: Add zlib:static.
[arguments]: Remove #true from build phases.  In 'build' phase, remove
obsolete CFLAGS, and also build static version.  In 'install' phase,
install them in &lt;out&gt;/hurd.  There is no check target, so set #:tests?
to #false.

Signed-off-by: Josselin Poiret &lt;dev@jpoiret.xyz&gt;
</div><div class='diffstat-header'><a href='/guix/diff/?id=37256c02a2b2b54378b19a31765e1e42aa3ff514'>Diffstat</a> (limited to 'gnu/home/services')</div><table summary='diffstat' class='diffstat'></table><div class='diffstat-summary'>0 files changed, 0 insertions, 0 deletions</div><table summary='diff' class='diff'><tr><td></td></tr></table></div> <!-- class=content -->
                         <div class=footer>generated by
                             <a href="https://git.zx2c4.com/cgit/about/">
                                 cgit
                             </a>
                         </div>
                        </div> <!-- id=cgit -->
</body>
</html>