;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2018 Arun Isaac <arunisaac@systemreboot.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu services games)
  #:use-module (gnu services)
  #:use-module (gnu services shepherd)
  #:use-module (gnu packages admin)
  #:use-module (gnu packages games)
  #:use-module (gnu system shadow)
  #:use-module (guix gexp)
  #:use-module (guix modules)
  #:use-module (guix records)
  #:use-module (ice-9 match)
  #:export (wesnothd-configuration
            wesnothd-configuration?
            wesnothd-service-type))

;;;
;;; The Battle for Wesnoth server
;;;

(define-record-type* <wesnothd-configuration>
  wesnothd-configuration make-wesnothd-configuration wesnothd-configuration?
  (package wesnothd-configuration-package
           (default wesnoth-server))
  (port wesnothd-configuration-port
        (default 15000)))

(define %wesnothd-accounts
  (list (user-account
         (name "wesnothd")
         (group "wesnothd")
         (system? #t)
         (comment "Wesnoth daemon user")
         (home-directory "/var/empty")
         (shell (file-append shadow "/sbin/nologin")))
        (user-group
         (name "wesnothd")
         (system? #t))))

(define wesnothd-shepherd-service
  (match-lambda
    (($ <wesnothd-configuration> package port)
     (with-imported-modules (source-module-closure
                             '((gnu build shepherd)))
       (shepherd-service
        (documentation "The Battle for Wesnoth server")
        (provision '(wesnoth-daemon))
        (requirement '(networking))
        (modules '((gnu build shepherd)))
        (start #~(make-forkexec-constructor/container
                  (list #$(file-append package "/bin/wesnothd")
                        "-p" #$(number->string port))
                  #:user "wesnothd" #:group "wesnothd"))
        (stop #~(make-kill-destructor)))))))

(define wesnothd-service-type
  (service-type
   (name 'wesnothd)
   (description
    "Run The Battle for Wesnoth server @command{wesnothd}.")
   (extensions
    (list (service-extension account-service-type
                             (const %wesnothd-accounts))
          (service-extension shepherd-root-service-type
                             (compose list wesnothd-shepherd-service))))
   (default-value (wesnothd-configuration))))
tès</td></tr>
<tr><td><span title='2019-01-01 18:57:56 +0300'>2019-01-01</span></td><td><a href='/guix/commit/gnu/tests/monitoring.scm?id=8b6c91ba538f87d519ffa1d5d3fc3324fdaac85f'>gnu: php-with-bcmath: Deprecate in favour of 'php'.</a><span class='msg-avail'>...</span></td><td>Oleg Pykhalov</td></tr>
<tr><td><span title='2018-12-17 22:09:11 +0300'>2018-12-17</span></td><td><a href='/guix/commit/gnu/tests/monitoring.scm?id=85c07cff9cd2197a16c2d3544e4930e278513cf7'>services: monitoring: Add 'zabbix-front-end'.</a><span class='msg-avail'>...</span></td><td>Oleg Pykhalov</td></tr>
<tr><td><span title='2018-12-17 22:09:10 +0300'>2018-12-17</span></td><td><a href='/guix/commit/gnu/tests/monitoring.scm?id=6106d7cae49fb6686a237b53d465c89211ecad8f'>services: monitoring: Add 'zabbix-agent'.</a><span class='msg-avail'>...</span></td><td>Oleg Pykhalov</td></tr>
<tr><td><span title='2018-12-17 22:09:10 +0300'>2018-12-17</span></td><td><a href='/guix/commit/gnu/tests/monitoring.scm?id=6b1c4179e2596d860b1c49dea8021bc39d28da67'>services: monitoring: Add 'zabbix-server'.</a><span class='msg-avail'>...</span></td><td>Oleg Pykhalov</td></tr>
<tr><td><span title='2018-10-18 01:12:22 +0200'>2018-10-18</span></td><td><a href='/guix/commit/gnu/tests/monitoring.scm?id=39d7fdce453b0ca23ecbed72048647debbaa58a6'>services: dhcp-client: Deprecate 'dhcp-client-service' procedure.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-07-09 10:39:06 +0200'>2018-07-09</span></td><td><a href='/guix/commit/gnu/tests/monitoring.scm?id=a33652ee336ae9a5d2ab5fd54bf2397caec42a0e'>services: Add prometheus-node-exporter-service-type.</a><span class='msg-avail'>...</span></td><td>Gábor Boskovits</td></tr>