;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2013 Andreas Enge <andreas@enge.fr>
;;; Copyright © 2017 Efraim Flashner <efraim@flashner.co.il>
;;; Copyright © 2018 Tobias Geerinckx-Rice <me@tobias.gr>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu packages lsof)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix packages)
  #:use-module (guix download)
  #:use-module (guix build-system gnu)
  #:use-module (gnu packages perl))

(define-public lsof
  (package
   (name "lsof")
   (version "4.91")
   (source
    (origin
      (method url-fetch)
      (uri
       (apply append
              (map
               (lambda (mirror-uri)
                 (let ((tarball (string-append name "_" version ".tar.bz2")))
                   (list
                    (string-append mirror-uri "/" tarball)
                    ;; Upon every new release, the previous one is moved here:
                    (string-append mirror-uri "/OLD/" tarball))))
               (list
                "ftp://lsof.itap.purdue.edu/pub/tools/unix/lsof/"

                ;; Add mirrors because the canonical FTP server at purdue.edu
                ;; bails out when it cannot do a reverse DNS lookup, as noted
                ;; at <http://people.freebsd.org/~abe/>.
                "ftp://ftp.fu-berlin.de/pub/unix/tools/lsof/"
                (string-append "http://www.mirrorservice.org/sites/"
                               "lsof.itap.purdue.edu/pub/tools/unix/lsof")
                (string-append "ftp://ftp.mirrorservice.org/sites/"
                               "lsof.itap.purdue.edu/pub/tools/unix/lsof")))))
      (sha256
       (base32 "18sh4hbl9jw2szkf0gvgan8g13f3g4c6s2q9h3zq5gsza9m99nn9"))))
   (build-system gnu-build-system)
   (native-inputs `(("perl" ,perl)))
   (arguments
    `(#:phases
      (modify-phases %standard-phases
        (replace 'unpack
          (lambda* (#:key source #:allow-other-keys)
            (let ((unpack (assoc-ref %standard-phases 'unpack)))
              (unpack #:source source)
              (unpack #:source (car (find-files "." "\\.tar$"))))))
        (replace 'configure
          (lambda _
            (setenv "LSOF_CC" "gcc")
            (setenv "LSOF_MAKE" "make")
            (invoke "./Configure" "linux")
            #t))
        (add-after 'configure 'patch-timestamps
          (lambda _
            (substitute* "Makefile"
              (("`date`") "`date --date=@1`"))
            #t))
        (add-before 'check 'disable-failing-tests
          (lambda _
            (substitute* "tests/Makefile"
              ;; Fails with ‘ERROR!!! client gethostbyaddr() failure’.
              (("(STDTST=.*) LTsock" _ prefix) prefix)
              ;; Fails without access to a remote NFS server.
              (("(OPTTST=.*) LTnfs"  _ prefix) prefix))
            #t))
        (replace 'check
          (lambda _
            (with-directory-excursion "tests"
              ;; Tests refuse to run on ‘unvalidated’ platforms.
              (make-file-writable "TestDB")
              (invoke "./Add2TestDB")

              ;; The ‘standard’ tests suggest running ‘optional’ ones as well.
              (invoke "make" "standard" "optional")
              #t)))
        (replace 'install
          (lambda* (#:key outputs #:allow-other-keys)
            (let ((out (assoc-ref outputs "out")))
              (install-file "lsof" (string-append out "/bin"))
              (install-file "lsof.8" (string-append out "/share/man/man8")))
            #t)))))
   (synopsis "Display information about open files")
   (description
    "Lsof stands for LiSt Open Files, and it does just that.
It lists information about files that are open by the processes running
on the system.")
   (license (license:fsf-free
             "file://00FAQ"
             "License inspired by zlib, see point 1.9 of 00FAQ in the distribution."))
   (home-page "http://people.freebsd.org/~abe/")))
s</td></tr>
<tr><td><span title='2018-03-13 21:48:26 +0200'>2018-03-13</span></td><td><a href='/guix/commit/gnu/packages/spice.scm?id=96dcb8a037e8dd4997096217f7f77110265b2ede'>gnu: usbredir: Declare a source file-name.</a><span class='msg-avail'>...</span></td><td>Efraim Flashner</td></tr>
<tr><td><span title='2018-01-21 02:53:15 +0100'>2018-01-21</span></td><td><a href='/guix/commit/gnu/packages/spice.scm?id=d5ae997aafd4470e14c6f97f30ee92655d0f6d05'>gnu: spice: Use HTTPS for spice-space.org home pages.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2018-01-21 02:53:15 +0100'>2018-01-21</span></td><td><a href='/guix/commit/gnu/packages/spice.scm?id=e564a16e28fc098cb43ef98aa86b5dcda946cf48'>gnu: spice-gtk: Update to 0.34.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2017-12-04 14:05:23 -0500'>2017-12-04</span></td><td><a href='/guix/commit/gnu/packages/spice.scm?id=b142756d9c6a2dd6936b7175f120846190f52aaa'>gnu: spice: Update to 0.14.0.</a><span class='msg-avail'>...</span></td><td>Andy Patterson</td></tr>
<tr><td><span title='2017-10-19 12:17:43 +0200'>2017-10-19</span></td><td><a href='/guix/commit/gnu/packages/spice.scm?id=c44dd0d67629ec787bdac1ae71f90b56a8e145e7'>gnu: spice-gtk: Enable GObject introspection support.</a><span class='msg-avail'>...</span></td><td>Andy Patterson</td></tr>
<tr><td><span title='2017-07-13 12:32:15 -0400'>2017-07-13</span></td><td><a href='/guix/commit/gnu/packages/spice.scm?id=3e879d1add2451ba6d11aff2cd853d66741ebc71'>gnu: spice-protocol: Update to 0.12.13.</a><span class='msg-avail'>...</span></td><td>Leo Famulari</td></tr>
<tr><td><span title='2017-07-12 16:27:40 -0400'>2017-07-12</span></td><td><a href='/guix/commit/gnu/packages/spice.scm?id=d89ce52096982d2b5ff3f81f9dc0c8316590fe41'>gnu: spice: Fix CVE-2017-7506.</a><span class='msg-avail'>...</span></td><td>Leo Famulari</td></tr>
<tr><td><span title='2017-07-12 16:27:40 -0400'>2017-07-12</span></td><td><a href='/guix/commit/gnu/packages/spice.scm?id=301565266fa563193a5e6c909fe72994a87a1f45'>gnu: usbredir: Use HTTPS home-page URL.</a><span class='msg-avail'>...</span></td><td>Leo Famulari</td></tr>
<tr><td><span title='2017-07-12 16:27:37 -0400'>2017-07-12</span></td><td><a href='/guix/commit/gnu/packages/spice.scm?id=83ad0dfcbe95a8a4c2eb850e54bcc40b3f8526c3'>gnu: virt-viewer: Update to 5.0.</a><span class='msg-avail'>...</span></td><td>Leo Famulari</td></tr>