;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2023 Janneke Nieuwenhuizen <janneke@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu home services media)
  #:use-module (srfi srfi-26)
  #:use-module (gnu home services)
  #:use-module (gnu home services shepherd)
  #:use-module (gnu packages kodi)
  #:use-module (gnu services configuration)
  #:use-module (gnu services shepherd)
  #:use-module (guix records)
  #:use-module (guix gexp)
  #:export (home-kodi-configuration
            home-kodi-service-type))


;;;
;;; Kodi.
;;;

(define-record-type* <home-kodi-configuration>
  home-kodi-configuration make-home-kodi-configuration
  home-kodi-configuration?
  (kodi          home-kodi-kodi          ;file-like
                 (default kodi))
  (extra-options home-kodi-extra-options ;list of string
                 (default '())))

(define (home-kodi-services config)
  "Return a <shepherd-service> for kodi with CONFIG."
  (match-record config <home-kodi-configuration>
    (kodi extra-options)
    (let* ((kodi (file-append kodi "/bin/kodi"))
           (command #~'(#$kodi "-fs" #$@extra-options))
           (log-file #~(string-append %user-log-dir "/kodi.log")))
      (list (shepherd-service
             (documentation "Run the kodi media center.")
             (provision '(kodi))
             (modules '((shepherd support)))      ;for '%user-log-dir'
             (start #~(make-forkexec-constructor #$command
                                                 #:log-file #$log-file))
             (stop #~(make-kill-destructor)))))))

(define home-kodi-service-type
  (service-type
   (name 'home-kodi)
   (default-value (home-kodi-configuration))
   (extensions
    (list (service-extension home-shepherd-service-type
                             home-kodi-services)))
   (description
    "Install and configure the Kodi media center so that it runs as a Shepherd
service.")))
gnu/installer/keymap.scm?id=f0752de257d5521f7cbe31a4c0f5114694747a08&amp;showmsg=1'>Expand</a>)</th><th class='left'>Author</th></tr>
<tr><td><span title='2021-09-21 20:35:49 +0000'>2021-09-21</span></td><td><a href='/guix/commit/gnu/installer/keymap.scm?id=d58e52b0713648dd30d41b41277854a935d8d15a'>installer: keymap: Fix optional fields handling.</a><span class='msg-avail'>...<span class='msg-tooltip'>Fixes: &lt;https://issues.guix.gnu.org/50723&gt;.

The keymap xml contains optional shortDescription and description fields. The
assoc-ref call on those fields can return false, handle it correctly.

* gnu/installer/keymap.scm (xkb-rules-&gt;models+layouts): Introduce a new
"maybe-empty" helper to deal with optional fields. Use it for shortDescription
and description fields.
</span></span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2020-04-09 02:42:54 +0000'>2020-04-09</span></td><td><a href='/guix/commit/gnu/installer/keymap.scm?id=91c231a2223440081426929828a23c7baa0214fd'>installer: Allow Alt+Shift toggle from non-Latin keyboard layouts.</a><span class='msg-avail'>...<span class='msg-tooltip'>Fixes &lt;https://bugs.gnu.org/40493&gt;.

* gnu/installer/newt/keymap.scm (%non-latin-layouts): New variable.
(%non-latin-variants): New variable.
(%latin-layout+variants): New variable.
(toggleable-latin-layout): New procedure to compute combined layouts.
(run-keymap-page): Use it.
(keyboard-layout-&gt;configuration): Apply it in config.scm.
(run-layout-page): Mention Alt+Shift.
* gnu/installer/keymap.scm (kmscon-update-keymap): Pass on XKB options.
* gnu/installer/record.scm (&lt;installer&gt;): Adjust code comments.
* gnu/installer.scm (apply-keymap): Pass on XKB options.
(installer-steps): Adjust code comments.
* gnu/packages/patches/kmscon-runtime-keymap-switch.patch: Apply XKB options.
</span></span></td><td>Florian Pelz</td></tr>