;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2022 Mathieu Othacehe <othacehe@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu compression)
  #:use-module (guix gexp)
  #:use-module (guix ui)
  #:use-module ((gnu packages compression) #:hide (zip))
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-9)
  #:use-module (ice-9 match)
  #:export (compressor
            compressor?
            compressor-name
            compressor-extension
            compressor-command
            %compressors
            lookup-compressor))

;; Type of a compression tool.
(define-record-type <compressor>
  (compressor name extension command)
  compressor?
  (name       compressor-name)      ;string (e.g., "gzip")
  (extension  compressor-extension) ;string (e.g., ".lz")
  (command    compressor-command))  ;gexp (e.g., #~(list "/gnu/store/…/gzip"
                                    ;                    "-9n" ))

(define %compressors
  ;; Available compression tools.
  (list (compressor "gzip"  ".gz"
                    #~(list #+(file-append gzip "/bin/gzip") "-9n"))
        (compressor "lzip"  ".lz"
                    #~(list #+(file-append lzip "/bin/lzip") "-9"))
        (compressor "xz"    ".xz"
                    #~(append (list #+(file-append xz "/bin/xz")
                                    "-e")
                              (%xz-parallel-args)))
        (compressor "bzip2" ".bz2"
                    #~(list #+(file-append bzip2 "/bin/bzip2") "-9"))
        (compressor "zstd" ".zst"
                    ;; The default level 3 compresses better than gzip in a
                    ;; fraction of the time, while the highest level 19
                    ;; (de)compresses more slowly and worse than xz.
                    #~(list #+(file-append zstd "/bin/zstd") "-3"))
        (compressor "none" "" #f)))

(define (lookup-compressor name)
  "Return the compressor object called NAME.  Error out if it could not be
found."
  (or (find (match-lambda
              (($ <compressor> name*)
               (string=? name* name)))
            %compressors)
      (leave (G_ "~a: compressor not found~%") name)))
1:21:27 +0100'>2024-02-19</span></td><td><a href='/guix/commit/gnu/machine?id=9ce548a26e59d85ad9341c0212fef38392d49ff4'>machine/ssh: Refresh parameterization of %CURRENT-SYSTEM.</a><span class='msg-avail'>...</span></td><td>Ricardo Wurmus</td></tr>
<tr><td><span title='2023-08-08 18:01:54 +0200'>2023-08-08</span></td><td><a href='/guix/commit/gnu/machine?id=5652c2e14728cf746f86c4ec34a84e99eb34f9a0'>system: Do not check initrd modules for pseudo file systems.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2022-11-17 22:27:39 +0100'>2022-11-17</span></td><td><a href='/guix/commit/gnu/machine?id=17b01d546306885ff3c07e7b6aaffb541a8b9043'>machine: ssh: Validate 'system' field.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2022-11-09 13:45:24 +0100'>2022-11-09</span></td><td><a href='/guix/commit/gnu/machine?id=8d7cb7f2a4d0b7ce49764e4ba24026762d640da7'>machine/digital-ocean: Pull operating system definition out of string.</a><span class='msg-avail'>...</span></td><td>Ricardo Wurmus</td></tr>
<tr><td><span title='2022-11-09 13:45:24 +0100'>2022-11-09</span></td><td><a href='/guix/commit/gnu/machine?id=ebb88e2bed889b67ea83893c907ab29e3bc81e8b'>machine/digital-ocean: Set load path to Guile 3.0 directories.</a><span class='msg-avail'>...</span></td><td>Ricardo Wurmus</td></tr>
<tr><td><span title='2022-11-09 13:45:24 +0100'>2022-11-09</span></td><td><a href='/guix/commit/gnu/machine?id=e8dcd008a0be8bd967efabab6960d19e5424d93e'>machine/digital-ocean: Use static-networking-service-type.</a><span class='msg-avail'>...</span></td><td>Ricardo Wurmus</td></tr>
<tr><td><span title='2022-11-09 13:45:24 +0100'>2022-11-09</span></td><td><a href='/guix/commit/gnu/machine?id=c8e41af7be47fdd3ae16765d5cf892582f5a407a'>machine/digital-ocean: Use nightly Guix.</a><span class='msg-avail'>...</span></td><td>Ricardo Wurmus</td></tr>
<tr><td><span title='2022-10-17 07:29:09 +0200'>2022-10-17</span></td><td><a href='/guix/commit/gnu/machine?id=82b0f3755d12e04578a54ee53b3a8051958e8143'>guix: Fix typos.</a><span class='msg-avail'>...</span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2022-09-26 23:29:35 +0200'>2022-09-26</span></td><td><a href='/guix/commit/gnu/machine?id=1033645e9d3899edd6b052b19e24c0a718b95e88'>machine: ssh: Parameterize '%current-system' early on.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2022-09-04 17:57:02 +0200'>2022-09-04</span></td><td><a href='/guix/commit/gnu/machine?id=a451a809d5537035cc8888cfde5349842a68e934'>Fix misspelling of GUIX_DIGITAL_OCEAN_TOKEN.</a><span class='msg-avail'>...</span></td><td>Matthew James Kraai</td></tr>