;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2019 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu build locale)
  #:use-module (guix build utils)
  #:use-module (srfi srfi-1)
  #:use-module (ice-9 rdelim)
  #:use-module (ice-9 match)
  #:use-module (ice-9 regex)
  #:export (build-locale
            normalize-codeset
            locale->name+codeset
            read-supported-locales))

(define locale-rx
  ;; Regexp matching a locale line in 'localedata/SUPPORTED'.
  (make-regexp
   "^[[:space:]]*([[:graph:]]+)/([[:graph:]]+)[[:space:]]*\\\\$"))

(define (read-supported-locales port)
  "Read the 'localedata/SUPPORTED' file from PORT.  That file is actually a
makefile snippet, with one locale per line, and a header that can be
discarded."
  (let loop ((locales '()))
    (define line
      (read-line port))

    (cond ((eof-object? line)
           (reverse locales))
          ((string-prefix? "#" (string-trim line)) ;comment
           (loop locales))
          ((string-contains line "=")            ;makefile variable assignment
           (loop locales))
          (else
           (match (regexp-exec locale-rx line)
             (#f
              (loop locales))
             (m
              (loop (alist-cons (match:substring m 1)
                                (match:substring m 2)
                                locales))))))))

(define (normalize-codeset codeset)
  "Compute the \"normalized\" variant of CODESET."
  ;; info "(libc) Using gettextized software", for the algorithm used to
  ;; compute the normalized codeset.
  (letrec-syntax ((-> (syntax-rules ()
                        ((_ proc value)
                         (proc value))
                        ((_ proc rest ...)
                         (proc (-> rest ...))))))
    (-> (lambda (str)
          (if (string-every char-set:digit str)
              (string-append "iso" str)
              str))
        string-downcase
        (lambda (str)
          (string-filter char-set:letter+digit str))
        codeset)))

(define* (build-locale locale
                       #:key
                       (localedef "localedef")
                       (directory ".")
                       (codeset "UTF-8")
                       (name (string-append locale "." codeset)))
  "Compute locale data for LOCALE and CODESET--e.g., \"en_US\" and
\"UTF-8\"--with LOCALEDEF, and store it in DIRECTORY under NAME."
  (format #t "building locale '~a'...~%" name)
  (invoke localedef "--no-archive" "--prefix" directory
          "-i" locale "-f" codeset
          (string-append directory "/" name)))

(define (locale->name+codeset locale)
  "Split a locale name such as \"aa_ER@saaho.UTF-8\" into two values: the
language/territory/modifier part, and the codeset."
  (match (string-rindex locale #\.)
    (#f  (values locale #f))
    (dot (values (string-take locale dot)
                 (string-drop locale (+ dot 1))))))
gt;.

* guix/ui.scm (size-&gt;number)[unit-pos]: Add #\. to CHAR-SET:DIGIT.
* tests/ui.scm ("size-&gt;number, 1.M"): New test.


</td></tr>
<tr class='logheader'><td><span title='2019-09-19 23:24:04 +0200'>2019-09-19</span></td><td class='logsubject'><a href='/guix/commit/tests/ui.scm?id=d2cdef65605b9e14bfa02c3bf1612ab6b62f4a89'>ui: 'relevance' connects regexps with a logical and.</a></td><td>zimoun</td></tr>
<tr class='nohover-highlight'><td/><td colspan='3' class='logmsg'>
Fixes &lt;https://bugs.gnu.org/36763&gt;.
Previously, the logical and connecting the regexps did not output the expected
results (introduced in 8874faaaac665100a095ef25e39c9a389f5a397f).

* guix/ui.scm (relevance)
[score]: Change its arguments.
[regexp-&gt;score]: New procedure.
* tests/ui.scm ("package-relevance"): Add test.

Signed-off-by: Ludovic Courtès &lt;ludo@gnu.org&gt;


</td></tr>
<tr class='logheader'><td><span title='2019-06-27 11:14:40 +0200'>2019-06-27</span></td><td class='logsubject'><a href='/guix/commit/tests/ui.scm?id=8874faaaac665100a095ef25e39c9a389f5a397f'>ui: 'relevance' considers regexps connected with a logical and.</a></td><td>Ludovic Courtès</td></tr>
<tr class='nohover-highlight'><td/><td colspan='3' class='logmsg'>
* guix/ui.scm (relevance)[score]: Change to return 0 when one of REGEXPS
doesn't match.
* tests/ui.scm ("package-relevance"): New test.


</td></tr>
<tr class='logheader'><td><span title='2017-05-10 22:05:21 +0200'>2017-05-10</span></td><td class='logsubject'><a href='/guix/commit/tests/ui.scm?id=30d2397f73d6fa9e77eed70ec6df8afd3b9f5f5e'>ui: 'string-&gt;duration' correctly handles hours.</a></td><td>Ludovic Courtès</td></tr>
<tr class='nohover-highlight'><td/><td colspan='3' class='logmsg'>
* guix/ui.scm (string-&gt;duration): Add missing '=&gt;' for hours.
* tests/ui.scm ("duration, 2 hours"): New test.


</td></tr>
<tr class='logheader'><td><span title='2017-03-08 23:42:53 +0100'>2017-03-08</span></td><td class='logsubject'><a href='/guix/commit/tests/ui.scm?id=1062063a65036f32a061c54866d33ffe079ec44e'>ui: Don't use '%default-port-encoding' to set the encoding of string ports.</a></td><td>Ludovic Courtès</td></tr>
<tr class='nohover-highlight'><td/><td colspan='3' class='logmsg'>
* guix/ui.scm (right-arrow): Call 'set-port-encoding!' to set PORT's
encoding; remove use of 'with-fluids'.  This is for compatibility with
Guile 2.2 where the encoding of string ports is not influenced by
%DEFAULT-PORT-ENCODING.
* tests/ui.scm ("show-manifest-transaction"): Likewise.


</td></tr>
<tr class='logheader'><td><span title='2016-06-09 23:34:56 +0200'>2016-06-09</span></td><td class='logsubject'><a href='/guix/commit/tests/ui.scm?id=638c5b79397aba92ab3211a1ea3b3418e112ec66'>ui: 'string-&gt;duration' supports hours and seconds.</a></td><td>Ludovic Courtès</td></tr>
<tr class='nohover-highlight'><td/><td colspan='3' class='logmsg'>
* guix/ui.scm (string-&gt;duration): Add seconds and hours.
* tests/ui.scm ("duration, 1 second"): New test.


</td></tr>