;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017 David Craven <david@craven.ch>
;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu bootloader extlinux)
  #:use-module (gnu bootloader)
  #:use-module (gnu system)
  #:use-module (gnu packages bootloaders)
  #:use-module (guix gexp)
  #:use-module (guix monads)
  #:use-module (guix records)
  #:use-module (guix utils)
  #:export (extlinux-bootloader))

(define* (extlinux-configuration-file config entries
                                      #:key
                                      (system (%current-system))
                                      (old-entries '()))
  "Return the U-Boot configuration file corresponding to CONFIG, a
<u-boot-configuration> object, and where the store is available at STORE-FS, a
<file-system> object.  OLD-ENTRIES is taken to be a list of menu entries
corresponding to old generations of the system."

  (define all-entries
    (append entries (map menu-entry->boot-parameters
                         (bootloader-configuration-menu-entries config))))

  (define (boot-parameters->gexp params)
    (let ((label (boot-parameters-label params))
          (kernel (boot-parameters-kernel params))
          (kernel-arguments (boot-parameters-kernel-arguments params))
          (initrd (boot-parameters-initrd params)))
      #~(format port "LABEL ~a
  MENU LABEL ~a
  KERNEL ~a
  FDTDIR ~a/lib/dtbs
  INITRD ~a
  APPEND ~a
~%"
                #$label #$label
                #$kernel #$kernel #$initrd
                (string-join (list #$@kernel-arguments)))))

  (define builder
    #~(call-with-output-file #$output
        (lambda (port)
          (let ((timeout #$(bootloader-configuration-timeout config)))
            (format port "# This file was generated from your GuixSD configuration.  Any changes
# will be lost upon reconfiguration.
UI menu.c32
PROMPT ~a
TIMEOUT ~a~%"
                    (if (> timeout 0) 1 0)
                    ;; timeout is expressed in 1/10s of seconds.
                    (* 10 timeout))
            #$@(map boot-parameters->gexp all-entries)

            #$@(if (pair? old-entries)
                   #~((format port "~%")
                      #$@(map boot-parameters->gexp old-entries)
                      (format port "~%"))
                   #~())))))

  (gexp->derivation "extlinux.conf" builder))




;;;
;;; Install procedures.
;;;

(define dd
  #~(lambda (bs count if of)
      (zero? (system* "dd"
                      (string-append "bs=" (number->string bs))
                      (string-append "count=" (number->string count))
                      (string-append "if=" if)
                      (string-append "of=" of)))))

(define install-extlinux
  #~(lambda (bootloader device mount-point)
      (let ((extlinux (string-append bootloader "/sbin/extlinux"))
            (install-dir (string-append mount-point "/boot/extlinux"))
            (syslinux-dir (string-append bootloader "/share/syslinux")))
        (for-each (lambda (file)
                    (install-file file install-dir))
                  (find-files syslinux-dir "\\.c32$"))

        (unless (and (zero? (system* extlinux "--install" install-dir))
                     (#$dd 440 1 (string-append syslinux-dir "/mbr.bin") device))
          (error "failed to install SYSLINUX")))))



;;;
;;; Bootloader definitions.
;;;

(define extlinux-bootloader
  (bootloader
   (name 'extlinux)
   (package syslinux)
   (installer install-extlinux)
   (configuration-file "/boot/extlinux/extlinux.conf")
   (configuration-file-generator extlinux-configuration-file)))
93e2fd7a9f57f12bf'>machine: Use 'become-command'.</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>
<tr><td><span title='2019-08-15 07:43:13 -0400'>2019-08-15</span></td><td><a href='/guix/commit/gnu/machine?id=3033d59ac9a747b42a1fa6ca6664d4fbc62ca117'>machine: Automatically authorize the coordinator's signing key.</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>
<tr><td><span title='2019-08-15 07:43:09 -0400'>2019-08-15</span></td><td><a href='/guix/commit/gnu/machine?id=9c70c460a05b2bc60f3f3602f0a2dba0f79ce86c'>machine: Implement 'roll-back-machine'.</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>
<tr><td><span title='2019-08-15 07:43:03 -0400'>2019-08-15</span></td><td><a href='/guix/commit/gnu/machine?id=5ea7537b9a650cfa525401c19879080a9cf42e13'>machine: Allow non-root users to deploy.</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>
<tr><td><span title='2019-08-14 15:38:09 -0400'>2019-08-14</span></td><td><a href='/guix/commit/gnu/machine?id=2c8e04f13670c8c7ad8c7195c305960dd1905363'>remote: Build derivations appropriate for the remote's</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>
<tr><td><span title='2019-08-07 18:29:07 -0400'>2019-08-07</span></td><td><a href='/guix/commit/gnu/machine?id=d84e9b75b2aba98583531f2876d9298871389585'>machine: Add 'build-locally?' field for managed hosts.</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>
<tr><td><span title='2019-08-06 16:40:25 -0400'>2019-08-06</span></td><td><a href='/guix/commit/gnu/machine?id=fd3119db4fed02a1f3491460be776a3b5d2b2cd3'>machine: Implement safety checks.</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>
<tr><td><span title='2019-08-06 15:48:51 -0400'>2019-08-06</span></td><td><a href='/guix/commit/gnu/machine?id=d97ce20400b5d2967bfbc0e9fbfb99bbb2daed4f'>machine: Rename 'system' field.</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>
<tr><td><span title='2019-07-26 19:19:49 +0200'>2019-07-26</span></td><td><a href='/guix/commit/gnu/machine?id=5c793753b31b1dcd9a554bce953124f7ae88ca9a'>guix system: Add 'reconfigure' module.</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>
<tr><td><span title='2019-07-18 12:57:00 +0200'>2019-07-18</span></td><td><a href='/guix/commit/gnu/machine?id=53f21b3fe9ed57f0feef003185b561efc9b3e30c'>machine: Fix typo.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2019-07-06 02:10:04 -0400'>2019-07-06</span></td><td><a href='/guix/commit/gnu/machine?id=fa9edf09e992db7510c7471486dffc93e1e707e5'>gnu: Add machine type for deployment specifications.</a><span class='msg-avail'>...</span></td><td>Jakob L. Kreuze</td></tr>