;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017 David Craven <david@craven.ch>
;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu bootloader extlinux)
  #:use-module (gnu bootloader)
  #:use-module (gnu packages bootloaders)
  #:use-module (guix gexp)
  #:use-module (guix utils)
  #:export (extlinux-bootloader
            extlinux-bootloader-gpt))

(define* (extlinux-configuration-file config entries
                                      #:key
                                      (system (%current-system))
                                      (old-entries '())
                                      #:allow-other-keys)
  "Return the U-Boot configuration file corresponding to CONFIG, a
<u-boot-configuration> object, and where the store is available at STORE-FS, a
<file-system> object.  OLD-ENTRIES is taken to be a list of menu entries
corresponding to old generations of the system."

  (define all-entries
    (append entries (bootloader-configuration-menu-entries config)))

  (define (menu-entry->gexp entry)
    (let ((label (menu-entry-label entry))
          (kernel (menu-entry-linux entry))
          (kernel-arguments (menu-entry-linux-arguments entry))
          (initrd (menu-entry-initrd entry)))
      #~(format port "LABEL ~a
  MENU LABEL ~a
  KERNEL ~a
  FDTDIR ~a/lib/dtbs
  INITRD ~a
  APPEND ~a
~%"
                #$label #$label
                #$kernel (dirname #$kernel) #$initrd
                (string-join (list #$@kernel-arguments)))))

  (define builder
    #~(call-with-output-file #$output
        (lambda (port)
          (let ((timeout #$(bootloader-configuration-timeout config)))
            (format port "# This file was generated from your Guix configuration.  Any changes
# will be lost upon reconfiguration.
UI menu.c32
MENU TITLE GNU Guix Boot Options
PROMPT ~a
TIMEOUT ~a~%"
                    (if (> timeout 0) 1 0)
                    ;; timeout is expressed in 1/10s of seconds.
                    (* 10 timeout))
            #$@(map menu-entry->gexp all-entries)

            #$@(if (pair? old-entries)
                   #~((format port "~%")
                      #$@(map menu-entry->gexp old-entries)
                      (format port "~%"))
                   #~())))))

  (computed-file "extlinux.conf" builder
                 #:options '(#:local-build? #t
                             #:substitutable? #f)))




;;;
;;; Install procedures.
;;;

(define (install-extlinux mbr)
  #~(lambda (bootloader device mount-point)
      (let ((extlinux (string-append bootloader "/sbin/extlinux"))
            (install-dir (string-append mount-point "/boot/extlinux"))
            (syslinux-dir (string-append bootloader "/share/syslinux")))
        (for-each (lambda (file)
                    (install-file file install-dir))
                  (find-files syslinux-dir "\\.c32$"))
        (invoke/quiet extlinux "--install" install-dir)
        (write-file-on-device (string-append syslinux-dir "/" #$mbr)
                              440 device 0))))

(define install-extlinux-mbr
  (install-extlinux "mbr.bin"))

(define install-extlinux-gpt
  (install-extlinux "gptmbr.bin"))



;;;
;;; Bootloader definitions.
;;;

(define extlinux-bootloader
  (bootloader
   (name 'extlinux)
   (package syslinux)
   (installer install-extlinux-mbr)
   (configuration-file "/boot/extlinux/extlinux.conf")
   (configuration-file-generator extlinux-configuration-file)))

(define extlinux-bootloader-gpt
  (bootloader
   (inherit extlinux-bootloader)
   (installer install-extlinux-gpt)))
services: rottlog: Add /var/log/debug to '%default-rotations'.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2017-11-05 15:29:52 +0100'>2017-11-05</span></td><td><a href='/guix/commit/gnu/services/admin.scm?id=21b71b01e9c2264c31ef30451c152bb38cc9e635'>services: Add 'description' fields.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2017-08-09 23:50:35 +0100'>2017-08-09</span></td><td><a href='/guix/commit/gnu/services/admin.scm?id=101205662588f033c944034f91e7d3cda06d6e56'>services: admin: Simplify the handling of the Tailon debug? option.</a><span class='msg-avail'>...</span></td><td>Christopher Baines</td></tr>
<tr><td><span title='2017-08-09 23:50:31 +0100'>2017-08-09</span></td><td><a href='/guix/commit/gnu/services/admin.scm?id=91fdc8a574cccecd55d042bc1f76ab7f7d3adced'>services: Update the Tailon service for Tailon 1.3.0.</a><span class='msg-avail'>...</span></td><td>Christopher Baines</td></tr>
<tr><td><span title='2017-08-09 23:50:27 +0100'>2017-08-09</span></td><td><a href='/guix/commit/gnu/services/admin.scm?id=f2d8e7f720c92dfb0f49d61f7b66d45e3e63e4cd'>services: Add missing wrap-lines option to tailon.</a><span class='msg-avail'>...</span></td><td>Christopher Baines</td></tr>
<tr><td><span title='2017-07-29 12:45:03 +0100'>2017-07-29</span></td><td><a href='/guix/commit/gnu/services/admin.scm?id=730ed6ec8b69a0f908a8aadbbe0555dd45de227c'>gnu: services: admin: Add tailon.</a><span class='msg-avail'>...</span></td><td>Christopher Baines</td></tr>
<tr><td><span title='2017-06-12 23:34:14 +0200'>2017-06-12</span></td><td><a href='/guix/commit/gnu/services/admin.scm?id=254ea3f945e8bc44f8c3a4159302f24f4fe5f216'>services: rottlog: Make extensible.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2017-06-12 23:34:13 +0200'>2017-06-12</span></td><td><a href='/guix/commit/gnu/services/admin.scm?id=81fa2229ecb80a8ae90c8e24771e1df880e75383'>services: rottlog: Define &lt;log-rotation&gt; objects.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2017-04-16 00:48:08 +0200'>2017-04-16</span></td><td><a href='/guix/commit/gnu/services/admin.scm?id=3d3c56500843b5573ba6419db5e66075fb8ac8ef'>services: Add a default value to various service types.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2016-12-19 23:57:20 +0100'>2016-12-19</span></td><td><a href='/guix/commit/gnu/services/admin.scm?id=dc0ef095b32f57a935764d40530af0b32a01d715'>services: guix: Add 'log-file' configuration option.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>