;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017 David Craven <david@craven.ch>
;;; Copyright © 2017 Mathieu Othacehe <m.othacehe@gmail.com>
;;; Copyright © 2022 Reza Alizadeh Majd <r.majd@pantherx.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu bootloader extlinux)
  #:use-module (gnu bootloader)
  #:use-module (gnu packages bootloaders)
  #:use-module (guix gexp)
  #:use-module (guix utils)
  #:export (extlinux-bootloader
            extlinux-bootloader-gpt))

(define* (extlinux-configuration-file config entries
                                      #:key
                                      (system (%current-system))
                                      (old-entries '())
                                      #:allow-other-keys)
  "Return the U-Boot configuration file corresponding to CONFIG, a
<u-boot-configuration> object, and where the store is available at STORE-FS, a
<file-system> object.  OLD-ENTRIES is taken to be a list of menu entries
corresponding to old generations of the system."

  (define all-entries
    (append entries (bootloader-configuration-menu-entries config)))

  (define with-fdtdir?
    (bootloader-configuration-device-tree-support? config))

  (define (menu-entry->gexp entry)
    (let ((label (menu-entry-label entry))
          (kernel (menu-entry-linux entry))
          (kernel-arguments (menu-entry-linux-arguments entry))
          (initrd (menu-entry-initrd entry)))
      #~(format port "LABEL ~a
  MENU LABEL ~a
  KERNEL ~a
  ~a
  INITRD ~a
  APPEND ~a
~%"
                #$label #$label
                #$kernel
                (if #$with-fdtdir?
                    (string-append "FDTDIR " (dirname #$kernel) "/lib/dtbs")
                    "")
                #$initrd
                (string-join (list #$@kernel-arguments)))))

  (define builder
    #~(call-with-output-file #$output
        (lambda (port)
          (let ((timeout #$(bootloader-configuration-timeout config)))
            (format port "# This file was generated from your Guix configuration.  Any changes
# will be lost upon reconfiguration.
UI menu.c32
MENU TITLE GNU Guix Boot Options
PROMPT ~a
TIMEOUT ~a~%"
                    (if (> timeout 0) 1 0)
                    ;; timeout is expressed in 1/10s of seconds.
                    (* 10 timeout))
            #$@(map menu-entry->gexp all-entries)

            #$@(if (pair? old-entries)
                   #~((format port "~%")
                      #$@(map menu-entry->gexp old-entries)
                      (format port "~%"))
                   #~())))))

  (computed-file "extlinux.conf" builder
                 #:options '(#:local-build? #t
                             #:substitutable? #f)))




;;;
;;; Install procedures.
;;;

(define (install-extlinux mbr)
  #~(lambda (bootloader device mount-point)
      (let ((extlinux (string-append bootloader "/sbin/extlinux"))
            (install-dir (string-append mount-point "/boot/extlinux"))
            (syslinux-dir (string-append bootloader "/share/syslinux")))
        (for-each (lambda (file)
                    (install-file file install-dir))
                  (find-files syslinux-dir "\\.c32$"))
        (invoke/quiet extlinux "--install" install-dir)
        (write-file-on-device (string-append syslinux-dir "/" #$mbr)
                              440 device 0))))

(define install-extlinux-mbr
  (install-extlinux "mbr.bin"))

(define install-extlinux-gpt
  (install-extlinux "gptmbr.bin"))



;;;
;;; Bootloader definitions.
;;;

(define extlinux-bootloader
  (bootloader
   (name 'extlinux)
   (package syslinux)
   (installer install-extlinux-mbr)
   (configuration-file "/boot/extlinux/extlinux.conf")
   (configuration-file-generator extlinux-configuration-file)))

(define extlinux-bootloader-gpt
  (bootloader
   (inherit extlinux-bootloader)
   (installer install-extlinux-gpt)))
u/packages/documentation.scm?id=f1728d43460e63b106dd446e70001d8e100eaf6d'>Merge branch 'master' into core-updates</a></td><td>Ricardo Wurmus</td></tr>
<tr><td><span title='2018-06-22 23:34:04 +0200'>2018-06-22</span></td><td><a href='/guix/commit/gnu/packages/documentation.scm?id=dbe1bd5dd9ca7a8a52e679f573b409340a2632d6'>gnu: doxygen: Update to 1.8.14.</a><span class='msg-avail'>...</span></td><td>Danny Milosavljevic</td></tr>
<tr><td><span title='2018-06-08 15:23:39 +0200'>2018-06-08</span></td><td><a href='/guix/commit/gnu/packages/documentation.scm?id=849a1399ca46497ad6acc5b11903f345502c02de'>gnu: doxygen: Work around GCC ICE on armhf-linux.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-03-25 05:01:55 -0400'>2018-03-25</span></td><td><a href='/guix/commit/gnu/packages/documentation.scm?id=8a442e5db2989df6283b323fc8176df75972bab2'>gnu: asciidoc: Restore custom 'bootstrap' phase.</a><span class='msg-avail'>...</span></td><td>Mark H Weaver</td></tr>
<tr><td><span title='2018-03-11 22:04:40 +0100'>2018-03-11</span></td><td><a href='/guix/commit/gnu/packages/documentation.scm?id=189be331acfda1c242a9c85fca8d2a0356742f48'>build-system/gnu: Add 'bootstrap' phase.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-02-09 01:46:34 -0500'>2018-02-09</span></td><td><a href='/guix/commit/gnu/packages/documentation.scm?id=efe2a2833c6d306d0c60127fdfebaff6dc415b4c'>Merge branch 'master' into core-updates</a></td><td>Mark H Weaver</td></tr>
<tr><td><span title='2018-02-06 20:02:12 +0100'>2018-02-06</span></td><td><a href='/guix/commit/gnu/packages/documentation.scm?id=ccfe4aa1c09b5205a1d17070eb4f9f6da59650bc'>gnu: asciidoc: Update to 8.6.10.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>