;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2021 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

;;; This file returns a manifest containing origins of all the packages.  The
;;; main purpose is to allow continuous integration services to keep upstream
;;; source code around.  It can also be passed to 'guix weather -m'.

(use-modules (srfi srfi-1) (srfi srfi-26)
             (ice-9 match) (ice-9 vlist)
             (guix packages) (guix profiles)
             (gnu packages))

(define (all-packages)
  "Return the list of all the packages, public or private, omitting only
superseded packages."
  (fold-packages (lambda (package lst)
                   (match (package-replacement package)
                     (#f (cons package lst))
                     (replacement
                      (append (list replacement package) lst))))
                 '()
                 #:select? (negate package-superseded)))

(define (upstream-origin source)
  "Return SOURCE without any patches or snippet."
  (origin (inherit source)
          (snippet #f) (patches '())))

(define (all-origins)
  "Return the list of origins referred to by all the packages."
  (let loop ((packages (all-packages))
             (origins  '())
             (visited   vlist-null))
    (match packages
      ((head . tail)
       (let ((new (remove (cut vhash-assq <> visited)
                          (package-direct-sources head))))
         (loop tail (append new origins)
               (fold (cut vhash-consq <> #t <>)
                     visited new))))
      (()
       origins))))

;; Return a manifest containing all the origins.
(manifest (map (lambda (origin)
                 (manifest-entry
                   (name (or (origin-actual-file-name origin)
                             "origin"))
                   (version "0")
                   (item (upstream-origin origin))))
               (all-origins)))
wmsg=1'>Expand</a>)</th><th class='left'>Author</th></tr>
<tr><td><span title='2023-07-07 21:14:10 +0200'>2023-07-07</span></td><td><a href='/guix/commit/gnu/tests/image.scm?id=209204e23b39af09e0ea92540b6fa00a60e6a0ae'>image: Prefer gpt partition table for efi images</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/system/image.scm (efi-disk-image): Use gpt partition-table-type.
(efi32-disk-image): Use gpt partition-table-type.
(qcow2-image-type): Use mbr partition-table-type explicitly.
* gnu/tests/image.scm: Assert partition table type of efi-disk-image.

Signed-off-by: Josselin Poiret &lt;dev@jpoiret.xyz&gt;
</span></span></td><td>Sergey Trofimov</td></tr>
<tr><td><span title='2022-08-30 19:29:58 +0200'>2022-08-30</span></td><td><a href='/guix/commit/gnu/tests/image.scm?id=73fb14c28ae883b6bd22ffdc63d1d59752cb8e0e'>tests: image: New test.</a><span class='msg-avail'>...<span class='msg-tooltip'>Add a new image test module to validate the image creation itself. The images
structures are validated using guile-parted. Checking the content of those
images is out of scope and should be performed in other modules (installation
for instance).

* gnu/tests/image.scm: New file.
* gnu/local.mk (GNU_SYSTEM_MODULES): Add it.
</span></span></td><td>Mathieu Othacehe</td></tr>