;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2021 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

;;; This file returns a manifest containing origins of all the packages.  The
;;; main purpose is to allow continuous integration services to keep upstream
;;; source code around.  It can also be passed to 'guix weather -m'.

(use-modules (srfi srfi-1) (srfi srfi-26)
             (ice-9 match) (ice-9 vlist)
             (guix packages) (guix profiles)
             (gnu packages))

(define (all-packages)
  "Return the list of all the packages, public or private, omitting only
superseded packages."
  (fold-packages (lambda (package lst)
                   (match (package-replacement package)
                     (#f (cons package lst))
                     (replacement
                      (append (list replacement package) lst))))
                 '()
                 #:select? (negate package-superseded)))

(define (upstream-origin source)
  "Return SOURCE without any patches or snippet."
  (origin (inherit source)
          (snippet #f) (patches '())))

(define (all-origins)
  "Return the list of origins referred to by all the packages."
  (let loop ((packages (all-packages))
             (origins  '())
             (visited   vlist-null))
    (match packages
      ((head . tail)
       (let ((new (remove (cut vhash-assq <> visited)
                          (package-direct-sources head))))
         (loop tail (append new origins)
               (fold (cut vhash-consq <> #t <>)
                     visited new))))
      (()
       origins))))

;; Return a manifest containing all the origins.
(manifest (map (lambda (origin)
                 (manifest-entry
                   (name (or (origin-actual-file-name origin)
                             "origin"))
                   (version "0")
                   (item (upstream-origin origin))))
               (all-origins)))
ref='/guix/commit/tests/swh.scm?id=5225732b9b54ffa92b9d199246b87dae666a3f77'>swh: Test proper handling of null visit snapshot URL.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-12-21 17:47:35 +0100'>2020-12-21</span></td><td><a href='/guix/commit/tests/swh.scm?id=9608f4003dedd8dfe99327c15668ca1a43ebd93b'>tests: Fix malformed JSON.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-02-27 23:29:30 +0100'>2020-02-27</span></td><td><a href='/guix/commit/tests/swh.scm?id=749b9582061f7d929be83a194040b63b41afec81'>swh: Adjust 'origin' test.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-09-02 15:25:01 +0200'>2019-09-02</span></td><td><a href='/guix/commit/tests/swh.scm?id=ba1c1853a79a5930ca7db7a6b368859f805df98d'>swh: Add hooks for rate limiting handling.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-09-02 15:25:01 +0200'>2019-09-02</span></td><td><a href='/guix/commit/tests/swh.scm?id=9323ab550f3bcb75fcaefbb20847595974702d5b'>tests: 'with-http-server' accepts multiple responses.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-07-22 11:53:39 +0200'>2019-07-22</span></td><td><a href='/guix/commit/tests/swh.scm?id=96f1cbeff84819f9886d15763b4c477cdecd7784'>swh: Add basic tests.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>