dnl -*- Autoconf -*- fragment for the C++ daemon.

AC_MSG_CHECKING([whether to build daemon])
AC_MSG_RESULT([$guix_build_daemon])

dnl C++ environment.  This macro must be used unconditionnaly.
AC_PROG_CXX
AM_PROG_AR
AC_LANG([C++])

if test "x$guix_build_daemon" = "xyes"; then

  GUIX_ASSERT_CXX11

  AC_PROG_RANLIB
  AC_CONFIG_HEADERS([nix/config.h])

  dnl Use 64-bit file system calls so that we can support files > 2 GiB.
  AC_SYS_LARGEFILE

  dnl Look for zlib, a required dependency.
  AC_CHECK_LIB([z], [gzdopen], [true],
    [AC_MSG_ERROR([Guix requires zlib.  See http://www.zlib.net/.])])
  AC_CHECK_HEADERS([zlib.h], [true],
    [AC_MSG_ERROR([Guix requires zlib.  See http://www.zlib.net/.])])

  dnl Look for libbz2, an optional dependency.
  AC_CHECK_LIB([bz2], [BZ2_bzWriteOpen], [HAVE_LIBBZ2=yes], [HAVE_LIBBZ2=no])
  if test "x$HAVE_LIBBZ2" = xyes; then
    AC_CHECK_HEADERS([bzlib.h])
    HAVE_LIBBZ2="$ac_cv_header_bzlib_h"
  fi

  dnl Look for SQLite, a required dependency.
  PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= 3.6.19])

  AC_DEFINE_UNQUOTED([SYSTEM], ["$guix_system"],
    [Guix host system type--i.e., platform and OS kernel tuple.])

  case "$LIBGCRYPT_PREFIX" in
    no)
      LIBGCRYPT_CFLAGS=""
      ;;
    *)
      LIBGCRYPT_CFLAGS="-I$LIBGCRYPT_PREFIX/include"
      ;;
  esac

  case "$LIBGCRYPT_LIBDIR" in
    no | "")
      LIBGCRYPT_LIBS="-lgcrypt"
      ;;
    *)
      LIBGCRYPT_LIBS="-L$LIBGCRYPT_LIBDIR -lgcrypt"
      ;;
  esac

  AC_SUBST([LIBGCRYPT_CFLAGS])
  AC_SUBST([LIBGCRYPT_LIBS])

  save_CFLAGS="$CFLAGS"
  save_LDFLAGS="$LDFLAGS"
  CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
  LDFLAGS="$LDFLAGS $LIBGCRYPT_LDFLAGS"

  have_gcrypt=yes
  AC_CHECK_LIB([gcrypt], [gcry_md_open], [:], [have_gcrypt=no])
  AC_CHECK_HEADER([gcrypt.h], [:], [have_gcrypt=no])
  if test "x$have_gcrypt" != "xyes"; then
    AC_MSG_ERROR([GNU libgcrypt not found; please install it.])
  fi

  CFLAGS="$save_CFLAGS"
  LDFLAGS="$save_LDFLAGS"

  dnl Chroot support.
  AC_CHECK_FUNCS([chroot unshare])
  AC_CHECK_HEADERS([sched.h sys/param.h sys/mount.h sys/syscall.h])

  if test "x$ac_cv_func_chroot" != "xyes"; then
    AC_MSG_ERROR(['chroot' function missing, bailing out])
  fi

  dnl lutimes and lchown: used when canonicalizing store items.
  dnl posix_fallocate: used when extracting archives.
  dnl vfork: to speed up spawning of helper programs.
  dnl   `--> now disabled because of unpredictable behavior:
  dnl        see <http://lists.gnu.org/archive/html/guix-devel/2014-05/msg00036.html>
  dnl        and Nix commit f794465c (Nov. 2012).
  dnl sched_setaffinity: to improve RPC locality.
  dnl statvfs: to detect disk-full conditions.
  dnl strsignal: for error reporting.
  dnl statx: fine-grain 'stat' call, new in glibc 2.28.
  AC_CHECK_FUNCS([lutimes lchown posix_fallocate sched_setaffinity \
     statvfs nanosleep strsignal statx])

  dnl Check whether the store optimiser can optimise symlinks.
  AC_MSG_CHECKING([whether it is possible to create a link to a symlink])
  ln -s bla tmp_link
  if ln tmp_link tmp_link2 2> /dev/null; then
      AC_MSG_RESULT(yes)
      AC_DEFINE(CAN_LINK_SYMLINK, 1, [Whether link() works on symlinks.])
  else
      AC_MSG_RESULT(no)
  fi
  rm -f tmp_link tmp_link2

  dnl Check for <locale>.
  AC_LANG_PUSH(C++)
  AC_CHECK_HEADERS([locale])
  AC_LANG_POP(C++)


  dnl Check whether we have the `personality' syscall, which allows us
  dnl to do i686-linux builds on x86_64-linux machines.
  AC_CHECK_HEADERS([sys/personality.h])

  dnl Determine the appropriate default list of substitute URLs (GnuTLS
  dnl is required so we can default to 'https'.)
  guix_substitute_urls="https://ci.guix.gnu.org"

  AC_MSG_CHECKING([for default substitute URLs])
  AC_MSG_RESULT([$guix_substitute_urls])

  AC_DEFINE_UNQUOTED([GUIX_SUBSTITUTE_URLS], ["$guix_substitute_urls"],
    [Default list of substitute URLs used by 'guix-daemon'.])

  dnl Check for Guile-SSH, which is required by 'guix offload'.
  GUIX_CHECK_GUILE_SSH

  case "x$guix_cv_have_recent_guile_ssh" in
    xyes)
      guix_build_daemon_offload="yes"
      AC_DEFINE([HAVE_DAEMON_OFFLOAD_HOOK], [1],
	[Define if the daemon's 'offload' build hook is being built (requires Guile-SSH).])
      ;;
    *)
      guix_build_daemon_offload="no"
      ;;
  esac

  dnl Temporary directory used to store the daemon's data.
  GUIX_TEST_ROOT_DIRECTORY
  GUIX_TEST_ROOT="$ac_cv_guix_test_root"
  AC_SUBST([GUIX_TEST_ROOT])

  GUIX_CHECK_LOCALSTATEDIR
fi

AM_CONDITIONAL([HAVE_LIBBZ2], [test "x$HAVE_LIBBZ2" = "xyes"])
AM_CONDITIONAL([BUILD_DAEMON], [test "x$guix_build_daemon" = "xyes"])
AM_CONDITIONAL([BUILD_DAEMON_OFFLOAD],			\
  [test "x$guix_build_daemon" = "xyes"			\
   && test "x$guix_build_daemon_offload" = "xyes"])
:43 +0100'>2019-01-21</span></td><td><a href='/guix/commit/.mailmap?id=e3634bd0a3480bde3aba5bd6d84d7aff25413207'>Update .mailmap.</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2018-08-27 14:46:26 +0200'>2018-08-27</span></td><td><a href='/guix/commit/.mailmap?id=4715f92ef0b9650cc4075c69f17aa51e84da3f21'>Update email for Pierre Neidhardt.</a><span class='msg-avail'>...</span></td><td>Pierre Neidhardt</td></tr>
<tr><td><span title='2018-07-16 17:14:39 +0200'>2018-07-16</span></td><td><a href='/guix/commit/.mailmap?id=8bbb79cf95a07a40950448a8a09d888254404ed4'>mailmap: Add a line for Pierre-Antoine.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-07-16 16:53:50 +0200'>2018-07-16</span></td><td><a href='/guix/commit/.mailmap?id=33f4d14ab17096984404fc404b4539d784ecbf32'>mailmap: Add another line for myself.</a><span class='msg-avail'>...</span></td><td>Nils Gillmann</td></tr>
<tr><td><span title='2018-03-20 17:17:58 +0100'>2018-03-20</span></td><td><a href='/guix/commit/.mailmap?id=4a78fd4617908546be15d2c101f5cab512c71f8e'>Correct name and Email for ng0.</a><span class='msg-avail'>...</span></td><td>ng0</td></tr>
<tr><td><span title='2018-02-11 09:44:11 -0500'>2018-02-11</span></td><td><a href='/guix/commit/.mailmap?id=c275462025917ad7b8e182f29d6580804e585643'>mailmap: Adjust entries for ng0.</a><span class='msg-avail'>...</span></td><td>ng0</td></tr>
<tr><td><span title='2017-11-26 18:21:19 -0500'>2017-11-26</span></td><td><a href='/guix/commit/.mailmap?id=9221979e367a95c14a35236742792fb624d8e47c'>Update e-mail for ng0.</a><span class='msg-avail'>...</span></td><td>ng0</td></tr>
<tr><td><span title='2017-10-03 17:07:54 +0200'>2017-10-03</span></td><td><a href='/guix/commit/.mailmap?id=d109b1e85c5c1438e66dfc05ea4a018418edaf19'>Update e-mail for Theodoros Foradis.</a><span class='msg-avail'>...</span></td><td>Theodoros Foradis</td></tr>
<tr><td><span title='2017-08-29 20:13:24 -0400'>2017-08-29</span></td><td><a href='/guix/commit/.mailmap?id=3c8ba11a97d3f3b671b8919da8c41f0b0e2ccaf3'>Update e-mail for Kei Kebreau.</a><span class='msg-avail'>...</span></td><td>Kei Kebreau</td></tr>
<tr><td><span title='2017-08-13 16:11:48 -0400'>2017-08-13</span></td><td><a href='/guix/commit/.mailmap?id=79d5ad20e87066a0937a4b61a4857de2b34a7a30'>mailmap: fix entries for ng0.</a><span class='msg-avail'>...</span></td><td>ng0</td></tr>
<tr><td><span title='2017-06-16 15:48:17 +0300'>2017-06-16</span></td><td><a href='/guix/commit/.mailmap?id=a235ec3a6aa21980fe70e8d0c133e50986afbded'>mailmap: Adjust entries for ng0.</a><span class='msg-avail'>...</span></td><td>ng0</td></tr>