;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 Alex Kost <alezost@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

;;;
;;; Generate AUTHORS file for directory with the Guix git repository.
;;;

(use-modules
 (ice-9 popen)
 (ice-9 rdelim)
 (ice-9 match)
 (srfi srfi-1)
 (guix config)
 (guix utils)
 (guix build utils))

(define %guix-dir
  (make-parameter #f))

(define-syntax-rule (append-maybe init-lst (test add-lst) ...)
  (let* ((lst init-lst)
         (lst (if test
                  (append lst add-lst)
                  lst))
         ...)
    lst))

(define (command-output cmd . args)
  "Execute CMD with ARGS and return its output without trailing newspace."
  (let* ((port (apply open-pipe* OPEN_READ cmd args))
         (output (read-string port)))
    (close-port port)
    (string-trim-right output #\newline)))

(define (git-output . args)
  "Execute git command with ARGS and return its output without trailing
newspace."
  (with-directory-excursion (%guix-dir)
    (apply command-output "git" args)))

(define* (contributors-string #:optional (range "HEAD"))
  "Return a string with names of people contributed to commit RANGE."
  (git-output "shortlog" "--numbered" "--summary" "--email" range))

(define* (tags #:key pattern sort)
  "Return a list of the git repository tags.
PATTERN is passed to '--list' and SORT is passed to '--sort' options of
'git tag' command."
  (let* ((args (append-maybe
                '("tag")
                (pattern (list "--list" pattern))
                (sort    (list "--sort" sort))))
         (output (apply git-output args)))
    (string-split output #\newline)))

(define (version-tags)
  "Return only version tags (v0.8, etc.) sorted from the biggest version
to the smallest one."
  (tags #:pattern "v*"
        #:sort "-version:refname"))

(define (generate-authors-file file)
  "Generate authors FILE."
  (define previous-release-tag
    (find (lambda (tag)
            (version>? %guix-version
                       (substring tag 1))) ; remove leading 'v'
          (version-tags)))

  (define release-range
    (string-append previous-release-tag "..HEAD"))

  (with-output-to-file file
    (lambda ()
      (display "\
GNU Guix consists of Scheme code that implements the deployment model
of the Nix package management tool.  In fact, it currently talks to a
build daemon whose code comes from Nix (see the manual for details.)

Nix was initially written by Eelco Dolstra; other people have been
contributing to it.  See `nix/AUTHORS' for details.\n\n")
      (format #t "Contributors to GNU Guix ~a:\n\n"
              %guix-version)
      (display (contributors-string release-range))
      (newline) (newline)
      (display "Overall contributors:\n\n")
      (display (contributors-string))
      (newline))))

(define (show-help)
  (match (command-line)
    ((me _ ...)
     (format #t "Usage: guile ~a DIRECTORY AUTHORS
Generate AUTHORS file for DIRECTORY with the Guix git repository.\n"
             me))))

(match (command-line)
  ((_ guix-dir authors-file)
   (parameterize ((%guix-dir guix-dir))
     (generate-authors-file authors-file)))
  (_
   (show-help)
   (exit 1)))

;;; generate-authors.scm ends here
mon: Remove unused function exportPaths.</a><span class='msg-avail'>...</span></td><td>Maxime Devos</td></tr>
<tr><td><span title='2022-09-11 16:43:30 +0200'>2022-09-11</span></td><td><a href='/guix/commit/nix?id=1c5f5d6d8cb3bd42ed436e31366a328598165734'>daemon: Remove unused function openStore.</a><span class='msg-avail'>...</span></td><td>Maxime Devos</td></tr>
<tr><td><span title='2022-06-05 02:00:00 +0200'>2022-06-05</span></td><td><a href='/guix/commit/nix?id=0ace58b99c7292dd962bcd244f274f8033a7fce4'>daemon: Quote consistently within a string.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2022-05-29 02:00:00 +0200'>2022-05-29</span></td><td><a href='/guix/commit/nix?id=82b06436b4b563a85e70f3fcc610959482f08e91'>daemon: Clarify ‘--check’ error when outputs are missing.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2022-05-18 22:29:55 +0200'>2022-05-18</span></td><td><a href='/guix/commit/nix?id=32916e04f7e1729b7ea5ab768607eb08183c015d'>daemon: runChild() is forbidden to talk during environment set up</a><span class='msg-avail'>...</span></td><td>yarl-baudig@mailoo.org</td></tr>
<tr><td><span title='2022-04-14 14:48:20 +0200'>2022-04-14</span></td><td><a href='/guix/commit/nix?id=5f74169e8e03e64a15499866c6a6de9f38d36f2d'>daemon: Support systemd-style socket activation.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2022-01-18 18:46:51 +0100'>2022-01-18</span></td><td><a href='/guix/commit/nix?id=575e52ac2b090fd194086e9c1c53bbf8055acbc2'>daemon: Always default to gzip for log compression.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-11-27 00:49:53 +0100'>2021-11-27</span></td><td><a href='/guix/commit/nix?id=1b1f557d888fa84b1bc818f1b221776355a7a2dd'>daemon: Print the line whence we expect an integer.</a><span class='msg-avail'>...</span></td><td>Tobias Geerinckx-Rice</td></tr>
<tr><td><span title='2021-11-25 00:17:21 +0100'>2021-11-25</span></td><td><a href='/guix/commit/nix?id=f9b1bb916c284bea00dd5549a43e0894b219d650'>daemon: Read substitute nar size as 'unsigned long long'.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-11-25 00:17:21 +0100'>2021-11-25</span></td><td><a href='/guix/commit/nix?id=1eb40a6dc4917f5a2e915f8b31b750dba3d378c6'>daemon: Read unsigned nar size and download size from substituter.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-11-19 23:04:19 +0100'>2021-11-19</span></td><td><a href='/guix/commit/nix?id=24224530d1f4a70808d003ba8dce849b77625b79'>daemon: Micro-optimize 'deletePath'.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-11-16 14:34:28 +0100'>2021-11-16</span></td><td><a href='/guix/commit/nix?id=472a0e82a52a3d5d841e1dfad6b13e26082a5750'>daemon: Do not deduplicate files smaller than 8 KiB.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-10-01 08:58:06 +0000'>2021-10-01</span></td><td><a href='/guix/commit/nix?id=8579304e8f4deaca33b816b2d56af1d814a03bde'>build: Don’t delete ‘guix-gc.timer’ file.</a><span class='msg-avail'>...</span></td><td>Xinglu Chen</td></tr>
<tr><td><span title='2021-09-20 14:18:21 +0000'>2021-09-20</span></td><td><a href='/guix/commit/nix?id=5c4fd77097e2cecfd4780e099af7954f86779fe1'>etc: Add systemd files for running ‘guix gc’ periodically</a><span class='msg-avail'>...</span></td><td>Thiago Jung Bauermann</td></tr>