;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 Alex Kost <alezost@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

;;;
;;; Generate AUTHORS file for directory with the Guix git repository.
;;;

(use-modules
 (ice-9 popen)
 (ice-9 rdelim)
 (ice-9 match)
 (srfi srfi-1)
 (guix config)
 (guix utils)
 (guix build utils))

(define %guix-dir
  (make-parameter #f))

(define-syntax-rule (append-maybe init-lst (test add-lst) ...)
  (let* ((lst init-lst)
         (lst (if test
                  (append lst add-lst)
                  lst))
         ...)
    lst))

(define (command-output cmd . args)
  "Execute CMD with ARGS and return its output without trailing newspace."
  (let* ((port (apply open-pipe* OPEN_READ cmd args))
         (output (read-string port)))
    (close-port port)
    (string-trim-right output #\newline)))

(define (git-output . args)
  "Execute git command with ARGS and return its output without trailing
newspace."
  (with-directory-excursion (%guix-dir)
    (apply command-output "git" args)))

(define* (contributors-string #:optional (range "HEAD"))
  "Return a string with names of people contributed to commit RANGE."
  (git-output "shortlog" "--numbered" "--summary" "--email" range))

(define* (tags #:key pattern sort)
  "Return a list of the git repository tags.
PATTERN is passed to '--list' and SORT is passed to '--sort' options of
'git tag' command."
  (let* ((args (append-maybe
                '("tag")
                (pattern (list "--list" pattern))
                (sort    (list "--sort" sort))))
         (output (apply git-output args)))
    (string-split output #\newline)))

(define (version-tags)
  "Return only version tags (v0.8, etc.) sorted from the biggest version
to the smallest one."
  (tags #:pattern "v*"
        #:sort "-version:refname"))

(define (generate-authors-file file)
  "Generate authors FILE."
  (define previous-release-tag
    (find (lambda (tag)
            (version>? %guix-version
                       (substring tag 1))) ; remove leading 'v'
          (version-tags)))

  (define release-range
    (string-append previous-release-tag "..HEAD"))

  (with-output-to-file file
    (lambda ()
      (display "\
GNU Guix consists of Scheme code that implements the deployment model
of the Nix package management tool.  In fact, it currently talks to a
build daemon whose code comes from Nix (see the manual for details.)

Nix was initially written by Eelco Dolstra; other people have been
contributing to it.  See `nix/AUTHORS' for details.\n\n")
      (format #t "Contributors to GNU Guix ~a:\n\n"
              %guix-version)
      (display (contributors-string release-range))
      (newline) (newline)
      (display "Overall contributors:\n\n")
      (display (contributors-string))
      (newline))))

(define (show-help)
  (match (command-line)
    ((me _ ...)
     (format #t "Usage: guile ~a DIRECTORY AUTHORS
Generate AUTHORS file for DIRECTORY with the Guix git repository.\n"
             me))))

(match (command-line)
  ((_ guix-dir authors-file)
   (parameterize ((%guix-dir guix-dir))
     (generate-authors-file authors-file)))
  (_
   (show-help)
   (exit 1)))

;;; generate-authors.scm ends here
pan class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-08-29 16:24:17 +0200'>2020-08-29</span></td><td><a href='/guix/commit/m4?id=f5d3a1690cb78ce9413b78352f1030bf4801617a'>build: Remove check for Guile 2.2.1 bug.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-08-24 13:35:24 +0200'>2020-08-24</span></td><td><a href='/guix/commit/m4?id=4c0c65acfade63ce0549115d19db4b639c1e9992'>Use "guile-zlib" and "guile-lzlib" instead of (guix config).</a><span class='msg-avail'>...</span></td><td>Mathieu Othacehe</td></tr>
<tr><td><span title='2020-07-20 23:25:09 +0200'>2020-07-20</span></td><td><a href='/guix/commit/m4?id=e8088f0b06c2193f2cce04a48aa1350229442a9f'>ssh: Speed up RPCs by using #:nodelay.</a><span class='msg-avail'>...</span></td><td>Lars-Dominik Braun</td></tr>
<tr><td><span title='2020-05-28 11:12:40 +0300'>2020-05-28</span></td><td><a href='/guix/commit/m4?id=03e6404936ef0974fdbc877d537b97b28e54124d'>doc: Remove explicit support for mips64el-linux.</a><span class='msg-avail'>...</span></td><td>Efraim Flashner</td></tr>
<tr><td><span title='2020-05-28 00:55:00 +0200'>2020-05-28</span></td><td><a href='/guix/commit/m4?id=c1dc50ab202fafedde3a6b70ce6339496ad53a51'>maint: Check whether Guile-Gcrypt is recent enough.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-02-22 00:45:58 +0100'>2020-02-22</span></td><td><a href='/guix/commit/m4?id=378918725259d221222dd0b1831fbaa3e0a17e1f'>build: Depend on guile-ssh 0.12.0</a><span class='msg-avail'>...</span></td><td>Lars-Dominik Braun</td></tr>
<tr><td><span title='2019-08-17 19:26:21 +0200'>2019-08-17</span></td><td><a href='/guix/commit/m4?id=611a64bd7e0893057cd04dcdc2a8d5e7ecc39e45'>build: 'GUIX_CHECK_GUILE_JSON' really checks for Guile-JSON 3.x.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-07-25 00:16:41 +0200'>2019-07-25</span></td><td><a href='/guix/commit/m4?id=81c3dc32244a17241d74eea9fa265edfcb326f6d'>maint: Switch to Guile-JSON 3.x.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2019-05-06 23:21:33 +0200'>2019-05-06</span></td><td><a href='/guix/commit/m4?id=fea338c6ca1922097fa233be85f424c152a4f507'>Add (guix lzlib).</a><span class='msg-avail'>...</span></td><td>Pierre Neidhardt</td></tr>
<tr><td><span title='2018-11-23 15:42:00 +0100'>2018-11-23</span></td><td><a href='/guix/commit/m4?id=60e1c1099fc3d73ed7d3235e71aae5d00ab7d773'>Update Guile-SQLite3 URL everywhere.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-09-04 17:25:11 +0200'>2018-09-04</span></td><td><a href='/guix/commit/m4?id=ca719424455465fca4b872c371daf2a46de88b33'>Switch to Guile-Gcrypt.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-06-01 15:35:15 +0200'>2018-06-01</span></td><td><a href='/guix/commit/m4?id=d59e75f3b5b82692bd250a1a3a9965397bb588c5'>build: Check for Guile-SQLite3.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>