;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2015 Alex Kost <alezost@gmail.com>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

;;;
;;; Generate AUTHORS file for directory with the Guix git repository.
;;;

(use-modules
 (ice-9 popen)
 (ice-9 rdelim)
 (ice-9 match)
 (srfi srfi-1)
 (guix config)
 (guix utils)
 (guix build utils))

(define %guix-dir
  (make-parameter #f))

(define-syntax-rule (append-maybe init-lst (test add-lst) ...)
  (let* ((lst init-lst)
         (lst (if test
                  (append lst add-lst)
                  lst))
         ...)
    lst))

(define (command-output cmd . args)
  "Execute CMD with ARGS and return its output without trailing newspace."
  (let* ((port (apply open-pipe* OPEN_READ cmd args))
         (output (read-string port)))
    (close-port port)
    (string-trim-right output #\newline)))

(define (git-output . args)
  "Execute git command with ARGS and return its output without trailing
newspace."
  (with-directory-excursion (%guix-dir)
    (apply command-output "git" args)))

(define* (contributors-string #:optional (range "HEAD"))
  "Return a string with names of people contributed to commit RANGE."
  (git-output "shortlog" "--numbered" "--summary" "--email" range))

(define* (tags #:key pattern sort)
  "Return a list of the git repository tags.
PATTERN is passed to '--list' and SORT is passed to '--sort' options of
'git tag' command."
  (let* ((args (append-maybe
                '("tag")
                (pattern (list "--list" pattern))
                (sort    (list "--sort" sort))))
         (output (apply git-output args)))
    (string-split output #\newline)))

(define (version-tags)
  "Return only version tags (v0.8, etc.) sorted from the biggest version
to the smallest one."
  (tags #:pattern "v*"
        #:sort "-version:refname"))

(define (generate-authors-file file)
  "Generate authors FILE."
  (define previous-release-tag
    (find (lambda (tag)
            (version>? %guix-version
                       (substring tag 1))) ; remove leading 'v'
          (version-tags)))

  (define release-range
    (string-append previous-release-tag "..HEAD"))

  (with-output-to-file file
    (lambda ()
      (display "\
GNU Guix consists of Scheme code that implements the deployment model
of the Nix package management tool.  In fact, it currently talks to a
build daemon whose code comes from Nix (see the manual for details.)

Nix was initially written by Eelco Dolstra; other people have been
contributing to it.  See `nix/AUTHORS' for details.\n\n")
      (format #t "Contributors to GNU Guix ~a:\n\n"
              %guix-version)
      (display (contributors-string release-range))
      (newline) (newline)
      (display "Overall contributors:\n\n")
      (display (contributors-string))
      (newline))))

(define (show-help)
  (match (command-line)
    ((me _ ...)
     (format #t "Usage: guile ~a DIRECTORY AUTHORS
Generate AUTHORS file for DIRECTORY with the Guix git repository.\n"
             me))))

(match (command-line)
  ((_ guix-dir authors-file)
   (parameterize ((%guix-dir guix-dir))
     (generate-authors-file authors-file)))
  (_
   (show-help)
   (exit 1)))

;;; generate-authors.scm ends here
lt;jgart@dismail.de&gt;
Co-authored-by: Jorge Acereda &lt;jacereda@gmail.com&gt;
Signed-off-by: Nicolas Goaziou &lt;mail@nicolasgoaziou.fr&gt;
</span></span></td><td>Guix Together</td></tr>
<tr><td><span title='2021-12-17 12:41:03 -0500'>2021-12-17</span></td><td><a href='/guix/commit/gnu/packages/time.scm?id=d080368cb5159613a1ff6611e55e09b62977383e'>gnu: datefudge: Add a backup source URI.</a><span class='msg-avail'>...<span class='msg-tooltip'>This tarball disappeared upstream.

* gnu/packages/time.scm (datefudge)[source]: Add backup URI.
</span></span></td><td>Leo Famulari</td></tr>
<tr><td><span title='2021-12-13 17:48:25 +0100'>2021-12-13</span></td><td><a href='/guix/commit/gnu/packages/time.scm?id=8394619baceb118df92e355377fd543bb1aa501a'>gnu: Simplify package inputs.</a><span class='msg-avail'>...<span class='msg-tooltip'>This commit was obtained by running:

  ./pre-inst-env guix style

without any additional argument.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-11-18 15:40:34 +0100'>2021-11-18</span></td><td><a href='/guix/commit/gnu/packages/time.scm?id=f8119cb5148d1e32ab434fc56964d0fa8969e3c4'>gnu: python-aniso8601: Update to 9.0.1.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/packages/time.scm (python-aniso8601): Update to 9.0.1.
[propagated-inputs]: Remove.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-11-11 12:18:23 -0500'>2021-11-11</span></td><td><a href='/guix/commit/gnu/packages/time.scm?id=33c7e1834739da8905aecd09fa44c8744bf7d773'>gnu: python-dateutil: Update to 2.8.2.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/packages/time.scm (python-dateutil): Update to 2.8.2.
</span></span></td><td>Maxim Cournoyer</td></tr>
<tr><td><span title='2021-10-20 12:58:50 +0300'>2021-10-20</span></td><td><a href='/guix/commit/gnu/packages/time.scm?id=19d3cfec72720a4a1339be3d14f4d88ae5bd59f4'>gnu: python-arrow: Move python-pytz to native-inputs.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/packages/time.scm (python-arrow)[propagated-inputs]: Move
python-pytz to ...
[native-inputs]: ... here since it is only used for testing purposes.

Signed-off-by: Efraim Flashner &lt;efraim@flashner.co.il&gt;
</span></span></td><td>jgart</td></tr>
<tr><td><span title='2021-07-09 11:58:52 +0200'>2021-07-09</span></td><td><a href='/guix/commit/gnu/packages/time.scm?id=b182121458c0126a05a41fec78a4f42472ba8081'>gnu: python-arrow: Honor #:tests? in 'check' phase.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/packages/time.scm (python-arrow)[arguments]: 'check' phase honors
 #:tests?.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2021-07-09 11:58:51 +0200'>2021-07-09</span></td><td><a href='/guix/commit/gnu/packages/time.scm?id=7ad7b0780617fa4055434590ca186a5d2cd87b59'>gnu: python-arrow: Update to 1.1.1.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/packages/time.scm (python-arrow): Update to 1.1.1.
</span></span></td><td>Kris Fremen</td></tr>