;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

;;;
;;; Check whether important binaries are available.
;;;

(use-modules (guix store)
             (guix grafts)
             (guix packages)
             (guix derivations)
             (guix ui)
             (gnu packages commencement)
             (ice-9 match)
             (srfi srfi-1)
             (srfi srfi-26))

(define (final-inputs store system)
  "Return the list of outputs directories of the final inputs for SYSTEM."
  (append-map (match-lambda
                ((or (name package) (name package _))
                 (let ((drv (package-derivation store package system)))
                   ;; Libc's 'debug' output refers to gcc-cross-boot0, but it's
                   ;; hard to avoid, so we tolerate it.  This should be the
                   ;; only exception.  Likewise, 'bash:include' depends on
                   ;; bootstrap-binaries via its 'Makefile.inc' (FIXME).
                   (filter-map (match-lambda
                                 (("debug" . directory)
                                  (if (string=? "glibc" (package-name package))
                                      #f
                                      directory))
                                 (("include" . directory)
                                  (if (string=? "bash" (package-name package))
                                      #f
                                      directory))
                                 ((_ . directory) directory))
                               (derivation->output-paths drv)))))
              %final-inputs))

(define (assert-valid-substitute substitute)
  "Make sure SUBSTITUTE does not refer to any bootstrap inputs, and bail out
if it does."
  (let ((references (substitutable-references substitute)))
    (when (any (cut string-contains <> "boot") references)
      (leave (G_ "'~a' refers to bootstrap inputs: ~s~%")
             (substitutable-path substitute) references))))

(define (test-final-inputs store system)
  "Check whether the final inputs for SYSTEM are clean---i.e., they don't
refer to the bootstrap tools."
  (format #t "checking final inputs for '~a'...~%" system)
  (let* ((inputs    (final-inputs store system))
         (available (substitutable-path-info store inputs)))
    (for-each (lambda (dir)
                (unless (find (lambda (substitute)
                                (string=? (substitutable-path substitute)
                                          dir))
                              available)
                  (leave (G_ "~a (system: ~a) has no substitute~%")
                         dir system)))
              inputs)

    (for-each assert-valid-substitute available)))

;; Entry point.
(with-store store
  (parameterize ((%graft? #f))
    (set-build-options store #:use-substitutes? #t)

    (for-each (cut test-final-inputs store <>)
              %hydra-supported-systems)))

ass='msg-avail'>...</span></td><td>ng0</td></tr>
<tr><td><span title='2017-12-07 11:23:27 -0500'>2017-12-07</span></td><td><a href='/guix/commit/gnu/packages/guile-wm.scm?id=7b45392616ad5842c278441cb8443febefccc6ae'>gnu: guile-wm: Update to 1.0-1.f3c7b3b.</a><span class='msg-avail'>...</span></td><td>ng0</td></tr>
<tr><td><span title='2017-12-07 11:23:18 -0500'>2017-12-07</span></td><td><a href='/guix/commit/gnu/packages/guile-wm.scm?id=0504daaace5252a123828319db676eba197c9882'>gnu: guile-xcb: Update to 1.3-1.db7d5a3.</a><span class='msg-avail'>...</span></td><td>ng0</td></tr>
<tr><td><span title='2017-09-20 20:58:04 -0400'>2017-09-20</span></td><td><a href='/guix/commit/gnu/packages/guile-wm.scm?id=dc1d3cdef70f0e3c047c229c2a0e561d1f47bde8'>gnu: Use 'modify-phases' syntax.</a><span class='msg-avail'>...</span></td><td>Kei Kebreau</td></tr>
<tr><td><span title='2017-08-25 02:15:14 +0200'>2017-08-25</span></td><td><a href='/guix/commit/gnu/packages/guile-wm.scm?id=44aca1a3e5f3bdac1db7103b546b10d65b3038ad'>gnu: guile-xcb: Update source URL.</a><span class='msg-avail'>...</span></td><td>Ricardo Wurmus</td></tr>
<tr><td><span title='2017-08-24 20:42:45 +0200'>2017-08-24</span></td><td><a href='/guix/commit/gnu/packages/guile-wm.scm?id=3f8efbb9a46c655d009f309ed75efa63d6fc08f4'>gnu: guile-wm: Update source URL.</a><span class='msg-avail'>...</span></td><td>Ricardo Wurmus</td></tr>