;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2020 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

;;;
;;; Validate 'etc/news.scm'.
;;;

(use-modules (git)
             (guix git)
             (guix ui)
             (guix channels)
             (srfi srfi-26)
             (ice-9 match))

;; XXX: These two things are currently private.
(define read-channel-news (@@ (guix channels) read-channel-news))
(define channel-news-entries (cut struct-ref <> 0))

(define (all-the-news directory)
  "Return the <channel-news> read from DIRECTORY, a checkout of the 'guix'
channel."
  (call-with-input-file (string-append directory "/etc/news.scm")
    read-channel-news))

(define (validate-texinfo str type language)
  "Parse STR as a Texinfo fragment and raise an error if that fails."
  (catch #t
    (lambda ()
      (texi->plain-text str))
    (lambda (key . args)
      (print-exception (current-error-port) #f key args)
      (report-error (G_ "the Texinfo snippet below is invalid (~a, ~a):~%")
                    type language)
      (display str (current-error-port))
      (exit 1))))

(define (validate-news-entry repository entry)
  "Validate ENTRY, a <channel-news-entry>, making sure it refers to an
existent commit of REPOSITORY and contains only valid Texinfo."
  (catch 'git-error
    (lambda ()
      (let ((commit (commit-lookup repository
                                   (string->oid
                                    (channel-news-entry-commit entry)))))
        (for-each (match-lambda
                    ((language . title)
                     (validate-texinfo title 'title language)))
                  (channel-news-entry-title entry))
        (for-each (match-lambda
                    ((language . body)
                     (validate-texinfo body 'body language)))
                  (channel-news-entry-body entry))))
    (lambda (key error . rest)
      (if (= GIT_ENOTFOUND (git-error-code error))
          (leave (G_ "commit '~a' of entry '~a' does not exist~%")
                 (channel-news-entry-commit entry)
                 (channel-news-entry-title entry))
          (apply throw key error rest)))))

(let* ((this-directory (dirname (current-filename)))
       (top-directory  (string-append this-directory "/.."))
       (entries        (channel-news-entries (all-the-news top-directory))))
  (with-repository top-directory repository
    (for-each (cut validate-news-entry repository <>)
              entries)
    (info (G_ "All ~a channel news entries are valid.~%")
          (length entries))))
<td>Marius Bakke</td></tr>
<tr><td><span title='2019-03-13 23:12:43 +0100'>2019-03-13</span></td><td><a href='/guix/commit/doc/images?id=e1c15e8b8e25e14c253ff1212e289565736f6ea7'>doc: Document the graphical installer some more.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2018-12-16 22:49:10 +0100'>2018-12-16</span></td><td><a href='/guix/commit/doc/images?id=b3bf38a5600d0fdcb0aeed29ee121edef632165d'>doc: Update mesboot graph without bootstrap-guile.</a><span class='msg-avail'>...</span></td><td>Jan Nieuwenhuizen</td></tr>
<tr><td><span title='2018-11-24 08:18:31 +0100'>2018-11-24</span></td><td><a href='/guix/commit/doc/images?id=3d3daf7fa1794c64914ed53e51838a41d9b7adc4'>doc: Update for bootstrap-mescc-tools change.</a><span class='msg-avail'>...</span></td><td>Jan Nieuwenhuizen</td></tr>
<tr><td><span title='2018-09-23 09:46:26 +0200'>2018-09-23</span></td><td><a href='/guix/commit/doc/images?id=a243722c5b8d50b4f0e3f9717ca71aa43dfc56a3'>doc: Describe the Reduced Binary Seed bootstrap.</a><span class='msg-avail'>...</span></td><td>Jan Nieuwenhuizen</td></tr>
<tr><td><span title='2016-12-17 14:46:42 +0100'>2016-12-17</span></td><td><a href='/guix/commit/doc/images?id=aaee461b9d5fb85fc1a548877dc7eea3dd4fbf50'>doc: Update dot graphs.</a><span class='msg-avail'>...</span></td><td>Ludovic Courtès</td></tr>