;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2020 Ludovic Courtès <ludo@gnu.org>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

;;;
;;; Validate 'etc/news.scm'.
;;;

(use-modules (git)
             (guix git)
             (guix ui)
             (guix channels)
             (srfi srfi-26)
             (ice-9 match))

;; XXX: These two things are currently private.
(define read-channel-news (@@ (guix channels) read-channel-news))
(define channel-news-entries (cut struct-ref <> 0))

(define (all-the-news directory)
  "Return the <channel-news> read from DIRECTORY, a checkout of the 'guix'
channel."
  (call-with-input-file (string-append directory "/etc/news.scm")
    read-channel-news))

(define (validate-texinfo str type language)
  "Parse STR as a Texinfo fragment and raise an error if that fails."
  (catch #t
    (lambda ()
      (texi->plain-text str))
    (lambda (key . args)
      (print-exception (current-error-port) #f key args)
      (report-error (G_ "the Texinfo snippet below is invalid (~a, ~a):~%")
                    type language)
      (display str (current-error-port))
      (exit 1))))

(define (validate-news-entry repository entry)
  "Validate ENTRY, a <channel-news-entry>, making sure it refers to an
existent commit of REPOSITORY and contains only valid Texinfo."
  (catch 'git-error
    (lambda ()
      (let ((commit (commit-lookup repository
                                   (string->oid
                                    (channel-news-entry-commit entry)))))
        (for-each (match-lambda
                    ((language . title)
                     (validate-texinfo title 'title language)))
                  (channel-news-entry-title entry))
        (for-each (match-lambda
                    ((language . body)
                     (validate-texinfo body 'body language)))
                  (channel-news-entry-body entry))))
    (lambda (key error . rest)
      (if (= GIT_ENOTFOUND (git-error-code error))
          (leave (G_ "commit '~a' of entry '~a' does not exist~%")
                 (channel-news-entry-commit entry)
                 (channel-news-entry-title entry))
          (apply throw key error rest)))))

(let* ((this-directory (dirname (current-filename)))
       (top-directory  (string-append this-directory "/.."))
       (entries        (channel-news-entries (all-the-news top-directory))))
  (with-repository top-directory repository
    (for-each (cut validate-news-entry repository <>)
              entries)
    (info (G_ "All ~a channel news entries are valid.~%")
          (length entries))))
1-09 22:48:02 +0100'>2020-11-09</span></td><td><a href='/guix/commit/gnu/services/web.scm?id=acb9f7849f7f9c2fb22585f45efaaa8ea397dd70'>services: nginx: Re-introduce server-names-hash-bucket-size.</a><span class='msg-avail'>...<span class='msg-tooltip'>This was unintentionally removed in
00014f769233facebd84f13a00b10032a22cb440.

* gnu/services/web.scm (default-nginx-config): Re-introduce processing
of server-names-hash-bucket-size option.
</span></span></td><td>Julien Lepiller</td></tr>
<tr><td><span title='2020-10-27 18:00:28 +0100'>2020-10-27</span></td><td><a href='/guix/commit/gnu/services/web.scm?id=2ade5bdeb8978d252f298df7150b8d1a359e618d'>services: Add gmnisrv web service.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/services/web.scm (&lt;gmnisrv-configuration&gt;): New record type.
(%default-gmnisrv-config-file): New variable.
(%gmnisrv-accounts, %gmnisrv-activation): New variables.
(gmnisrv-shepherd-service): New procedure.
(gmnisrv-service-type): New variable.
* doc/guix.texi (Web Services): Document it.

Signed-off-by: Ludovic Courtès &lt;ludo@gnu.org&gt;
</span></span></td><td>Alexandru-Sergiu Marton</td></tr>
<tr><td><span title='2020-10-27 18:00:28 +0100'>2020-10-27</span></td><td><a href='/guix/commit/gnu/services/web.scm?id=e86c2f058aac730b407bd128782d3627f71c0fa7'>services: hpcguix-web: Set 'XDG_CACHE_HOME' to a writable directory.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/services/web.scm (hpcguix-web-shepherd-service): Change
XDG_CACHE_HOME to /var/cache/guix/web.  Previously, the authentication
code would try to write to /var/cache/guix/authentication, which would
fail.
</span></span></td><td>Ludovic Courtès</td></tr>
<tr><td><span title='2020-10-14 23:41:26 +0300'>2020-10-14</span></td><td><a href='/guix/commit/gnu/services/web.scm?id=00014f769233facebd84f13a00b10032a22cb440'>services: nginx: Add lua module.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/services/web.scm (&lt;nginx-configuration&gt;)
[lua-package-path, lua-package-cpath]: New record types.
* gnu/services/web.scm (default-nginx-config): Use them.
* doc/guix.texi (Web Services): Document this.
* doc/guix-cookbook.texi (System Configuration): Document this.
</span></span></td><td>Oleg Pykhalov</td></tr>
<tr><td><span title='2020-10-14 14:34:15 +0200'>2020-10-14</span></td><td><a href='/guix/commit/gnu/services/web.scm?id=5436b673f53d27753b53ab8d94eea6153a20e483'>services: nginx: Fix typo in exported symbol.</a><span class='msg-avail'>...<span class='msg-tooltip'>* gnu/services/web.scm: Fix typo in exported symbol.

Signed-off-by: Julien Lepiller &lt;julien@lepiller.eu&gt;
</span></span></td><td>Lulu</td></tr>