aboutsummaryrefslogtreecommitdiff
;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2017, 2018 Oleg Pykhalov <go.wigust@gmail.com>
;;; Copyright © 2017-2018, 2020-2022 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2017, 2018 Clément Lassieur <clement@lassieur.org>
;;; Copyright © 2018 Christopher Baines <mail@cbaines.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (gnu tests version-control)
  #:use-module (gnu tests)
  #:use-module (gnu system)
  #:use-module (gnu system file-systems)
  #:use-module (gnu system shadow)
  #:use-module (gnu system vm)
  #:use-module (gnu services)
  #:use-module (gnu services version-control)
  #:use-module (gnu services cgit)
  #:use-module (gnu services ssh)
  #:use-module (gnu services web)
  #:use-module (gnu services networking)
  #:use-module (gnu packages version-control)
  #:use-module (gnu packages ssh)
  #:use-module (guix gexp)
  #:use-module (guix store)
  #:use-module (guix modules)
  #:export (%test-cgit
            %test-git-http
            %test-gitolite
            %test-gitile))

(define README-contents
  "Hello!  This is what goes inside the 'README' file.")

(define %make-git-repository
  ;; Create Git repository in /srv/git/test.
  (with-imported-modules (source-module-closure
                          '((guix build utils)))
    #~(begin
        (use-modules (guix build utils))

        (let ((git (string-append #$git "/bin/git")))
          (mkdir-p "/tmp/test-repo")
          (with-directory-excursion "/tmp/test-repo"
            (call-with-output-file "/tmp/test-repo/README"
              (lambda (port)
                (display #$README-contents port)))
            (invoke git "config" "--global" "user.email" "charlie@example.org")
            (invoke git "config" "--global" "user.name" "A U Thor")
            (invoke git "init")
            (invoke git "add" ".")
            (invoke git "commit" "-m" "That's a commit."))

          (mkdir-p "/srv/git")
          (rename-file "/tmp/test-repo/.git" "/srv/git/test")
          (with-output-to-file "/srv/git/test/git-daemon-export-ok"
            (lambda _
              (display "")))))))

(define %test-repository-service
  ;; Service that creates /srv/git/test.
  (simple-service 'make-git-repository activation-service-type
                  %make-git-repository))

(define %cgit-configuration-nginx
  (list
   (nginx-server-configuration
    (root cgit)
    (locations
     (list
      (nginx-location-configuration
       (uri "@cgit")
       (body '("fastcgi_param SCRIPT_FILENAME $document_root/lib/cgit/cgit.cgi;"
               "fastcgi_param PATH_INFO $uri;"
               "fastcgi_param QUERY_STRING $args;"
               "fastcgi_param HTTP_HOST $server_name;"
               "fastcgi_pass 127.0.0.1:9000;")))))
    (try-files (list "$uri" "@cgit"))
    (listen '("19418"))
    (ssl-certificate #f)
    (ssl-certificate-key #f))))

(define %cgit-os
  ;; Operating system under test.
  (let ((base-os
         (simple-operating-system
          (service dhcp-client-service-type)
          (service cgit-service-type
                   (cgit-configuration
                    (nginx %cgit-configuration-nginx)))
          %test-repository-service)))
    (operating-system
      (inherit base-os)
      (packages (cons* git
                       (operating-system-packages base-os))))))

(define* (run-cgit-test #:optional (http-port 19418))
  "Run tests in %CGIT-OS, which has nginx running and listening on
HTTP-PORT."
  (define os
    (marionette-operating-system
     %cgit-os
     #:imported-modules '((gnu services herd)
                          (guix combinators))))

  (define vm
    (virtual-machine
     (operating-system os)
     (port-forwardings `((8080 . ,http-port)))))

  (define test
    (with-imported-modules '((gnu build marionette))
      #~(begin
          (use-modules (srfi srfi-11) (srfi srfi-64)
                       (gnu build marionette)
                       (web uri)
                       (web client)
                       (web response))

          (define marionette
            (make-marionette (list #$vm)))

          (test-runner-current (system-test-runner #$output))
          (test-begin "cgit")

          ;; XXX: Shepherd reads the config file *before* binding its control
          ;; socket, so /var/run/shepherd/socket might not exist yet when the
          ;; 'marionette' service is started.
          (test-assert "shepherd socket ready"
            (marionette-eval
             `(begin
                (use-modules (gnu services herd))
                (let loop ((i 10))
                  (cond ((file-exists? (%shepherd-socket-file))
                         #t)
                        ((> i 0)
                         (sleep 1)
                         (loop (- i 1)))
                        (else
                         'failure))))
             marionette))

          ;; Wait for nginx to be up and running.
          (test-assert "nginx running"
            (wait-for-file "/var/run/nginx/pid" marionette))

          ;; Wait for fcgiwrap to be up and running.
          (test-assert "fcgiwrap running"
            (wait-for-tcp-port 9000 marionette))

          ;; Make sure the PID file is created.
          (test-assert "PID file"
            (marionette-eval
             '(file-exists? "/var/run/nginx/pid")
             marionette))

          ;; Make sure the configuration file is created.
          (test-assert "configuration file"
            (marionette-eval
             '(file-exists? "/etc/cgitrc")
             marionette))

          ;; Make sure Git test repository is created.
          (test-assert "Git test repository"
            (marionette-eval
             '(file-exists? "/srv/git/test")
             marionette))

          ;; Make sure we can access pages that correspond to our repository.
          (letrec-syntax ((test-url
                           (syntax-rules ()
                             ((_ path code)
                              (test-equal (string-append "GET " path)
                                code
                                (let-values (((response body)
                                              (http-get (string-append
                                                         "http://localhost:8080"
                                                         path))))
                                  (response-code response))))
                             ((_ path)
                              (test-url path 200)))))
            (test-url "/")
            (test-url "/test")
            (test-url "/test/log")
            (test-url "/test/tree")
            (test-url "/test/tree/README")
            (test-url "/test/does-not-exist" 404)
            (test-url "/test/tree/does-not-exist" 404)
            (test-url "/does-not-exist" 404))

          (test-end))))

  (gexp->derivation "cgit-test" test))

(define %test-cgit
  (system-test
   (name "cgit")
   (description "Connect to a running Cgit server.")
   (value (run-cgit-test))))


;;;
;;; Git server.
;;;

(define %git-nginx-configuration
  (nginx-configuration
   (server-blocks
    (list
     (nginx-server-configuration
      (listen '("19418"))
      (ssl-certificate #f)
      (ssl-certificate-key #f)
      (locations
       (list (git-http-nginx-location-configuration
              (git-http-configuration (export-all? #t)
                                      (uri-path "/git"))))))))))

(define %git-http-os
  (simple-operating-system
   (service dhcp-client-service-type)
   (service fcgiwrap-service-type)
   (service nginx-service-type %git-nginx-configuration)
   %test-repository-service))

(define* (run-git-http-test #:optional (http-port 19418))
  (define os
    (marionette-operating-system
     %git-http-os
     #:imported-modules '((gnu services herd)
                          (guix combinators))))

  (define vm
    (virtual-machine
     (operating-system os)
     (port-forwardings `((8080 . ,http-port)))))

  (define test
    (with-imported-modules '((gnu build marionette)
                             (guix build utils))
      #~(begin
          (use-modules (srfi srfi-64)
                       (rnrs io ports)
                       (gnu build marionette)
                       (guix build utils))

          (define marionette
            (make-marionette (list #$vm)))

          (test-runner-current (system-test-runner #$output))
          (test-begin "git-http")

          ;; Wait for nginx to be up and running.
          (test-assert "nginx running"
            (wait-for-file "/var/run/nginx/pid" marionette))

          ;; Make sure Git test repository is created.
          (test-assert "Git test repository"
            (marionette-eval
             '(file-exists? "/srv/git/test")
             marionette))

          (test-assert "fcgiwrap listens"
            ;; Wait for fcgiwrap to be ready before cloning.
            (wait-for-tcp-port 9000 marionette))

          ;; Make sure we can clone the repo from the host.
          (test-equal "clone"
            '#$README-contents
            (begin
              (invoke #$(file-append git "/bin/git") "clone" "-v"
                      "http://localhost:8080/git/test" "/tmp/clone")
              (call-with-input-file "/tmp/clone/README"
                get-string-all)))

          (test-end))))

  (gexp->derivation "git-http" test))

(define %test-git-http
  (system-test
   (name "git-http")
   (description "Connect to a running Git HTTP server.")
   (value (run-git-http-test))))


;;;
;;; Gitolite.
;;;

(define %gitolite-test-admin-keypair
  (computed-file
   "gitolite-test-admin-keypair"
   (with-imported-modules (source-module-closure
                           '((guix build utils)))
     #~(begin
         (use-modules (ice-9 match) (srfi srfi-26)
                      (guix build utils))

         (mkdir #$output)
         (invoke #$(file-append openssh "/bin/ssh-keygen")
                 "-f" (string-append #$output "/test-admin")
                 "-t" "rsa"
                 "-q"
                 "-N" "")))))

(define %gitolite-os
  (simple-operating-system
   (service dhcp-client-service-type)
   (service openssh-service-type)
   (service gitolite-service-type
            (gitolite-configuration
             (admin-pubkey
              (file-append %gitolite-test-admin-keypair "/test-admin.pub"))))))

(define (run-gitolite-test)
  (define os
    (marionette-operating-system
     %gitolite-os
     #:imported-modules '((gnu services herd)
                          (guix combinators))))

  (define vm
    (virtual-machine
     (operating-system os)
     (port-forwardings `((2222 . 22)))))

  (define test
    (with-imported-modules '((gnu build marionette)
                             (guix build utils))
      #~(begin
          (use-modules (srfi srfi-64)
                       (rnrs io ports)
                       (gnu build marionette)
                       (guix build utils))

          (define marionette
            (make-marionette (list #$vm)))

          (test-runner-current (system-test-runner #$output))
          (test-begin "gitolite")

          ;; Wait for sshd to be up and running.
          (test-assert "service running"
            (marionette-eval
             '(begin
                (use-modules (gnu services herd))
                (start-service 'ssh-daemon))
             marionette))

          (display #$%gitolite-test-admin-keypair)

          (setenv "GIT_SSH_VARIANT" "ssh")
          (setenv "GIT_SSH_COMMAND"
                  (string-join
                   '(#$(file-append openssh "/bin/ssh")
                     "-i" #$(file-append %gitolite-test-admin-keypair
                                         "/test-admin")
                     "-o" "UserKnownHostsFile=/dev/null"
                     "-o" "StrictHostKeyChecking=no")))

          (test-assert "cloning the admin repository"
            (invoke #$(file-append git "/bin/git")
                    "clone" "-v"
                    "ssh://git@localhost:2222/gitolite-admin"
                    "/tmp/clone"))

          (test-assert "admin key exists"
            (file-exists? "/tmp/clone/keydir/test-admin.pub"))

          (with-directory-excursion "/tmp/clone"
            (invoke #$(file-append git "/bin/git")
                    "-c" "user.name=Guix" "-c" "user.email=guix"
                    "commit"
                    "-m" "Test commit"
                    "--allow-empty")

            (test-assert "pushing, and the associated hooks"
              (invoke #$(file-append git "/bin/git") "push")))

          (test-end))))

  (gexp->derivation "gitolite" test))

(define %test-gitolite
  (system-test
   (name "gitolite")
   (description "Clone the Gitolite admin repository.")
   (value (run-gitolite-test))))

;;;
;;; Gitile.
;;;

(define %gitile-configuration-nginx
  (nginx-server-configuration
   (root "/does/not/exists")
   (try-files (list "$uri" "=404"))
   (listen '("19418"))
   (ssl-certificate #f)
   (ssl-certificate-key #f)))

(define %gitile-os
  ;; Operating system under test.
  (simple-operating-system
   (service dhcp-client-service-type)
   (simple-service 'srv-git activation-service-type
                   #~(mkdir-p "/srv/git"))
   (service gitile-service-type
            (gitile-configuration
             (base-git-url "http://localhost")
             (repositories "/srv/git")
             (nginx %gitile-configuration-nginx)))
   %test-repository-service))

(define* (run-gitile-test #:optional (http-port 19418))
  "Run tests in %GITOLITE-OS, which has nginx running and listening on
HTTP-PORT."
  (define os
    (marionette-operating-system
     %gitile-os
     #:imported-modules '((gnu services herd)
                          (guix combinators))))

  (define vm
    (virtual-machine
     (operating-system os)
     (port-forwardings `((8081 . ,http-port)))
     (memory-size 1024)))

  (define test
    (with-imported-modules '((gnu build marionette))
      #~(begin
          (use-modules (srfi srfi-11) (srfi srfi-64)
                       (gnu build marionette)
                       (web uri)
                       (web client)
                       (web response))

          (define marionette
            (make-marionette (list #$vm)))

          (test-runner-current (system-test-runner #$output))
          (test-begin "gitile")

          ;; XXX: Shepherd reads the config file *before* binding its control
          ;; socket, so /var/run/shepherd/socket might not exist yet when the
          ;; 'marionette' service is started.
          (test-assert "shepherd socket ready"
            (marionette-eval
             `(begin
                (use-modules (gnu services herd))
                (let loop ((i 10))
                  (cond ((file-exists? (%shepherd-socket-file))
                         #t)
                        ((> i 0)
                         (sleep 1)
                         (loop (- i 1)))
                        (else
                         'failure))))
             marionette))

          ;; Wait for nginx to be up and running.
          (test-assert "nginx running"
            (wait-for-file "/var/run/nginx/pid" marionette))

          ;; Make sure Git test repository is created.
          (test-assert "Git test repository"
            (marionette-eval
             '(file-exists? "/srv/git/test")
             marionette))

          (sleep 2)

          ;; Make sure we can access pages that correspond to our repository.
          (letrec-syntax ((test-url
                           (syntax-rules ()
                             ((_ path code)
                              (test-equal (string-append "GET " path)
                                code
                                (let-values (((response body)
                                              (http-get (string-append
                                                         "http://localhost:8081"
                                                         path))))
                                  (response-code response))))
                             ((_ path)
                              (test-url path 200)))))
            (test-url "/")
            (test-url "/css/gitile.css")
            (test-url "/test")
            (test-url "/test/commits")
            (test-url "/test/tree" 404)
            (test-url "/test/tree/-")
            (test-url "/test/tree/-/README")
            (test-url "/test/does-not-exist" 404)
            (test-url "/test/tree/-/does-not-exist" 404)
            (test-url "/does-not-exist" 404))

          (test-end))))

  (gexp->derivation "gitile-test" test))

(define %test-gitile
  (system-test
   (name "gitile")
   (description "Connect to a running Gitile server.")
   (value (run-gitile-test))))
generated by cgit
(lambda* (#:key inputs #:allow-other-keys)
- (for-each (lambda (file)
- (substitute* file
- (("http://www.oasis-open.org/docbook/xml/4.1.2/docbookx.dtd")
- (string-append (assoc-ref inputs "docbook-xml")
- "/xml/dtd/docbook/docbookx.dtd"))))
- (find-files "Source" "\\.sgml$"))))
- (add-after 'unpack 'embed-absolute-wpebackend-reference
- (lambda* (#:key inputs #:allow-other-keys)
- (let ((wpebackend-fdo (assoc-ref inputs "wpebackend-fdo")))
- (substitute* "Source/WebKit/UIProcess/glib/WebProcessPoolGLib.cpp"
- (("libWPEBackend-fdo-([\\.0-9]+)\\.so" all version)
- (string-append wpebackend-fdo "/lib/" all))))))
- ,@(if (target-x86-64?)
- '()
- '((add-after 'unpack 'disable-sse2
- (lambda _
- (substitute* "Source/cmake/WebKitCompilerFlags.cmake"
- (("WTF_CPU_X86 AND NOT CMAKE_CROSSCOMPILING")
- "FALSE"))))))
- (add-after 'install 'move-doc-files
- (lambda* (#:key outputs #:allow-other-keys)
- (let ((out (assoc-ref outputs "out"))
- (doc (assoc-ref outputs "doc")))
- (mkdir-p (string-append doc "/share"))
- (rename-file (string-append out "/share/gtk-doc")
- (string-append doc "/share/gtk-doc"))))))))
+ (list
+ ;; The release archive doesn't include the resources/sources needed to
+ ;; run the various regression tests.
+ #:tests? #f
+ ;; When building using the default RelWithDebInfo build type, the final
+ ;; binaries require 20 GiB of memory to link (even with ld.gold or lld)
+ ;; and produce 4.6 GiB of debug symbols.
+ #:build-type "Release"
+ #:configure-flags #~(list
+ "-DPORT=GTK"
+ ;; GTKDOC will be removed upstream soon in favor of
+ ;; gi-docgen; it is normally disabled because the
+ ;; doc is rather expensive to build.
+ "-DENABLE_GTKDOC=ON"
+ ;; The minibrowser, not built by default, is a good
+ ;; tool to validate the good operation of
+ ;; webkitgtk.
+ "-DENABLE_MINIBROWSER=ON"
+ ;; The default lib installation prefix is lib64.
+ (string-append "-DLIB_INSTALL_DIR=" #$output "/lib"))
+ ;; The build may fail with -j1 (see:
+ ;; https://bugs.webkit.org/show_bug.cgi?id=195251).
+ #:make-flags #~(list "-j" (number->string (max 2 (parallel-job-count))))
+ #:phases
+ #~(modify-phases %standard-phases
+ (add-after 'unpack 'configure-bubblewrap-store-directory
+ (lambda _
+ ;; This phase works in tandem with
+ ;; webkitgtk-adjust-bubblewrap-paths.patch and avoids hard
+ ;; coding /gnu/store, for users with other prefixes.
+ (let ((store-directory (%store-directory)))
+ (substitute*
+ "Source/WebKit/UIProcess/Launcher/glib/BubblewrapLauncher.cpp"
+ (("@storedir@") store-directory)))))
+ (add-after 'unpack 'do-not-disable-new-dtags
+ ;; Ensure the linker uses new dynamic tags as this is what Guix
+ ;; uses and validates in the validate-runpath phase.
+ (lambda _
+ (substitute* "Source/cmake/OptionsCommon.cmake"
+ (("if \\(LD_SUPPORTS_DISABLE_NEW_DTAGS\\)")
+ "if (FALSE)"))))
+ (add-after 'unpack 'help-cmake-find-elogind
+ (lambda _
+ (substitute* "Source/cmake/FindJournald.cmake"
+ ;; Otherwise, CMake would throw an error because it relies on
+ ;; the pkg-config search to locate headers.
+ (("pkg_check_modules\\(PC_SYSTEMD QUIET libsystemd")
+ "pkg_check_modules(PC_SYSTEMD QUIET libelogind"))))
+ (add-after 'unpack 'patch-gtk-doc-scan
+ (lambda* (#:key native-inputs inputs #:allow-other-keys)
+ (substitute* (find-files "Source" "\\.sgml$")
+ (("http://www.oasis-open.org/docbook/xml/4.1.2/docbookx.dtd")
+ (search-input-file (or native-inputs inputs)
+ "xml/dtd/docbook/docbookx.dtd")))))
+ (add-after 'unpack 'embed-absolute-wpebackend-reference
+ (lambda* (#:key inputs #:allow-other-keys)
+ (let ((wpebackend-fdo (assoc-ref inputs "wpebackend-fdo")))
+ (substitute* "Source/WebKit/UIProcess/glib/WebProcessPoolGLib.cpp"
+ (("libWPEBackend-fdo-[\\.0-9]+\\.so" all)
+ (search-input-file inputs (string-append "lib/" all)))))))
+ #$@(if (target-x86-64?)
+ '()
+ '((add-after 'unpack 'disable-sse2
+ (lambda _
+ (substitute* "Source/cmake/WebKitCompilerFlags.cmake"
+ (("WTF_CPU_X86 AND NOT CMAKE_CROSSCOMPILING")
+ "FALSE"))))))
+ (add-after 'install 'move-doc-files
+ (lambda* (#:key outputs #:allow-other-keys)
+ (let ((doc (assoc-ref outputs "doc")))
+ (mkdir-p (string-append doc "/share"))
+ (rename-file (string-append #$output "/share/gtk-doc")
+ (string-append doc "/share/gtk-doc"))))))))
(native-inputs
- `(("bison" ,bison)
- ("gettext" ,gettext-minimal)
- ("glib:bin" ,glib "bin") ; for glib-mkenums, etc.
- ("gobject-introspection" ,gobject-introspection)
- ("gperf" ,gperf)
- ("perl" ,perl)
- ("pkg-config" ,pkg-config)
- ("python" ,python-wrapper)
- ("gtk-doc" ,gtk-doc/stable) ; For documentation generation
- ("docbook-xml" ,docbook-xml) ; For documentation generation
- ("ruby" ,ruby)))
+ (list bison
+ gettext-minimal
+ `(,glib "bin") ;for glib-mkenums, etc.
+ gobject-introspection
+ gperf
+ perl
+ pkg-config
+ python-wrapper
+ ;; These are required to build the documentation.
+ gtk-doc/stable
+ docbook-xml
+ ruby))
(propagated-inputs
(list gtk+ libsoup))
(inputs
- `(("at-spi2-core" ,at-spi2-core)
- ("bubblewrap" ,bubblewrap)
- ("enchant" ,enchant)
- ("geoclue" ,geoclue)
- ("gst-plugins-base" ,gst-plugins-base)
- ("gtk+-2" ,gtk+-2)
- ("harfbuzz" ,harfbuzz)
- ("hyphen" ,hyphen)
- ("icu4c" ,icu4c)
- ("lcms" ,lcms)
- ("libgcrypt" ,libgcrypt)
- ("libjpeg" ,libjpeg-turbo)
- ("libnotify" ,libnotify)
- ("libpng" ,libpng)
- ("libseccomp" ,libseccomp)
- ("libsecret" ,libsecret)
- ("libtasn1" ,libtasn1)
- ("libwebp" ,libwebp)
- ("libwpe" ,libwpe)
- ("libxcomposite" ,libxcomposite)
- ("libxml2" ,libxml2)
- ("libxslt" ,libxslt)
- ("libxt" ,libxt)
- ("mesa" ,mesa)
- ("openjpeg" ,openjpeg)
- ("sqlite" ,sqlite)
- ("woff2" ,woff2)
- ("wpebackend-fdo" ,wpebackend-fdo)
- ("xdg-dbus-proxy" ,xdg-dbus-proxy)))
+ (list at-spi2-core
+ bubblewrap
+ elogind
+ enchant
+ geoclue
+ gst-plugins-base
+ gtk+-2
+ harfbuzz
+ hyphen
+ icu4c
+ lcms
+ libgcrypt
+ libjpeg-turbo
+ libmanette
+ libnotify
+ libpng
+ libseccomp
+ libsecret
+ libtasn1
+ libwebp
+ libwpe
+ libxcomposite
+ libxml2
+ libxslt
+ libxt
+ mesa
+ openjpeg
+ sqlite
+ woff2
+ wpebackend-fdo
+ xdg-dbus-proxy))
(home-page "https://www.webkitgtk.org/")
(synopsis "Web content engine for GTK+")
- (description
- "WebKitGTK+ is a full-featured port of the WebKit rendering engine,
+ (description "WebKitGTK+ is a full-featured port of the WebKit rendering engine,
suitable for projects requiring any kind of web integration, from hybrid
HTML/CSS applications to full-fledged web browsers. WebKitGTK+ video playing
capabilities can be extended through the use of GStreamer plugins (not
@@ -366,17 +389,17 @@ propagated by default) such as @code{gst-plugins-good} and
license:bsd-2
license:bsd-3))))
-;;; Required by gnome-online-accounts; as webkitgtk 2.34 propagates libsoup 3,
-;;; which causes the build to fail.
-;;; Also required by e.g. emacs-next-pgtk, emacs-xwidgets, and some other
-;;; Gnome packages for webkit2gtk-4.0. See also the upstream tracker for
-;;; libsoup 3: https://gitlab.gnome.org/GNOME/libsoup/-/issues/218
+;;; Required by gnome-online-accounts as webkitgtk propagates libsoup 3, which
+;;; causes the build to fail. Also required by e.g. emacs-next-pgtk,
+;;; emacs-xwidgets, and some other GNOME packages for webkit2gtk-4.0. See
+;;; also the upstream tracker for libsoup 3:
+;;; https://gitlab.gnome.org/GNOME/libsoup/-/issues/218
(define-public webkitgtk-with-libsoup2
(package/inherit webkitgtk
(name "webkitgtk-with-libsoup2")
(arguments (substitute-keyword-arguments (package-arguments webkitgtk)
((#:configure-flags flags)
- `(cons "-DUSE_SOUP2=ON" ,flags))))
+ #~(cons "-DUSE_SOUP2=ON" #$flags))))
(propagated-inputs
- (alist-replace "libsoup" (list libsoup-minimal-2)
- (package-propagated-inputs webkitgtk)))))
+ (modify-inputs (package-propagated-inputs webkitgtk)
+ (replace "libsoup" libsoup-minimal-2)))))
generated by cgit